You are viewing a plain text version of this content. The canonical link for it is here.
Posted to commits@flex.apache.org by ah...@apache.org on 2013/12/11 06:23:12 UTC
git commit: [flex-utilities] [refs/heads/develop] - Add Get and
Checksum tasks (MD5 only)
Updated Branches:
refs/heads/develop 8c90c12b4 -> 1a38abfd8
Add Get and Checksum tasks (MD5 only)
Project: http://git-wip-us.apache.org/repos/asf/flex-utilities/repo
Commit: http://git-wip-us.apache.org/repos/asf/flex-utilities/commit/1a38abfd
Tree: http://git-wip-us.apache.org/repos/asf/flex-utilities/tree/1a38abfd
Diff: http://git-wip-us.apache.org/repos/asf/flex-utilities/diff/1a38abfd
Branch: refs/heads/develop
Commit: 1a38abfd8e263cbc208b9164498506eef580feab
Parents: 8c90c12
Author: Alex Harui <ah...@apache.org>
Authored: Tue Dec 10 21:22:00 2013 -0800
Committer: Alex Harui <ah...@apache.org>
Committed: Tue Dec 10 21:22:00 2013 -0800
----------------------------------------------------------------------
ant_on_air/build.xml | 7 +-
ant_on_air/src/com/adobe/crypto/MD5Stream.as | 402 +++++++++++++++++++
ant_on_air/src/com/adobe/utils/IntUtil.as | 99 +++++
ant_on_air/src/org/apache/flex/ant/Ant.as | 5 +
.../src/org/apache/flex/ant/tags/Checksum.as | 145 +++++++
ant_on_air/src/org/apache/flex/ant/tags/Get.as | 139 +++++++
.../tags/supportClasses/FileSetTaskHandler.as | 1 +
ant_on_air/tests/AntTest.mxml | 20 +
ant_on_air/tests/test.xml | 21 +
9 files changed, 838 insertions(+), 1 deletion(-)
----------------------------------------------------------------------
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/build.xml
----------------------------------------------------------------------
diff --git a/ant_on_air/build.xml b/ant_on_air/build.xml
index 9ef3907..82cb24d 100644
--- a/ant_on_air/build.xml
+++ b/ant_on_air/build.xml
@@ -77,7 +77,12 @@
description="Compiles SWC"/>
<target name="init" depends="clean"
- description="Creates the deploy folders and sets app extension"/>
+ description="Creates the deploy folders and sets app extension">
+ <copy file="../installer/src/com/adobe/crypto/MD5Stream.as"
+ toFile="${SOURCE_DIR}/com/adobe/crypto/MD5Stream.as" />
+ <copy file="../installer/src/com/adobe/utils/IntUtil.as"
+ toFile="${SOURCE_DIR}/com/adobe/utils/IntUtil.as" />
+ </target>
<target name="clean" description="Cleans up old files.">
<delete dir="${LIBRARY_DIR}" failOnError="false" includeEmptyDirs="true" />
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/src/com/adobe/crypto/MD5Stream.as
----------------------------------------------------------------------
diff --git a/ant_on_air/src/com/adobe/crypto/MD5Stream.as b/ant_on_air/src/com/adobe/crypto/MD5Stream.as
new file mode 100644
index 0000000..7abeef0
--- /dev/null
+++ b/ant_on_air/src/com/adobe/crypto/MD5Stream.as
@@ -0,0 +1,402 @@
+/*
+ Copyright (c) 2008, Adobe Systems Incorporated
+ All rights reserved.
+
+ Redistribution and use in source and binary forms, with or without
+ modification, are permitted provided that the following conditions are
+ met:
+
+ * Redistributions of source code must retain the above copyright notice,
+ this list of conditions and the following disclaimer.
+
+ * Redistributions in binary form must reproduce the above copyright
+ notice, this list of conditions and the following disclaimer in the
+ documentation and/or other materials provided with the distribution.
+
+ * Neither the name of Adobe Systems Incorporated nor the names of its
+ contributors may be used to endorse or promote products derived from
+ this software without specific prior written permission.
+
+ THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+ IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+ THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+ PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
+ CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+ EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+ PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+ LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+ NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+ SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.crypto
+{
+ import com.adobe.utils.IntUtil;
+ import flash.utils.ByteArray;
+
+ /**
+ * Perform MD5 hash of an input stream in chunks. This class is
+ * based on com.adobe.crypto.MD5 and can process data in
+ * chunks. Both block creation and hash computation are done
+ * together for whatever input is available so that the memory
+ * overhead at a time is always fixed. Memory usage is governed by
+ * two parameters: one is the amount of data passed in to update()
+ * and the other is memoryBlockSize. The latter comes into play
+ * only when the memory window exceeds the pre allocated memory
+ * window of flash player. Usage: create an instance, call
+ * update(data) repeatedly for all chunks and finally complete()
+ * which will return the md5 hash.
+ */
+ public class MD5Stream
+ {
+ private static var mask:int = 0xFF;
+
+ private var arr:Array = [];
+
+ /* running count of length */
+ private var arrLen:int;
+
+ // initialize the md buffers
+ private var a:int = 1732584193;
+ private var b:int = -271733879;
+ private var c:int = -1732584194;
+ private var d:int = 271733878;
+
+ // variables to store previous values
+ private var aa:int;
+ private var bb:int;
+ private var cc:int;
+ private var dd:int;
+
+ /* index for data read */
+ private var arrIndexLen:int = 0;
+ /* index for hash computation */
+ private var arrProcessIndex:int = 0;
+ /* index for removing stale arr values */
+ private var cleanIndex:int = 0;
+
+ /**
+ * Change this value from the default (16384) in the range of
+ * MBs to actually affect GC as GC allocates in pools of
+ * memory */
+ public var memoryBlockSize:int = 16384;
+
+
+ public function MD5Stream()
+ {
+
+ }
+
+
+ /**
+ * Pass in chunks of the input data with update(), call
+ * complete() with an optional chunk which will return the
+ * final hash. Equivalent to the way
+ * java.security.MessageDigest works.
+ *
+ * @param input The optional bytearray chunk which is the final part of the input
+ * @return A string containing the hash value
+ * @langversion ActionScript 3.0
+ * @playerversion Flash 8.5
+ * @tiptext
+ */
+ public function complete(input:ByteArray=null):String
+ {
+ if ( arr.length == 0 )
+ {
+ if ( input == null )
+ {
+ throw new Error("null input to complete without prior call to update. At least an empty bytearray must be passed.");
+ }
+ }
+
+ if ( input != null )
+ {
+ readIntoArray(input);
+ }
+
+ //pad, append length
+ padArray(arrLen);
+
+ hashRemainingChunks(false);
+
+ var res:String = IntUtil.toHex( a ) + IntUtil.toHex( b ) +
+ IntUtil.toHex( c ) + IntUtil.toHex( d );
+ resetFields();
+
+ return res;
+ }
+
+ /**
+ * Pass in chunks of the input data with update(), call
+ * complete() with an optional chunk which will return the
+ * final hash. Equivalent to the way
+ * java.security.MessageDigest works.
+ *
+ * @param input The bytearray chunk to perform the hash on
+ * @langversion ActionScript 3.0
+ * @playerversion Flash 8.5
+ * @tiptext
+ */
+ public function update(input:ByteArray):void
+ {
+ readIntoArray(input);
+ hashRemainingChunks();
+ }
+
+ /**
+ * Re-initialize this instance for use to perform hashing on
+ * another input stream. This is called automatically by
+ * complete().
+ *
+ * @langversion ActionScript 3.0
+ * @playerversion Flash 8.5
+ * @tiptext
+ */
+ public function resetFields():void
+ {
+ //truncate array
+ arr.length = 0;
+ arrLen = 0;
+
+ // initialize the md buffers
+ a = 1732584193;
+ b = -271733879;
+ c = -1732584194;
+ d = 271733878;
+
+ // variables to store previous values
+ aa = 0;
+ bb = 0;
+ cc = 0;
+ dd = 0;
+
+ arrIndexLen = 0;
+ arrProcessIndex = 0;
+ cleanIndex = 0;
+ }
+
+ /** read into arr and free up used blocks of arr */
+ private function readIntoArray(input:ByteArray):void
+ {
+ var closestChunkLen:int = input.length * 8;
+ arrLen += closestChunkLen;
+
+ /* clean up memory. if there are entries in the array that
+ * are already processed and the amount is greater than
+ * memoryBlockSize, create a new array, copy the last
+ * block into it and let the old one get picked up by
+ * GC. */
+ if ( arrProcessIndex - cleanIndex > memoryBlockSize )
+ {
+ var newarr:Array= new Array();
+
+ /* AS Arrays in sparse arrays. arr[2002] can exist
+ * without values for arr[0] - arr[2001] */
+ for ( var j:int = arrProcessIndex; j < arr.length; j++ )
+ {
+ newarr[j] = arr[j];
+ }
+
+ cleanIndex = arrProcessIndex;
+ arr = null;
+ arr = newarr;
+ }
+
+ for ( var k:int = 0; k < closestChunkLen; k+=8 )
+ {
+ //discard high bytes (convert to uint)
+ arr[ int(arrIndexLen >> 5) ] |= ( input[ k / 8 ] & mask ) << ( arrIndexLen % 32 );
+ arrIndexLen += 8;
+ }
+
+
+ }
+
+ private function hashRemainingChunks(bUpdate:Boolean=true):void
+ {
+ var len:int = arr.length;
+
+ /* leave a 16 word block untouched if we are called from
+ * update. This is because, padArray() can modify the last
+ * block and this modification has to happen before we
+ * compute the hash. */
+ if ( bUpdate )
+ {
+ len -= 16;
+ }
+
+ /* don't do anything if don't have a 16 word block. */
+ if ( arrProcessIndex >= len || len - arrProcessIndex < 15 )
+ {
+ return;
+ }
+
+
+ for ( var i:int = arrProcessIndex; i < len ; i += 16, arrProcessIndex += 16)
+ {
+ // save previous values
+ aa = a;
+ bb = b;
+ cc = c;
+ dd = d;
+
+ // Round 1
+ a = ff( a, b, c, d, arr[int(i+ 0)], 7, -680876936 ); // 1
+ d = ff( d, a, b, c, arr[int(i+ 1)], 12, -389564586 ); // 2
+ c = ff( c, d, a, b, arr[int(i+ 2)], 17, 606105819 ); // 3
+ b = ff( b, c, d, a, arr[int(i+ 3)], 22, -1044525330 ); // 4
+ a = ff( a, b, c, d, arr[int(i+ 4)], 7, -176418897 ); // 5
+ d = ff( d, a, b, c, arr[int(i+ 5)], 12, 1200080426 ); // 6
+ c = ff( c, d, a, b, arr[int(i+ 6)], 17, -1473231341 ); // 7
+ b = ff( b, c, d, a, arr[int(i+ 7)], 22, -45705983 ); // 8
+ a = ff( a, b, c, d, arr[int(i+ 8)], 7, 1770035416 ); // 9
+ d = ff( d, a, b, c, arr[int(i+ 9)], 12, -1958414417 ); // 10
+ c = ff( c, d, a, b, arr[int(i+10)], 17, -42063 ); // 11
+ b = ff( b, c, d, a, arr[int(i+11)], 22, -1990404162 ); // 12
+ a = ff( a, b, c, d, arr[int(i+12)], 7, 1804603682 ); // 13
+ d = ff( d, a, b, c, arr[int(i+13)], 12, -40341101 ); // 14
+ c = ff( c, d, a, b, arr[int(i+14)], 17, -1502002290 ); // 15
+ b = ff( b, c, d, a, arr[int(i+15)], 22, 1236535329 ); // 16
+
+ // Round 2
+ a = gg( a, b, c, d, arr[int(i+ 1)], 5, -165796510 ); // 17
+ d = gg( d, a, b, c, arr[int(i+ 6)], 9, -1069501632 ); // 18
+ c = gg( c, d, a, b, arr[int(i+11)], 14, 643717713 ); // 19
+ b = gg( b, c, d, a, arr[int(i+ 0)], 20, -373897302 ); // 20
+ a = gg( a, b, c, d, arr[int(i+ 5)], 5, -701558691 ); // 21
+ d = gg( d, a, b, c, arr[int(i+10)], 9, 38016083 ); // 22
+ c = gg( c, d, a, b, arr[int(i+15)], 14, -660478335 ); // 23
+ b = gg( b, c, d, a, arr[int(i+ 4)], 20, -405537848 ); // 24
+ a = gg( a, b, c, d, arr[int(i+ 9)], 5, 568446438 ); // 25
+ d = gg( d, a, b, c, arr[int(i+14)], 9, -1019803690 ); // 26
+ c = gg( c, d, a, b, arr[int(i+ 3)], 14, -187363961 ); // 27
+ b = gg( b, c, d, a, arr[int(i+ 8)], 20, 1163531501 ); // 28
+ a = gg( a, b, c, d, arr[int(i+13)], 5, -1444681467 ); // 29
+ d = gg( d, a, b, c, arr[int(i+ 2)], 9, -51403784 ); // 30
+ c = gg( c, d, a, b, arr[int(i+ 7)], 14, 1735328473 ); // 31
+ b = gg( b, c, d, a, arr[int(i+12)], 20, -1926607734 ); // 32
+
+ // Round 3
+ a = hh( a, b, c, d, arr[int(i+ 5)], 4, -378558 ); // 33
+ d = hh( d, a, b, c, arr[int(i+ 8)], 11, -2022574463 ); // 34
+ c = hh( c, d, a, b, arr[int(i+11)], 16, 1839030562 ); // 35
+ b = hh( b, c, d, a, arr[int(i+14)], 23, -35309556 ); // 36
+ a = hh( a, b, c, d, arr[int(i+ 1)], 4, -1530992060 ); // 37
+ d = hh( d, a, b, c, arr[int(i+ 4)], 11, 1272893353 ); // 38
+ c = hh( c, d, a, b, arr[int(i+ 7)], 16, -155497632 ); // 39
+ b = hh( b, c, d, a, arr[int(i+10)], 23, -1094730640 ); // 40
+ a = hh( a, b, c, d, arr[int(i+13)], 4, 681279174 ); // 41
+ d = hh( d, a, b, c, arr[int(i+ 0)], 11, -358537222 ); // 42
+ c = hh( c, d, a, b, arr[int(i+ 3)], 16, -722521979 ); // 43
+ b = hh( b, c, d, a, arr[int(i+ 6)], 23, 76029189 ); // 44
+ a = hh( a, b, c, d, arr[int(i+ 9)], 4, -640364487 ); // 45
+ d = hh( d, a, b, c, arr[int(i+12)], 11, -421815835 ); // 46
+ c = hh( c, d, a, b, arr[int(i+15)], 16, 530742520 ); // 47
+ b = hh( b, c, d, a, arr[int(i+ 2)], 23, -995338651 ); // 48
+
+ // Round 4
+ a = ii( a, b, c, d, arr[int(i+ 0)], 6, -198630844 ); // 49
+ d = ii( d, a, b, c, arr[int(i+ 7)], 10, 1126891415 ); // 50
+ c = ii( c, d, a, b, arr[int(i+14)], 15, -1416354905 ); // 51
+ b = ii( b, c, d, a, arr[int(i+ 5)], 21, -57434055 ); // 52
+ a = ii( a, b, c, d, arr[int(i+12)], 6, 1700485571 ); // 53
+ d = ii( d, a, b, c, arr[int(i+ 3)], 10, -1894986606 ); // 54
+ c = ii( c, d, a, b, arr[int(i+10)], 15, -1051523 ); // 55
+ b = ii( b, c, d, a, arr[int(i+ 1)], 21, -2054922799 ); // 56
+ a = ii( a, b, c, d, arr[int(i+ 8)], 6, 1873313359 ); // 57
+ d = ii( d, a, b, c, arr[int(i+15)], 10, -30611744 ); // 58
+ c = ii( c, d, a, b, arr[int(i+ 6)], 15, -1560198380 ); // 59
+ b = ii( b, c, d, a, arr[int(i+13)], 21, 1309151649 ); // 60
+ a = ii( a, b, c, d, arr[int(i+ 4)], 6, -145523070 ); // 61
+ d = ii( d, a, b, c, arr[int(i+11)], 10, -1120210379 ); // 62
+ c = ii( c, d, a, b, arr[int(i+ 2)], 15, 718787259 ); // 63
+ b = ii( b, c, d, a, arr[int(i+ 9)], 21, -343485551 ); // 64
+
+ a += aa;
+ b += bb;
+ c += cc;
+ d += dd;
+
+ }
+
+ }
+
+ private function padArray(len:int):void
+ {
+ arr[ int(len >> 5) ] |= 0x80 << ( len % 32 );
+ arr[ int(( ( ( len + 64 ) >>> 9 ) << 4 ) + 14) ] = len;
+ arrLen = arr.length;
+ }
+
+ /* Code below same as com.adobe.crypto.MD5 */
+
+ /**
+ * Auxiliary function f as defined in RFC
+ */
+ private static function f( x:int, y:int, z:int ):int {
+ return ( x & y ) | ( (~x) & z );
+ }
+
+ /**
+ * Auxiliary function g as defined in RFC
+ */
+ private static function g( x:int, y:int, z:int ):int {
+ return ( x & z ) | ( y & (~z) );
+ }
+
+ /**
+ * Auxiliary function h as defined in RFC
+ */
+ private static function h( x:int, y:int, z:int ):int {
+ return x ^ y ^ z;
+ }
+
+ /**
+ * Auxiliary function i as defined in RFC
+ */
+ private static function i( x:int, y:int, z:int ):int {
+ return y ^ ( x | (~z) );
+ }
+
+ /**
+ * A generic transformation function. The logic of ff, gg, hh, and
+ * ii are all the same, minus the function used, so pull that logic
+ * out and simplify the method bodies for the transoformation functions.
+ */
+ private static function transform( func:Function, a:int, b:int, c:int, d:int, x:int, s:int, t:int):int {
+ var tmp:int = a + int( func( b, c, d ) ) + x + t;
+ return IntUtil.rol( tmp, s ) + b;
+ }
+
+ /**
+ * ff transformation function
+ */
+ private static function ff ( a:int, b:int, c:int, d:int, x:int, s:int, t:int ):int {
+ return transform( f, a, b, c, d, x, s, t );
+ }
+
+ /**
+ * gg transformation function
+ */
+ private static function gg ( a:int, b:int, c:int, d:int, x:int, s:int, t:int ):int {
+ return transform( g, a, b, c, d, x, s, t );
+ }
+
+ /**
+ * hh transformation function
+ */
+ private static function hh ( a:int, b:int, c:int, d:int, x:int, s:int, t:int ):int {
+ return transform( h, a, b, c, d, x, s, t );
+ }
+
+ /**
+ * ii transformation function
+ */
+ private static function ii ( a:int, b:int, c:int, d:int, x:int, s:int, t:int ):int {
+ return transform( i, a, b, c, d, x, s, t );
+ }
+
+ }
+}
\ No newline at end of file
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/src/com/adobe/utils/IntUtil.as
----------------------------------------------------------------------
diff --git a/ant_on_air/src/com/adobe/utils/IntUtil.as b/ant_on_air/src/com/adobe/utils/IntUtil.as
new file mode 100644
index 0000000..c7bae7c
--- /dev/null
+++ b/ant_on_air/src/com/adobe/utils/IntUtil.as
@@ -0,0 +1,99 @@
+/*
+ Copyright (c) 2008, Adobe Systems Incorporated
+ All rights reserved.
+
+ Redistribution and use in source and binary forms, with or without
+ modification, are permitted provided that the following conditions are
+ met:
+
+ * Redistributions of source code must retain the above copyright notice,
+ this list of conditions and the following disclaimer.
+
+ * Redistributions in binary form must reproduce the above copyright
+ notice, this list of conditions and the following disclaimer in the
+ documentation and/or other materials provided with the distribution.
+
+ * Neither the name of Adobe Systems Incorporated nor the names of its
+ contributors may be used to endorse or promote products derived from
+ this software without specific prior written permission.
+
+ THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+ IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+ THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+ PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR
+ CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+ EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+ PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+ PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+ LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+ NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+ SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+package com.adobe.utils {
+
+ import flash.utils.Endian;
+
+ /**
+ * Contains reusable methods for operations pertaining
+ * to int values.
+ */
+ public class IntUtil {
+
+ /**
+ * Rotates x left n bits
+ *
+ * @langversion ActionScript 3.0
+ * @playerversion Flash 9.0
+ * @tiptext
+ */
+ public static function rol ( x:int, n:int ):int {
+ return ( x << n ) | ( x >>> ( 32 - n ) );
+ }
+
+ /**
+ * Rotates x right n bits
+ *
+ * @langversion ActionScript 3.0
+ * @playerversion Flash 9.0
+ * @tiptext
+ */
+ public static function ror ( x:int, n:int ):uint {
+ var nn:int = 32 - n;
+ return ( x << nn ) | ( x >>> ( 32 - nn ) );
+ }
+
+ /** String for quick lookup of a hex character based on index */
+ private static var hexChars:String = "0123456789abcdef";
+
+ /**
+ * Outputs the hex value of a int, allowing the developer to specify
+ * the endinaness in the process. Hex output is lowercase.
+ *
+ * @param n The int value to output as hex
+ * @param bigEndian Flag to output the int as big or little endian
+ * @return A string of length 8 corresponding to the
+ * hex representation of n ( minus the leading "0x" )
+ * @langversion ActionScript 3.0
+ * @playerversion Flash 9.0
+ * @tiptext
+ */
+ public static function toHex( n:int, bigEndian:Boolean = false ):String {
+ var s:String = "";
+
+ if ( bigEndian ) {
+ for ( var i:int = 0; i < 4; i++ ) {
+ s += hexChars.charAt( ( n >> ( ( 3 - i ) * 8 + 4 ) ) & 0xF )
+ + hexChars.charAt( ( n >> ( ( 3 - i ) * 8 ) ) & 0xF );
+ }
+ } else {
+ for ( var x:int = 0; x < 4; x++ ) {
+ s += hexChars.charAt( ( n >> ( x * 8 + 4 ) ) & 0xF )
+ + hexChars.charAt( ( n >> ( x * 8 ) ) & 0xF );
+ }
+ }
+
+ return s;
+ }
+ }
+
+}
\ No newline at end of file
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/src/org/apache/flex/ant/Ant.as
----------------------------------------------------------------------
diff --git a/ant_on_air/src/org/apache/flex/ant/Ant.as b/ant_on_air/src/org/apache/flex/ant/Ant.as
index e0121d5..1dc97c6 100644
--- a/ant_on_air/src/org/apache/flex/ant/Ant.as
+++ b/ant_on_air/src/org/apache/flex/ant/Ant.as
@@ -97,6 +97,11 @@ package org.apache.flex.ant
}
}
+ /**
+ * the instance of the class dispatching progress events
+ */
+ public var progressClass:Object;
+
private var context:Object;
public static var ant:Ant;
public static var project:Project;
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/src/org/apache/flex/ant/tags/Checksum.as
----------------------------------------------------------------------
diff --git a/ant_on_air/src/org/apache/flex/ant/tags/Checksum.as b/ant_on_air/src/org/apache/flex/ant/tags/Checksum.as
new file mode 100644
index 0000000..dde7631
--- /dev/null
+++ b/ant_on_air/src/org/apache/flex/ant/tags/Checksum.as
@@ -0,0 +1,145 @@
+////////////////////////////////////////////////////////////////////////////////
+//
+// Licensed to the Apache Software Foundation (ASF) under one or more
+// contributor license agreements. See the NOTICE file distributed with
+// this work for additional information regarding copyright ownership.
+// The ASF licenses this file to You under the Apache License, Version 2.0
+// (the "License"); you may not use this file except in compliance with
+// the License. You may obtain a copy of the License at
+//
+// http://www.apache.org/licenses/LICENSE-2.0
+//
+// Unless required by applicable law or agreed to in writing, software
+// distributed under the License is distributed on an "AS IS" BASIS,
+// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+// See the License for the specific language governing permissions and
+// limitations under the License.
+//
+////////////////////////////////////////////////////////////////////////////////
+package org.apache.flex.ant.tags
+{
+ import com.adobe.crypto.MD5Stream;
+
+ import flash.events.Event;
+ import flash.events.ProgressEvent;
+ import flash.filesystem.File;
+ import flash.filesystem.FileMode;
+ import flash.filesystem.FileStream;
+ import flash.utils.ByteArray;
+
+ import mx.core.IFlexModuleFactory;
+
+ import org.apache.flex.ant.Ant;
+ import org.apache.flex.ant.tags.supportClasses.TaskHandler;
+
+ [Mixin]
+ public class Checksum extends TaskHandler
+ {
+ public static function init(mf:IFlexModuleFactory):void
+ {
+ Ant.antTagProcessors["checksum"] = Checksum;
+ }
+
+ public function Checksum()
+ {
+ super();
+ }
+
+ private var file:String;
+ private var toDir:String;
+ private var fileExt:String = ".md5";
+ private var verifyproperty:String;
+ private var readbuffersize:int = 8192;
+
+ override protected function processAttribute(name:String, value:String):void
+ {
+ if (name == "file")
+ file = value;
+ else if (name == "todir")
+ toDir = value;
+ else if (name == "fileext")
+ fileExt = value;
+ else if (name == "verifyproperty")
+ verifyproperty = value;
+ else if (name == "readbuffersize")
+ verifyproperty = value;
+ else
+ super.processAttribute(name, value);
+ }
+
+ private var md5:MD5Stream;
+ private var fs:FileStream;
+
+ override public function execute(callbackMode:Boolean):Boolean
+ {
+ super.execute(callbackMode);
+
+ var f:File = File.applicationDirectory.resolvePath(file);
+ fs = new FileStream();
+ fs.open(f, FileMode.READ);
+ md5 = new MD5Stream();
+ md5.resetFields();
+ getSum();
+ return false;
+ }
+
+ private function getSum():void
+ {
+ if (fs.bytesAvailable == 0)
+ {
+ sumComplete();
+ return;
+ }
+ var ba:ByteArray = new ByteArray();
+ fs.readBytes(ba, 0, Math.max(readbuffersize, fs.bytesAvailable));
+ md5.update(ba);
+ ant.functionToCall = getSum;
+ ant.progressClass = this;
+ ant.dispatchEvent(new ProgressEvent(ProgressEvent.PROGRESS, false, false,
+ fs.position, fs.position + fs.bytesAvailable));
+ }
+
+ private var sum:String;
+
+ private function sumComplete():void
+ {
+ var sumFile:File = getSumFile();
+ var fs:FileStream = new FileStream();
+ if (verifyproperty)
+ {
+ fs.open(sumFile, FileMode.READ);
+ var expected:String = fs.readUTFBytes(fs.bytesAvailable);
+ fs.close();
+ if (sum != expected)
+ context[verifyproperty] = "false";
+ else
+ context[verifyproperty] = "true";
+ }
+ else
+ {
+ fs.open(sumFile, FileMode.WRITE);
+ fs.writeUTFBytes(sum);
+ fs.close();
+ }
+
+ dispatchEvent(new Event(Event.COMPLETE));
+ }
+
+ private function getSumFile():File
+ {
+ var sumFile:File = File.applicationDirectory.resolvePath(toDir);
+ if (sumFile.isDirectory)
+ {
+ var fileName:String = file + fileExt;
+ var c:int = fileName.indexOf("?");
+ if (c != -1)
+ fileName = fileName.substring(0, c);
+ c = fileName.lastIndexOf("/");
+ if (c != -1)
+ fileName = fileName.substr(c + 1);
+ sumFile = sumFile.resolvePath(fileName);
+ }
+ return sumFile;
+ }
+ }
+}
\ No newline at end of file
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/src/org/apache/flex/ant/tags/Get.as
----------------------------------------------------------------------
diff --git a/ant_on_air/src/org/apache/flex/ant/tags/Get.as b/ant_on_air/src/org/apache/flex/ant/tags/Get.as
new file mode 100644
index 0000000..d11c194
--- /dev/null
+++ b/ant_on_air/src/org/apache/flex/ant/tags/Get.as
@@ -0,0 +1,139 @@
+////////////////////////////////////////////////////////////////////////////////
+//
+// Licensed to the Apache Software Foundation (ASF) under one or more
+// contributor license agreements. See the NOTICE file distributed with
+// this work for additional information regarding copyright ownership.
+// The ASF licenses this file to You under the Apache License, Version 2.0
+// (the "License"); you may not use this file except in compliance with
+// the License. You may obtain a copy of the License at
+//
+// http://www.apache.org/licenses/LICENSE-2.0
+//
+// Unless required by applicable law or agreed to in writing, software
+// distributed under the License is distributed on an "AS IS" BASIS,
+// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+// See the License for the specific language governing permissions and
+// limitations under the License.
+//
+////////////////////////////////////////////////////////////////////////////////
+package org.apache.flex.ant.tags
+{
+ import flash.events.Event;
+ import flash.events.IOErrorEvent;
+ import flash.events.ProgressEvent;
+ import flash.events.SecurityErrorEvent;
+ import flash.filesystem.File;
+ import flash.filesystem.FileMode;
+ import flash.filesystem.FileStream;
+ import flash.net.URLLoader;
+ import flash.net.URLLoaderDataFormat;
+ import flash.net.URLRequest;
+ import flash.utils.ByteArray;
+
+ import mx.core.IFlexModuleFactory;
+
+ import org.apache.flex.ant.Ant;
+ import org.apache.flex.ant.tags.supportClasses.TaskHandler;
+ import org.apache.flex.xml.ITagHandler;
+
+ [Mixin]
+ public class Get extends TaskHandler
+ {
+ public static function init(mf:IFlexModuleFactory):void
+ {
+ Ant.antTagProcessors["get"] = Get;
+ }
+
+ public function Get()
+ {
+ super();
+ }
+
+ private var src:String;
+ private var dest:String;
+ private var skipexisting:Boolean;
+
+ override protected function processAttribute(name:String, value:String):void
+ {
+ if (name == "src")
+ src = value;
+ else if (name == "dest")
+ dest = value;
+ else if (name == "skipexisting")
+ skipexisting = value == "true";
+ else
+ super.processAttribute(name, value);
+ }
+
+ private var urlLoader:URLLoader;
+
+ override public function execute(callbackMode:Boolean):Boolean
+ {
+ super.execute(callbackMode);
+
+ if (skipexisting)
+ {
+ var destFile:File = getDestFile();
+ if (destFile.exists)
+ return true;
+ }
+
+ urlLoader = new URLLoader();
+ urlLoader.load(new URLRequest(src));
+ urlLoader.dataFormat = URLLoaderDataFormat.BINARY;
+ urlLoader.addEventListener(Event.COMPLETE, completeHandler);
+ urlLoader.addEventListener(ProgressEvent.PROGRESS, progressHandler);
+ urlLoader.addEventListener(IOErrorEvent.IO_ERROR, ioErrorEventHandler);
+ urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
+ return false;
+ }
+
+ private function ioErrorEventHandler(event:IOErrorEvent):void
+ {
+ Ant.project.status = false;
+ dispatchEvent(new Event(Event.COMPLETE));
+ event.preventDefault();
+ }
+
+ private function securityErrorHandler(event:SecurityErrorEvent):void
+ {
+ Ant.project.status = false;
+ dispatchEvent(new Event(Event.COMPLETE));
+ event.preventDefault();
+ }
+
+ private function progressHandler(event:ProgressEvent):void
+ {
+ ant.progressClass = this;
+ ant.dispatchEvent(event);
+ }
+
+ private function completeHandler(event:Event):void
+ {
+ var destFile:File = getDestFile();
+ var fs:FileStream = new FileStream();
+ fs.open(destFile, FileMode.WRITE);
+ fs.writeBytes(urlLoader.data as ByteArray);
+ fs.close();
+
+ dispatchEvent(new Event(Event.COMPLETE));
+ }
+
+ private function getDestFile():File
+ {
+ var destFile:File = File.applicationDirectory.resolvePath(dest);
+ if (destFile.isDirectory)
+ {
+ var fileName:String = src;
+ var c:int = fileName.indexOf("?");
+ if (c != -1)
+ fileName = fileName.substring(0, c);
+ c = fileName.lastIndexOf("/");
+ if (c != -1)
+ fileName = fileName.substr(c + 1);
+ destFile = destFile.resolvePath(fileName);
+ }
+ return destFile;
+ }
+ }
+}
\ No newline at end of file
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/src/org/apache/flex/ant/tags/supportClasses/FileSetTaskHandler.as
----------------------------------------------------------------------
diff --git a/ant_on_air/src/org/apache/flex/ant/tags/supportClasses/FileSetTaskHandler.as b/ant_on_air/src/org/apache/flex/ant/tags/supportClasses/FileSetTaskHandler.as
index a5519c4..d35c8a2 100644
--- a/ant_on_air/src/org/apache/flex/ant/tags/supportClasses/FileSetTaskHandler.as
+++ b/ant_on_air/src/org/apache/flex/ant/tags/supportClasses/FileSetTaskHandler.as
@@ -117,6 +117,7 @@ package org.apache.flex.ant.tags.supportClasses
while (currentFile < currentList.length)
{
+ ant.progressClass = this;
var fileName:String = currentList[currentFile++];
ant.dispatchEvent(new ProgressEvent(ProgressEvent.PROGRESS, false, false, thisFile, totalFiles));
actOnFile(currentDir.nativePath, fileName);
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/tests/AntTest.mxml
----------------------------------------------------------------------
diff --git a/ant_on_air/tests/AntTest.mxml b/ant_on_air/tests/AntTest.mxml
index f3daaa7..6d42812 100644
--- a/ant_on_air/tests/AntTest.mxml
+++ b/ant_on_air/tests/AntTest.mxml
@@ -30,6 +30,9 @@ limitations under the License.
// all tag handlers
import AntClasses; AntClasses;
import org.apache.flex.ant.Ant;
+ import org.apache.flex.ant.tags.Copy;
+ import org.apache.flex.ant.tags.Get;
+ import org.apache.flex.ant.tags.Checksum;
private function checkargs(event:InvokeEvent):void
{
@@ -53,12 +56,29 @@ limitations under the License.
if (!ant.processXMLFile(file, context, true))
{
ant.addEventListener(Event.COMPLETE, completeHandler);
+ ant.addEventListener(ProgressEvent.PROGRESS, progressEventHandler);
pb.source = ant;
}
else
completeHandler(null);
}
+ private function progressEventHandler(event:ProgressEvent):void
+ {
+ if (ant.progressClass is Copy)
+ {
+ pb.label = "Copying %1 of %2";
+ }
+ else if (ant.progressClass is Get)
+ {
+ pb.label = "Downloading bytes %1 of %2";
+ }
+ else if (ant.progressClass is Checksum)
+ {
+ pb.label = "Verifying download: bytes %1 of %2";
+ }
+ }
+
private function completeHandler(event:Event):void
{
if (Ant.project.status)
http://git-wip-us.apache.org/repos/asf/flex-utilities/blob/1a38abfd/ant_on_air/tests/test.xml
----------------------------------------------------------------------
diff --git a/ant_on_air/tests/test.xml b/ant_on_air/tests/test.xml
index df33ee7..ba2b1a9 100644
--- a/ant_on_air/tests/test.xml
+++ b/ant_on_air/tests/test.xml
@@ -86,6 +86,27 @@
</condition>
</fail>
<echo>copied.xml ${copied.doesnt.exist.after.delete}. Should NOT say: didn't get deleted</echo>
+ <get src="http://archive.apache.org/dist/creadur/apache-rat-0.10/apache-rat-0.10-src.zip"
+ dest="${basedir}/temp" />
+ <fail message="apache-rat-0.10-src.zip was not copied to temp">
+ <condition>
+ <not>
+ <available file="${basedir}/temp/apache-rat-0.10-src.zip" />
+ </not>
+ </condition>
+ </fail>
+ <get src="http://archive.apache.org/dist/creadur/apache-rat-0.10/apache-rat-0.10-src.zip.md5"
+ dest="${basedir}/temp" />
+ <fail message="apache-rat-0.10-src.zip.md5 was not copied to temp">
+ <condition>
+ <not>
+ <available file="${basedir}/temp/apache-rat-0.10-src.zip.md5" />
+ </not>
+ </condition>
+ </fail>
+ <checksum file="${basedir}/temp/apache-rat-0.10-src.zip" todir="${basedir}/temp"
+ verifyproperty="rat.md5" />
+ <echo>rat checksum match = ${rat.md5}</echo>
<delete dir="${basedir}/temp" />
<available file="${basedir}/temp/org/apache/flex/ant/tags/Project.as" property="project.doesnt.exist.after.delete" value="didn't get deleted" />
<fail message="temp/copied.xml was not deleted">
Re: git commit: [flex-utilities] [refs/heads/develop] - Add Get and Checksum tasks (MD5 only)
Posted by Justin Mclean <ju...@classsoftware.com>.
Hi,
> It looked like it was already in there for Installer,
The installer downloads it as part of the build process, it's not in git. See the get-as3commons.swc target in teh build.xml file.
It's not been donated so I'm fairly certain that means it can't be in our repo, but the license is compatable (BSD) so we can use it.
Thanks,
Justin
Re: git commit: [flex-utilities] [refs/heads/develop] - Add Get and
Checksum tasks (MD5 only)
Posted by Alex Harui <ah...@adobe.com>.
That's the part of IP management I'm still not 100% certain on. On
legal-discuss we did get permission to include CC-BY icons as long as we
mention it in NOTICE. The MD5 code is also Category A I think so
theoretically we can do the same, but I still think Roy says no to storing
it in the repo without donation forms.
Let's see if any mentors chime in.
-Alex
On 12/10/13 10:19 PM, "Justin Mclean" <ju...@classsoftware.com> wrote:
>Hi,
>
>> It looked like it was already in there for Installer
>Actually it does look that way (it's not part of AS3commons) - opps. We
>don't own the IP so that's probably an issue.
>
>Justin
Re: git commit: [flex-utilities] [refs/heads/develop] - Add Get and Checksum tasks (MD5 only)
Posted by Justin Mclean <ju...@classsoftware.com>.
Hi,
> It looked like it was already in there for Installer
Actually it does look that way (it's not part of AS3commons) - opps. We don't own the IP so that's probably an issue.
Justin
Re: git commit: [flex-utilities] [refs/heads/develop] - Add Get and
Checksum tasks (MD5 only)
Posted by Alex Harui <ah...@adobe.com>.
It looked like it was already in there for Installer, so I just copied
what it was doing. It does seem like we should download it though. I'll
try to remember to revisit.
-Alex
On 12/10/13 9:34 PM, "Justin Mclean" <ju...@classsoftware.com> wrote:
>Hi,
>
>Just noticed "Copyright (c) 2008, Adobe Systems Incorporated" in there. I
>assume that's the MD5 code from AS3corelib? Does the code also need to be
>in our repo?
>
>Thanks,
>Justin
Re: git commit: [flex-utilities] [refs/heads/develop] - Add Get and Checksum tasks (MD5 only)
Posted by Justin Mclean <ju...@classsoftware.com>.
Hi,
Just noticed "Copyright (c) 2008, Adobe Systems Incorporated" in there. I assume that's the MD5 code from AS3corelib? Does the code also need to be in our repo?
Thanks,
Justin