You are viewing a plain text version of this content. The canonical link for it is here.
Posted to commits@syncope.apache.org by il...@apache.org on 2015/01/14 17:38:18 UTC
[2/5] syncope git commit: [SYNCOPE-620] FIT module is in,
now time for importing integration tests
http://git-wip-us.apache.org/repos/asf/syncope/blob/b015c443/syncope620/server/rest-cxf/src/main/resources/wadl2html/index.xsl
----------------------------------------------------------------------
diff --git a/syncope620/server/rest-cxf/src/main/resources/wadl2html/index.xsl b/syncope620/server/rest-cxf/src/main/resources/wadl2html/index.xsl
new file mode 100644
index 0000000..e238b99
--- /dev/null
+++ b/syncope620/server/rest-cxf/src/main/resources/wadl2html/index.xsl
@@ -0,0 +1,484 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+ Licensed to the Apache Software Foundation (ASF) under one
+ or more contributor license agreements. See the NOTICE file
+ distributed with this work for additional information
+ regarding copyright ownership. The ASF licenses this file
+ to you under the Apache License, Version 2.0 (the
+ "License"); you may not use this file except in compliance
+ with the License. You may obtain a copy of the License at
+
+ http://www.apache.org/licenses/LICENSE-2.0
+
+ Unless required by applicable law or agreed to in writing,
+ software distributed under the License is distributed on an
+ "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+ KIND, either express or implied. See the License for the
+ specific language governing permissions and limitations
+ under the License.
+-->
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns:xalan="http://xml.apache.org/xalan"
+ xmlns:wadl="http://wadl.dev.java.net/2009/02"
+ xmlns:xs="http://www.w3.org/2001/XMLSchema"
+ exclude-result-prefixes="xalan wadl xs"
+ version="1.0">
+
+ <xsl:param name="contextPath"/>
+
+ <xsl:variable name="namespaces">
+ <xsl:for-each select="/*/namespace::*">
+ <namespace prefix="{name()}" url="{.}"/>
+ </xsl:for-each>
+ </xsl:variable>
+
+ <xsl:variable name="namespacePos">
+ <xsl:for-each select="//xs:schema">
+ <namespace url="{@targetNamespace}" position="{position()}"/>
+ </xsl:for-each>
+ </xsl:variable>
+
+ <xsl:template match="/wadl:application">
+ <html lang="en">
+ <head>
+ <meta charset="utf-8"/>
+ <title>
+ <xsl:value-of select="wadl:doc/@title"/>
+ </title>
+
+ <link rel="stylesheet" href="{$contextPath}/webjars/jquery-ui/${jquery-ui.version}/themes/base/minified/jquery-ui.min.css"/>
+ <style>
+ body {
+ font-family: "Verdana,Arial,sans-serif";
+ font-size: 0.9em;
+ }
+
+ table {
+ font-family: "Verdana,Arial,sans-serif";
+ font-size: 0.9em;
+ border-width: 1px;
+ border-color: #666666;
+ border-collapse: collapse;
+ }
+ table th {
+ border-width: 1px;
+ padding: 8px;
+ border-style: solid;
+ border-color: #666666;
+ background-color: #dedede;
+ }
+ td {
+ border-width: 1px;
+ padding: 8px;
+ border-style: solid;
+ border-color: #666666;
+ background-color: #ffffff;
+ vertical-align: top;
+ }
+
+ .methods {
+ padding: 5px;
+ }
+
+ .representation-label {
+ font-weight: bold;
+ width: 80px;
+ }
+
+ .ui-widget { font-size: 0.9em; }
+ .ui-tabs-vertical { width: 60em; }
+ .ui-tabs-vertical .ui-tabs-nav { padding: .2em .1em .2em .2em; float: left; width: 15em; }
+ .ui-tabs-vertical .ui-tabs-nav li { clear: left; width: 100%; border-bottom-width: 1px !important; border-right-width: 0 !important; margin: 0 -1px .2em 0; }
+ .ui-tabs-vertical .ui-tabs-nav li a { display:block; }
+ .ui-tabs-vertical .ui-tabs-nav li.ui-tabs-active { padding-bottom: 0; padding-right: .1em; border-right-width: 1px; border-right-width: 1px; }
+ .ui-tabs-vertical .ui-tabs-panel { padding: 1em; float: right; width: 40em;}
+ </style>
+
+ <script src="{$contextPath}/webjars/jquery/${jquery.version}/jquery.min.js">
+ </script>
+ <script src="{$contextPath}/webjars/jquery-ui/${jquery-ui.version}/ui/minified/jquery-ui.min.js">
+ </script>
+ <script>
+ //<![CDATA[
+ $(function() {
+ //]]>
+ <xsl:for-each select="wadl:resources/wadl:resource">
+ <xsl:sort select="@path"/>
+ <xsl:text>$( "#accordion-</xsl:text>
+ <xsl:value-of select="position()"/>
+ <xsl:text>" ).accordion({
+ collapsible: true,
+ heightStyle: "content",
+ active: false
+ });
+ </xsl:text>
+
+ <xsl:variable name="parentResourcePath" select="translate(@path, '/{}', '___')"/>
+ <xsl:call-template name="dialog-init">
+ <xsl:with-param name="resourcePath" select="$parentResourcePath"/>
+ </xsl:call-template>
+ <xsl:for-each select="wadl:resource">
+ <xsl:variable name="childResourcePath" select="translate(@path, '/{}', '___')"/>
+ <xsl:call-template name="dialog-init">
+ <xsl:with-param name="resourcePath" select="concat($parentResourcePath, $childResourcePath)"/>
+ </xsl:call-template>
+ </xsl:for-each>
+ </xsl:for-each>
+ //<![CDATA[
+ $( "#tabs" ).tabs().addClass( "ui-tabs-vertical ui-helper-clearfix" );
+ $( "#tabs li" ).removeClass( "ui-corner-top" ).addClass( "ui-corner-left" );
+ });
+
+ /*
+ * hoverIntent | Copyright 2011 Brian Cherne
+ * http://cherne.net/brian/resources/jquery.hoverIntent.html
+ * modified by the jQuery UI team
+ */
+ $.event.special.hoverintent = {
+ setup: function() {
+ $( this ).bind( "mouseover", jQuery.event.special.hoverintent.handler );
+ },
+ teardown: function() {
+ $( this ).unbind( "mouseover", jQuery.event.special.hoverintent.handler );
+ },
+ handler: function( event ) {
+ var currentX, currentY, timeout,
+ args = arguments,
+ target = $( event.target ),
+ previousX = event.pageX,
+ previousY = event.pageY;
+
+ function track( event ) {
+ currentX = event.pageX;
+ currentY = event.pageY;
+ };
+
+ function clear() {
+ target
+ .unbind( "mousemove", track )
+ .unbind( "mouseout", clear );
+ clearTimeout( timeout );
+ }
+
+ function handler() {
+ var prop,
+ orig = event;
+
+ if ( ( Math.abs( previousX - currentX ) +
+ Math.abs( previousY - currentY ) ) < 7 ) {
+ clear();
+
+ event = $.Event( "hoverintent" );
+ for ( prop in orig ) {
+ if ( !( prop in event ) ) {
+ event[ prop ] = orig[ prop ];
+ }
+ }
+ // Prevent accessing the original event since the new event
+ // is fired asynchronously and the old event is no longer
+ // usable (#6028)
+ delete event.originalEvent;
+
+ target.trigger( event );
+ } else {
+ previousX = currentX;
+ previousY = currentY;
+ timeout = setTimeout( handler, 100 );
+ }
+ }
+
+ timeout = setTimeout( handler, 100 );
+ target.bind({
+ mousemove: track,
+ mouseout: clear
+ });
+ }
+ };
+ //]]>
+ </script>
+ </head>
+ <body>
+ <h1>
+ <xsl:value-of select="wadl:doc/@title"/>
+ </h1>
+
+ <h3>Namespaces</h3>
+ <table>
+ <tr>
+ <th>Prefix</th>
+ <th>URI</th>
+ <th>XSD</th>
+ </tr>
+ <xsl:apply-templates select="wadl:grammars/xs:schema"/>
+ </table>
+
+ <h3>REST resources</h3>
+ <div id="tabs">
+ <ul>
+ <xsl:for-each select="wadl:resources/wadl:resource">
+ <xsl:sort select="@path"/>
+ <li>
+ <a href="#tabs-{position()}">
+ <xsl:value-of select="@path"/>
+ </a>
+ </li>
+ </xsl:for-each>
+ </ul>
+
+ <xsl:apply-templates select="wadl:resources/wadl:resource">
+ <xsl:sort select="@path"/>
+ </xsl:apply-templates>
+ </div>
+ </body>
+ </html>
+ </xsl:template>
+
+ <xsl:template name="dialog-init">
+ <xsl:param name="resourcePath"/>
+
+ <xsl:for-each select="wadl:method">
+ <xsl:text>$(function() {
+ $( "#dialog</xsl:text>
+ <xsl:value-of select="$resourcePath"/>_<xsl:value-of select="position()"/>
+ <xsl:text>" ).dialog({
+ autoOpen: false,
+ modal: true,
+ height: "auto",
+ width: "auto",
+ resizable: false
+ });
+
+ $( "#opener</xsl:text>
+ <xsl:value-of select="$resourcePath"/>_<xsl:value-of select="position()"/>
+ <xsl:text>" ).click(function() {
+ $( "#dialog</xsl:text>
+ <xsl:value-of select="$resourcePath"/>_<xsl:value-of select="position()"/>
+ <xsl:text>" ).dialog( "open" );
+ });
+ });
+ </xsl:text>
+ </xsl:for-each>
+ </xsl:template>
+
+ <xsl:template match="xs:schema">
+ <xsl:variable name="targetNamespace" select="@targetNamespace"/>
+
+ <xsl:variable name="prefix"
+ select="xalan:nodeset($namespaces)/namespace[@url = $targetNamespace]/@prefix"/>
+
+ <tr>
+ <td>
+ <xsl:value-of select="$prefix"/>
+ </td>
+ <td>
+ <xsl:value-of select="@targetNamespace"/>
+ </td>
+ <td>
+ <a href="schema_{position()}_{$prefix}.html"
+ onClick="window.open('', 'schema', '', true).focus();" target="schema">
+ <xsl:value-of select="$prefix"/>.xsd</a>
+ </td>
+ </tr>
+ </xsl:template>
+
+ <xsl:template match="wadl:resource">
+ <div id="tabs-{position()}">
+ <h2>
+ <xsl:value-of select="@path"/>
+ </h2>
+
+ <xsl:if test="string-length(wadl:doc) > 0">
+ <p>
+ <xsl:value-of select="wadl:doc/text()" disable-output-escaping="yes"/>
+ </p>
+ </xsl:if>
+
+ <xsl:call-template name="parameters"/>
+
+ <xsl:call-template name="methods">
+ <xsl:with-param name="resourcePath" select="@path"/>
+ </xsl:call-template>
+
+ <xsl:variable name="parentPath" select="@path"/>
+ <div id="accordion-{position()}">
+ <xsl:for-each select="descendant::*[local-name() = 'resource']">
+ <xsl:sort select="@path"/>
+ <xsl:call-template name="subresource">
+ <xsl:with-param name="parentPath" select="$parentPath"/>
+ </xsl:call-template>
+ </xsl:for-each>
+ </div>
+ </div>
+ </xsl:template>
+
+ <xsl:template name="methods">
+ <xsl:param name="resourcePath"/>
+
+ <xsl:variable name="escapedPath" select="translate($resourcePath, '/{}', '___')"/>
+ <div class="methods">
+ <xsl:for-each select="wadl:method">
+ <button id="opener{$escapedPath}_{position()}">
+ <xsl:value-of select="@name"/>
+ <xsl:if test="string-length(@id) > 0">
+ <br/>
+ (<em>
+ <xsl:value-of select="@id"/>
+ </em>)
+ </xsl:if>
+ </button>
+ <div id="dialog{$escapedPath}_{position()}" title="{@name} {$resourcePath}">
+ <xsl:apply-templates select="."/>
+ </div>
+ </xsl:for-each>
+ </div>
+ </xsl:template>
+
+ <xsl:template name="subresource">
+ <xsl:param name="parentPath"/>
+
+ <h3>
+ <xsl:value-of select="@path"/>
+ </h3>
+
+ <div>
+ <xsl:if test="string-length(wadl:doc) > 0">
+ <p>
+ <xsl:value-of select="wadl:doc/text()" disable-output-escaping="yes"/>
+ </p>
+ </xsl:if>
+
+ <xsl:call-template name="parameters"/>
+
+ <xsl:call-template name="methods">
+ <xsl:with-param name="resourcePath" select="concat($parentPath, @path)"/>
+ </xsl:call-template>
+ </div>
+ </xsl:template>
+
+ <xsl:template match="wadl:method">
+ <xsl:if test="string-length(wadl:doc) > 0">
+ <p>
+ <xsl:value-of select="wadl:doc/text()" disable-output-escaping="yes"/>
+ </p>
+ </xsl:if>
+
+ <xsl:if test="count(wadl:request/@*) + count(wadl:request/*) > 0">
+ <xsl:apply-templates select="wadl:request"/>
+ </xsl:if>
+ <xsl:if test="count(wadl:response/@*) + count(wadl:response/*) > 0">
+ <xsl:apply-templates select="wadl:response"/>
+ </xsl:if>
+ </xsl:template>
+
+ <xsl:template match="wadl:request|wadl:response">
+ <xsl:call-template name="parameters"/>
+
+ <h4>
+ R<xsl:value-of select="substring-after(local-name(), 'r')"/>
+ </h4>
+
+ <xsl:if test="string-length(wadl:doc) > 0">
+ <p>
+ <xsl:value-of select="wadl:doc/text()" disable-output-escaping="yes"/>
+ </p>
+ </xsl:if>
+
+ <table>
+ <xsl:if test="string-length(@status) >0 ">
+ <tr>
+ <td class="representation-label">Status</td>
+ <td>
+ <xsl:value-of select="@status"/>
+ </td>
+ </tr>
+ </xsl:if>
+ <xsl:if test="count(wadl:representation) > 0">
+ <tr>
+ <td class="representation-label">Content type</td>
+ <td>
+ <xsl:if test="count(wadl:representation/@element) > 0">
+ <xsl:choose>
+ <xsl:when test="starts-with(wadl:representation/@element, 'xs:')">
+ <xsl:value-of select="wadl:representation/@element"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:variable name="schema-prefix"
+ select="substring-before(wadl:representation/@element, ':')"/>
+ <xsl:variable name="nsURL"
+ select="xalan:nodeset($namespaces)/namespace[@prefix = $schema-prefix]/@url"/>
+ <xsl:variable name="schema-position"
+ select="xalan:nodeset($namespacePos)/namespace[@url = $nsURL]/@position"/>
+
+ <a href="schema_{$schema-position}_{$schema-prefix}.html#{substring-after(wadl:representation/@element, ':')}"
+ onClick="window.open('', 'schema', '', true).focus();" target="schema">
+ <xsl:value-of select="wadl:representation/@element"/>
+ </a>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:if>
+ <xsl:if test="count(wadl:representation/wadl:param) > 0">
+ <xsl:value-of select="wadl:representation/wadl:param/@type"/>
+ </xsl:if>
+ <xsl:if test="count(wadl:representation/wadl:doc) > 0">
+ <br/>
+ <xsl:value-of select="wadl:representation/wadl:doc/text()" disable-output-escaping="yes"/>
+ </xsl:if>
+ </td>
+ </tr>
+ <tr>
+ <td class="representation-label">Media types</td>
+ <td>
+ <xsl:for-each select="wadl:representation">
+ <xsl:value-of select="@mediaType"/>
+ <br/>
+ </xsl:for-each>
+ </td>
+ </tr>
+ </xsl:if>
+ </table>
+ </xsl:template>
+
+ <xsl:template name="parameters">
+ <xsl:if test="count(wadl:param) > 0">
+ <h5>Parameters</h5>
+ <table>
+ <tr>
+ <th>Name</th>
+ <th>Description</th>
+ <th>Style</th>
+ <th>Type</th>
+ <th>Default</th>
+ </tr>
+ <xsl:for-each select="wadl:param">
+ <tr>
+ <td>
+ <xsl:value-of select="@name"/>
+ </td>
+ <td>
+ <xsl:value-of select="wadl:doc/text()" disable-output-escaping="yes"/>
+ </td>
+ <td>
+ <xsl:value-of select="@style"/>
+ </td>
+ <td>
+ <xsl:value-of select="@type"/>
+ <xsl:if test="count(wadl:option) > 0">
+ <ul>
+ <xsl:for-each select="wadl:option">
+ <li>
+ <xsl:value-of select="@value"/>
+ </li>
+ </xsl:for-each>
+ </ul>
+ </xsl:if>
+ </td>
+ <td>
+ <xsl:value-of select="@default"/>
+ </td>
+ </tr>
+ </xsl:for-each>
+ </table>
+ </xsl:if>
+ </xsl:template>
+
+</xsl:stylesheet>
http://git-wip-us.apache.org/repos/asf/syncope/blob/b015c443/syncope620/server/rest-cxf/src/main/resources/wadl2html/schema.xsl
----------------------------------------------------------------------
diff --git a/syncope620/server/rest-cxf/src/main/resources/wadl2html/schema.xsl b/syncope620/server/rest-cxf/src/main/resources/wadl2html/schema.xsl
new file mode 100644
index 0000000..6551d09
--- /dev/null
+++ b/syncope620/server/rest-cxf/src/main/resources/wadl2html/schema.xsl
@@ -0,0 +1,148 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+ Licensed to the Apache Software Foundation (ASF) under one
+ or more contributor license agreements. See the NOTICE file
+ distributed with this work for additional information
+ regarding copyright ownership. The ASF licenses this file
+ to you under the Apache License, Version 2.0 (the
+ "License"); you may not use this file except in compliance
+ with the License. You may obtain a copy of the License at
+
+ http://www.apache.org/licenses/LICENSE-2.0
+
+ Unless required by applicable law or agreed to in writing,
+ software distributed under the License is distributed on an
+ "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+ KIND, either express or implied. See the License for the
+ specific language governing permissions and limitations
+ under the License.
+-->
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns:wadl="http://wadl.dev.java.net/2009/02"
+ xmlns:xs="http://www.w3.org/2001/XMLSchema"
+ exclude-result-prefixes="wadl xs"
+ version="1.0">
+
+ <xsl:strip-space elements="*"/>
+
+ <xsl:param name="contextPath"/>
+ <xsl:param name="schema-position"/>
+ <xsl:param name="schema-prefix"/>
+
+ <xsl:template match="/wadl:application">
+ <html lang="en">
+ <head>
+ <meta charset="utf-8"/>
+ <title>
+ <xsl:value-of select="wadl:doc/@title"/>
+ </title>
+
+ <link rel="stylesheet" href="{$contextPath}/webjars/highlightjs/${highlightjs.version}/styles/default.min.css"/>
+
+ <script src="{$contextPath}/webjars/highlightjs/${highlightjs.version}/highlight.min.js">
+ </script>
+ <script>
+ hljs.initHighlightingOnLoad();
+ </script>
+ </head>
+ <body>
+ <pre>
+ <code class="xml">
+ <xsl:apply-templates select="//xs:schema[position() = $schema-position]" mode="verb"/>
+ </code>
+ </pre>
+ </body>
+ </html>
+ </xsl:template>
+
+ <xsl:template match="*|@*" mode="verb">
+ <xsl:variable name="node-type">
+ <xsl:call-template name="node-type"/>
+ </xsl:variable>
+ <xsl:choose>
+ <xsl:when test="$node-type='element'">
+ <xsl:for-each select="ancestor::node()">
+ <xsl:if test="position() > 3">
+ <xsl:text>  </xsl:text>
+ </xsl:if>
+ </xsl:for-each>
+
+ <xsl:choose>
+ <xsl:when test="name() = 'xs:complexType' or name() = 'xs:simpleType'">
+ <a name="int_{@name}">
+ <xsl:text><</xsl:text>
+ <xsl:value-of select="name()"/>
+ </a>
+ </xsl:when>
+ <xsl:when test="name() = 'xs:element'">
+ <a name="{@name}">
+ <xsl:text><</xsl:text>
+ <xsl:value-of select="name()"/>
+ </a>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text><</xsl:text>
+ <xsl:value-of select="name()"/>
+ </xsl:otherwise>
+ </xsl:choose>
+
+ <xsl:apply-templates select="@*" mode="verb"/>
+
+ <xsl:choose>
+ <xsl:when test="count(descendant::node()) = 0">
+ <xsl:text>/> </xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text>> </xsl:text>
+
+ <xsl:apply-templates mode="verb"/>
+
+ <xsl:for-each select="ancestor::node()">
+ <xsl:if test="position() > 3">
+ <xsl:text>  </xsl:text>
+ </xsl:if>
+ </xsl:for-each>
+
+ <xsl:text></</xsl:text>
+ <xsl:value-of select="name()"/>
+ <xsl:text>> </xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:when>
+ <xsl:when test="$node-type='text'">
+ <xsl:value-of select="self::text()"/>
+ </xsl:when>
+ <xsl:when test="$node-type='attribute'">
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="name()"/>
+ <xsl:text>="</xsl:text>
+ <xsl:choose>
+ <xsl:when test="contains(., ':') and not(starts-with(., 'xs:'))">
+ <a>
+ <xsl:variable name="current" select="."/>
+ <xsl:attribute name="href">
+ <xsl:choose>
+ <xsl:when test="name() = 'ref'">#<xsl:value-of select="substring-after($current, ':')"/></xsl:when>
+ <xsl:otherwise>#int_<xsl:value-of select="substring-after($current, ':')"/></xsl:otherwise>
+ </xsl:choose>
+ </xsl:attribute>
+ <xsl:value-of select="$current"/>
+ </a>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="."/>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:text>"</xsl:text>
+ </xsl:when>
+ </xsl:choose>
+ </xsl:template>
+
+ <xsl:template name="node-type">
+ <xsl:param name="node" select="."/>
+ <xsl:apply-templates mode="nodetype" select="$node"/>
+ </xsl:template>
+ <xsl:template mode="nodetype" match="*">element</xsl:template>
+ <xsl:template mode="nodetype" match="@*">attribute</xsl:template>
+ <xsl:template mode="nodetype" match="text()">text</xsl:template>
+</xsl:stylesheet>
http://git-wip-us.apache.org/repos/asf/syncope/blob/b015c443/syncope620/server/workflow-api/pom.xml
----------------------------------------------------------------------
diff --git a/syncope620/server/workflow-api/pom.xml b/syncope620/server/workflow-api/pom.xml
index a36e65e..4108c85 100644
--- a/syncope620/server/workflow-api/pom.xml
+++ b/syncope620/server/workflow-api/pom.xml
@@ -30,7 +30,7 @@ under the License.
<name>Apache Syncope Server Workflow API</name>
<description>Apache Syncope Server Workflow API</description>
<groupId>org.apache.syncope.server</groupId>
- <artifactId>syncope-workflow-api</artifactId>
+ <artifactId>syncope-server-workflow-api</artifactId>
<packaging>jar</packaging>
<properties>
@@ -40,7 +40,7 @@ under the License.
<dependencies>
<dependency>
<groupId>org.apache.syncope.server</groupId>
- <artifactId>syncope-provisioning-api</artifactId>
+ <artifactId>syncope-server-provisioning-api</artifactId>
<version>${project.version}</version>
</dependency>
</dependencies>
http://git-wip-us.apache.org/repos/asf/syncope/blob/b015c443/syncope620/server/workflow-java/pom.xml
----------------------------------------------------------------------
diff --git a/syncope620/server/workflow-java/pom.xml b/syncope620/server/workflow-java/pom.xml
index 1595c44..541a541 100644
--- a/syncope620/server/workflow-java/pom.xml
+++ b/syncope620/server/workflow-java/pom.xml
@@ -30,7 +30,7 @@ under the License.
<name>Apache Syncope Server Workflow Java</name>
<description>Apache Syncope Server Workflow Java</description>
<groupId>org.apache.syncope.server</groupId>
- <artifactId>syncope-workflow-java</artifactId>
+ <artifactId>syncope-server-workflow-java</artifactId>
<packaging>jar</packaging>
<properties>
@@ -49,7 +49,7 @@ under the License.
<dependency>
<groupId>org.apache.syncope.server</groupId>
- <artifactId>syncope-workflow-api</artifactId>
+ <artifactId>syncope-server-workflow-api</artifactId>
<version>${project.version}</version>
</dependency>
</dependencies>
http://git-wip-us.apache.org/repos/asf/syncope/blob/b015c443/syncope620/server/workflow-java/src/main/resources/workflow.properties
----------------------------------------------------------------------
diff --git a/syncope620/server/workflow-java/src/main/resources/workflow.properties b/syncope620/server/workflow-java/src/main/resources/workflow.properties
new file mode 100644
index 0000000..a72e766
--- /dev/null
+++ b/syncope620/server/workflow-java/src/main/resources/workflow.properties
@@ -0,0 +1,18 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements. See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership. The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied. See the License for the
+# specific language governing permissions and limitations
+# under the License.
+uwfAdapter=org.apache.syncope.server.workflow.java.DefaultUserWorkflowAdapter
+rwfAdapter=org.apache.syncope.server.workflow.java.DefaultRoleWorkflowAdapter
\ No newline at end of file
http://git-wip-us.apache.org/repos/asf/syncope/blob/b015c443/syncope620/server/workflow-java/src/main/resources/workflowContext.xml
----------------------------------------------------------------------
diff --git a/syncope620/server/workflow-java/src/main/resources/workflowContext.xml b/syncope620/server/workflow-java/src/main/resources/workflowContext.xml
new file mode 100644
index 0000000..9323891
--- /dev/null
+++ b/syncope620/server/workflow-java/src/main/resources/workflowContext.xml
@@ -0,0 +1,28 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!--
+Licensed to the Apache Software Foundation (ASF) under one
+or more contributor license agreements. See the NOTICE file
+distributed with this work for additional information
+regarding copyright ownership. The ASF licenses this file
+to you under the Apache License, Version 2.0 (the
+"License"); you may not use this file except in compliance
+with the License. You may obtain a copy of the License at
+
+ http://www.apache.org/licenses/LICENSE-2.0
+
+Unless required by applicable law or agreed to in writing,
+software distributed under the License is distributed on an
+"AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+KIND, either express or implied. See the License for the
+specific language governing permissions and limitations
+under the License.
+-->
+<beans xmlns="http://www.springframework.org/schema/beans"
+ xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
+ xsi:schemaLocation="http://www.springframework.org/schema/beans
+ http://www.springframework.org/schema/beans/spring-beans.xsd">
+
+ <bean class="${uwfAdapter}"/>
+ <bean class="${rwfAdapter}"/>
+
+</beans>