You are viewing a plain text version of this content. The canonical link for it is here.
Posted to commits@kvrocks.apache.org by hu...@apache.org on 2022/05/11 12:54:31 UTC
[incubator-kvrocks] branch unstable updated: Use FetchContent instead of ExternalProject and git submodules in CMake (#564)
This is an automated email from the ASF dual-hosted git repository.
hulk pushed a commit to branch unstable
in repository https://gitbox.apache.org/repos/asf/incubator-kvrocks.git
The following commit(s) were added to refs/heads/unstable by this push:
new a51be76 Use FetchContent instead of ExternalProject and git submodules in CMake (#564)
a51be76 is described below
commit a51be769f8d7f8b73ecac3cfe8183b7ec1c69193
Author: Twice <i...@twice.moe>
AuthorDate: Wed May 11 20:54:27 2022 +0800
Use FetchContent instead of ExternalProject and git submodules in CMake (#564)
Currently, we are using git submodules to manage external libraries which
need to pull full git histories. CMake gives a light way `FetchContent` to handle
this scenario after 3.11, we can only fetch the specify tag or commit instead of full histories.
Another minor change was that the CMake minimal required will be 3.13 to support the
FetchContent instruction.
Co-authored-by: tison <wa...@gmail.com>
Co-authored-by: hulk <hu...@gmail.com>
---
CMakeLists.txt | 34 ++++-----------
build.sh | 7 ++--
cmake/gflags.cmake | 60 --------------------------
cmake/glog.cmake | 52 +++++------------------
cmake/gtest.cmake | 42 +++++--------------
cmake/jemalloc.cmake | 57 ++++++++++++-------------
cmake/libevent.cmake | 51 +++++++++-------------
cmake/lua.cmake | 49 ++++++++++------------
cmake/modules/FindJeMalloc.cmake | 25 +++++++++++
cmake/modules/SnappyConfig.cmake | 24 +++++++++++
cmake/rocksdb.cmake | 91 ++++++++++++++--------------------------
cmake/snappy.cmake | 52 +++++------------------
cmake/utils.cmake | 43 +++++++++++++++++++
13 files changed, 237 insertions(+), 350 deletions(-)
diff --git a/CMakeLists.txt b/CMakeLists.txt
index b999564..d744244 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -15,7 +15,7 @@
# specific language governing permissions and limitations
# under the License.
-cmake_minimum_required(VERSION 3.10)
+cmake_minimum_required(VERSION 3.13)
project(kvrocks
VERSION 999.999.999
DESCRIPTION "NoSQL which based on rocksdb and compatible with the Redis protocol"
@@ -40,30 +40,24 @@ endif ()
if(NOT DISABLE_JEMALLOC)
include(cmake/jemalloc.cmake)
- list(APPEND EXTERNAL_LIBS PRIVATE ${jemalloc_LIBRARIES})
- list(APPEND EXTERNAL_INCS PRIVATE ${jemalloc_INCLUDE_DIRS})
+ list(APPEND EXTERNAL_LIBS PRIVATE jemalloc)
endif()
+include(cmake/gtest.cmake)
include(cmake/glog.cmake)
include(cmake/snappy.cmake)
include(cmake/rocksdb.cmake)
include(cmake/libevent.cmake)
include(cmake/lua.cmake)
-list(APPEND EXTERNAL_LIBS PRIVATE ${glog_LIBRARIES})
-list(APPEND EXTERNAL_INCS PRIVATE ${glog_INCLUDE_DIRS})
+list(APPEND EXTERNAL_LIBS PRIVATE glog)
+list(APPEND EXTERNAL_LIBS PRIVATE snappy)
-list(APPEND EXTERNAL_LIBS PRIVATE ${rocksdb_LIBRARIES})
-list(APPEND EXTERNAL_INCS PRIVATE ${rocksdb_INCLUDE_DIRS})
+list(APPEND EXTERNAL_LIBS PRIVATE rocksdb_with_headers)
-list(APPEND EXTERNAL_LIBS PRIVATE ${snappy_LIBRARIES})
-list(APPEND EXTERNAL_INCS PRIVATE ${snappy_INCLUDE_DIRS})
+list(APPEND EXTERNAL_LIBS PRIVATE event_with_headers)
-list(APPEND EXTERNAL_LIBS PRIVATE ${libevent_LIBRARIES})
-list(APPEND EXTERNAL_INCS PRIVATE ${libevent_INCLUDE_DIRS})
-
-list(APPEND EXTERNAL_LIBS PRIVATE ${lua_LIBRARIES})
-list(APPEND EXTERNAL_INCS PRIVATE ${lua_INCLUDE_DIRS})
+list(APPEND EXTERNAL_LIBS PRIVATE lua)
# End dependencies
@@ -88,13 +82,8 @@ if(ENBALE_ASAN)
target_compile_options(kvrocks PRIVATE -fsanitize=address)
target_link_libraries(kvrocks PRIVATE -fsanitize=address)
endif()
-add_dependencies(kvrocks libevent glog snappy rocksdb lua)
-if(NOT DISABLE_JEMALLOC)
- add_dependencies(kvrocks jemalloc)
-endif()
target_include_directories(kvrocks PRIVATE ${PROJECT_BINARY_DIR})
-target_include_directories(kvrocks ${EXTERNAL_INCS})
find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
target_compile_options(kvrocks PUBLIC "-pthread")
@@ -203,9 +192,7 @@ if(ENBALE_ASAN)
target_compile_options(kvrocks2redis PRIVATE -fno-omit-frame-pointer -fsanitize=address)
target_link_libraries(kvrocks2redis PRIVATE -fno-omit-frame-pointer -fsanitize=address)
endif()
-add_dependencies(kvrocks2redis libevent glog rocksdb)
target_include_directories(kvrocks2redis PRIVATE ${PROJECT_BINARY_DIR})
-target_include_directories(kvrocks2redis ${EXTERNAL_INCS})
if(UNWIND_LIB)
target_link_libraries(kvrocks2redis PRIVATE -lunwind)
endif()
@@ -404,13 +391,10 @@ add_executable(unittest
src/rand.cc
src/rand.h)
-add_dependencies(unittest glog rocksdb snappy lua)
target_compile_features(unittest PRIVATE cxx_std_11)
-message(${snappy_LIBRARIES})
-target_link_libraries(unittest PRIVATE ${EXTERNAL_LIBS} -lgtest)
+target_link_libraries(unittest PRIVATE ${EXTERNAL_LIBS} gtest_main)
if(UNWIND_LIB)
target_link_libraries(unittest PRIVATE -lunwind)
endif()
target_include_directories(unittest PRIVATE ${PROJECT_BINARY_DIR})
-target_include_directories(unittest ${EXTERNAL_INCS})
target_include_directories(unittest PRIVATE src)
diff --git a/build.sh b/build.sh
index f0d4d72..86c265b 100755
--- a/build.sh
+++ b/build.sh
@@ -57,12 +57,11 @@ if [ "$(printf '%s\n' "$CMAKE_REQUIRE_VERSION" "$CMAKE_VERSION" | sort -V | head
fi
mkdir -p $BUILD_DIR/cmake
cd $BUILD_DIR
- curl -O -L https://github.com/Kitware/CMake/releases/download/v3.13.2/cmake-3.13.2.tar.gz
- tar -zxf cmake-3.13.2.tar.gz && cd cmake-3.13.2
+ CMAKE_DOWNLOAD_VERSION=3.23.1
+ curl -O -L https://github.com/Kitware/CMake/releases/download/v$CMAKE_DOWNLOAD_VERSION/cmake-$CMAKE_DOWNLOAD_VERSION.tar.gz
+ tar -zxf cmake-$CMAKE_DOWNLOAD_VERSION.tar.gz && cd cmake-$CMAKE_DOWNLOAD_VERSION
./bootstrap --prefix=$CMAKE_INSTALL_DIR && make && make install && cd ../..
CMAKE_BIN=$CMAKE_INSTALL_DIR/bin/cmake
fi
-git submodule init
-git submodule update
cd $BUILD_DIR && $CMAKE_BIN -DCMAKE_BUILD_TYPE=Release .. && make -j4 kvrocks kvrocks2redis
diff --git a/cmake/gflags.cmake b/cmake/gflags.cmake
deleted file mode 100644
index 3fda25a..0000000
--- a/cmake/gflags.cmake
+++ /dev/null
@@ -1,60 +0,0 @@
-# Licensed to the Apache Software Foundation (ASF) under one
-# or more contributor license agreements. See the NOTICE file
-# distributed with this work for additional information
-# regarding copyright ownership. The ASF licenses this file
-# to you under the Apache License, Version 2.0 (the
-# "License"); you may not use this file except in compliance
-# with the License. You may obtain a copy of the License at
-#
-# http://www.apache.org/licenses/LICENSE-2.0
-#
-# Unless required by applicable law or agreed to in writing,
-# software distributed under the License is distributed on an
-# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
-# KIND, either express or implied. See the License for the
-# specific language governing permissions and limitations
-# under the License.
-
-if (NOT __GFLAGS_INCLUDED) # guard against multiple includes
- set(__GFLAGS_INCLUDED TRUE)
-
- # gflags will use pthreads if it's available in the system, so we must link with it
- find_package(Threads)
-
- # build directory
- set(gflags_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/gflags-prefix)
- # install directory
- set(gflags_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/gflags-install)
-
- if (UNIX)
- set(GFLAGS_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
-
- set(GFLAGS_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${GFLAGS_EXTRA_COMPILER_FLAGS})
- set(GFLAGS_C_FLAGS ${CMAKE_C_FLAGS} ${GFLAGS_EXTRA_COMPILER_FLAGS})
-
- ExternalProject_Add(gflags
- PREFIX ${gflags_PREFIX}
- #GIT_REPOSITORY "https://github.com/gflags/gflags.git"
- #GIT_TAG "v2.2.1"
- SOURCE_DIR ${PROJECT_SOURCE_DIR}/external/gflags
- INSTALL_DIR ${gflags_INSTALL}
- CMAKE_ARGS -DCMAKE_BUILD_TYPE=Release
- -DCMAKE_INSTALL_PREFIX=${gflags_INSTALL}
- -DBUILD_SHARED_LIBS=OFF
- -DBUILD_STATIC_LIBS=ON
- -DBUILD_PACKAGING=OFF
- -DBUILD_TESTING=OFF
- -DBUILD_NC_TESTS=OFF
- -DBUILD_CONFIG_TESTS=OFF
- -DINSTALL_HEADERS=ON
- -DCMAKE_C_FLAGS=${GFLAGS_C_FLAGS}
- -DCMAKE_CXX_FLAGS=${GFLAGS_CXX_FLAGS}
- LOG_DOWNLOAD 1
- LOG_INSTALL 1
- )
-
- set(gflags_FOUND TRUE)
- set(gflags_INCLUDE_DIRS ${gflags_INSTALL}/include)
- set(gflags_LIBRARIES ${gflags_INSTALL}/lib/libgflags.a ${CMAKE_THREAD_LIBS_INIT})
-endif()
diff --git a/cmake/glog.cmake b/cmake/glog.cmake
index 7270446..a6ca92b 100644
--- a/cmake/glog.cmake
+++ b/cmake/glog.cmake
@@ -15,48 +15,18 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __GLOG_INCLUDED)
- set(__GLOG_INCLUDED TRUE)
- find_package(Threads)
- set(CMAKE_INSTALL_LIBDIR lib)
- # build directory
- set(glog_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/glog-prefix)
- # install directory
- set(glog_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/glog-install)
+include_guard()
- if (UNIX)
- set(GLOG_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
+include(FetchContent)
- set(GLOG_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GLOG_EXTRA_COMPILER_FLAGS}")
- set(GLOG_C_FLAGS "${CMAKE_C_FLAGS} ${GLOG_EXTRA_COMPILER_FLAGS}")
+FetchContent_Declare(glog
+ GIT_REPOSITORY https://github.com/google/glog
+ GIT_TAG v0.4.0
+)
- ExternalProject_Add(glog
- PREFIX ${glog_PREFIX}
- #GIT_REPOSITORY "https://github.com/google/glog"
- #GIT_TAG "v0.3.5"
- SOURCE_DIR ${PROJECT_SOURCE_DIR}/external/glog
- INSTALL_DIR ${glog_INSTALL}
- CMAKE_ARGS -DCMAKE_BUILD_TYPE=Release
- -DCMAKE_INSTALL_LIBDIR=${CMAKE_INSTALL_LIBDIR}
- -DCMAKE_INSTALL_PREFIX=${glog_INSTALL}
- -DBUILD_SHARED_LIBS=OFF
- -DBUILD_STATIC_LIBS=ON
- -DBUILD_PACKAGING=OFF
- -DBUILD_TESTING=OFF
- -DBUILD_NC_TESTS=OFF
- -DBUILD_CONFIG_TESTS=OFF
- -DINSTALL_HEADERS=ON
- -DWITH_GFLAGS=OFF
- -DCMAKE_C_FLAGS=${GLOG_C_FLAGS}
- -DCMAKE_CXX_FLAGS=${GLOG_CXX_FLAGS}
- LOG_DOWNLOAD 1
- LOG_CONFIGURE 1
- LOG_INSTALL 1
- )
-
- set(glog_FOUND TRUE)
- set(glog_INCLUDE_DIRS ${glog_INSTALL}/include)
- set(glog_LIBRARIES ${glog_INSTALL}/${CMAKE_INSTALL_LIBDIR}/libglog.a)
-endif()
+include(cmake/utils.cmake)
+FetchContent_MakeAvailableWithArgs(glog
+ WITH_GFLAGS=OFF
+ WITH_GTEST=OFF
+)
diff --git a/cmake/gtest.cmake b/cmake/gtest.cmake
index bef29e9..ae9b0be 100644
--- a/cmake/gtest.cmake
+++ b/cmake/gtest.cmake
@@ -15,38 +15,18 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __GTEST_INCLUDED) # guard against multiple includes
- set(__GTEST_INCLUDED TRUE)
+include_guard()
- # gtest will use pthreads if it's available in the system, so we must link with it
- find_package(Threads)
+include(FetchContent)
- # build directory
- set(gtest_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/gtest-prefix)
- # install directory
- set(gtest_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/gtest-install)
+FetchContent_Declare(gtest
+ GIT_REPOSITORY https://github.com/google/googletest
+ GIT_TAG release-1.11.0
+)
- if (UNIX)
- set(GTEST_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
+include(cmake/utils.cmake)
- set(GTEST_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${GTEST_EXTRA_COMPILER_FLAGS})
- set(GTEST_C_FLAGS ${CMAKE_C_FLAGS} ${GTEST_EXTRA_COMPILER_FLAGS})
-
- ExternalProject_Add(gtest
- PREFIX ${gtest_PREFIX}
- SOURCE_DIR ${PROJECT_SOURCE_DIR}/external/googletest
- INSTALL_DIR ${gtest_INSTALL}
- CMAKE_ARGS -DCMAKE_BUILD_TYPE=Release
- -DCMAKE_INSTALL_PREFIX=${gtest_INSTALL}
- -DCMAKE_C_FLAGS=${GTEST_C_FLAGS}
- -DCMAKE_CXX_FLAGS=${GTEST_CXX_FLAGS}
- -DBUILD_GMOCK=OFF
- LOG_DOWNLOAD 1
- LOG_INSTALL 1
- )
-
- set(gtest_FOUND TRUE)
- set(gtest_INCLUDE_DIRS ${gtest_INSTALL}/include)
- set(gtest_LIBRARIES ${gtest_INSTALL}/${CMAKE_INSTALL_LIBDIR}/libgtest.a ${CMAKE_THREAD_LIBS_INIT})
-endif()
+FetchContent_MakeAvailableWithArgs(gtest
+ BUILD_GMOCK=OFF
+ INSTALL_GTEST=OFF
+)
diff --git a/cmake/jemalloc.cmake b/cmake/jemalloc.cmake
index 2d20001..729b4ce 100644
--- a/cmake/jemalloc.cmake
+++ b/cmake/jemalloc.cmake
@@ -15,39 +15,34 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __JEMALLOC_INCLUDED) # guard against multiple includes
- set(__JEMALLOC_INCLUDED TRUE)
+include_guard()
- find_package(Threads)
- # build directory
- set(jemalloc_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/jemalloc-prefix)
- # install directory
- set(jemalloc_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/jemalloc-install)
- set(JEMALLOC_SOURCE_DIR "${PROJECT_SOURCE_DIR}/external/jemalloc")
+include(FetchContent)
- if (UNIX)
- set(JEMALLOC_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
+FetchContent_Declare(jemalloc
+ GIT_REPOSITORY https://github.com/jemalloc/jemalloc
+ GIT_TAG 12cd13cd418512d9e7596921ccdb62e25a103f87
+)
- set(JEMALLOC_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${JEMALLOC_EXTRA_COMPILER_FLAGS})
- set(JEMALLOC_C_FLAGS ${CMAKE_C_FLAGS} ${JEMALLOC_EXTRA_COMPILER_FLAGS})
+FetchContent_GetProperties(jemalloc)
+if(NOT jemalloc_POPULATED)
+ FetchContent_Populate(jemalloc)
- ExternalProject_Add(jemalloc
- SOURCE_DIR ${JEMALLOC_SOURCE_DIR}
- PREFIX ${jemalloc_PREFIX}
- INSTALL_DIR ${jemalloc_INSTALL}
- CONFIGURE_COMMAND ${JEMALLOC_SOURCE_DIR}/configure --enable-autogen --disable-libdl --with-jemalloc-prefix=""
- --prefix=${jemalloc_INSTALL}
- BUILD_COMMAND make
- INSTALL_COMMAND make dist COMMAND make install
- )
- ExternalProject_Add_Step(jemalloc autoconf
- COMMAND autoconf
- WORKING_DIRECTORY ${JEMALLOC_SOURCE_DIR}
- COMMENT "Jemalloc autoconf"
- LOG 1
- )
- set(jemalloc_FOUND TRUE)
- set(jemalloc_INCLUDE_DIRS ${jemalloc_INSTALL}/include)
- set(jemalloc_LIBRARIES ${jemalloc_INSTALL}/lib/libjemalloc.a ${CMAKE_THREAD_LIBS_INIT})
+ execute_process(COMMAND autoconf
+ WORKING_DIRECTORY ${jemalloc_SOURCE_DIR}
+ )
+ execute_process(COMMAND ${jemalloc_SOURCE_DIR}/configure -C --enable-autogen --disable-libdl --with-jemalloc-prefix=""
+ WORKING_DIRECTORY ${jemalloc_BINARY_DIR}
+ )
+ add_custom_target(make_jemalloc
+ COMMAND make
+ WORKING_DIRECTORY ${jemalloc_BINARY_DIR}
+ )
endif()
+
+find_package(Threads REQUIRED)
+
+add_library(jemalloc INTERFACE)
+target_include_directories(jemalloc INTERFACE $<BUILD_INTERFACE:${jemalloc_BINARY_DIR}/include>)
+target_link_libraries(jemalloc INTERFACE $<BUILD_INTERFACE:${jemalloc_BINARY_DIR}/lib/libjemalloc.a> Threads::Threads)
+add_dependencies(jemalloc make_jemalloc)
diff --git a/cmake/libevent.cmake b/cmake/libevent.cmake
index 7b858eb..cdb355b 100644
--- a/cmake/libevent.cmake
+++ b/cmake/libevent.cmake
@@ -15,39 +15,26 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __LIBEVENT_INCLUDED)
- set(__LIBEVENT_INCLUDED TRUE)
- # build directory
- set(libevent_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/libevent-prefix)
- # install directory
- set(libevent_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/libevent-install)
+include_guard()
- if (UNIX)
- set(LIBEVENT_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
+include(FetchContent)
- set(LIBEVENT_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${LIBEVENT_EXTRA_COMPILER_FLAGS}")
- set(LIBEVENT_C_FLAGS "${CMAKE_C_FLAGS} ${LIBEVENT_EXTRA_COMPILER_FLAGS}")
+FetchContent_Declare(libevent
+ GIT_REPOSITORY https://github.com/libevent/libevent
+ GIT_TAG release-2.1.11-stable
+)
- ExternalProject_Add(libevent
- PREFIX ${libevent_PREFIX}
- SOURCE_DIR ${PROJECT_SOURCE_DIR}/external/libevent
- INSTALL_DIR ${libevent_INSTALL}
- CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
- -DCMAKE_INSTALL_PREFIX=${libevent_INSTALL}
- -DCMAKE_C_FLAGS=${LIBEVENT_C_FLAGS}
- -DCMAKE_CXX_FLAGS=${LIBEVENT_CXX_FLAGS}
- -DEVENT__DISABLE_TESTS=ON
- -DEVENT__DISABLE_REGRESS=ON
- -DEVENT__DISABLE_SAMPLES=ON
- -DEVENT__DISABLE_OPENSSL=ON
- -DEVENT__LIBRARY_TYPE=STATIC
- LOG_DOWNLOAD 1
- LOG_CONFIGURE 1
- LOG_INSTALL 1
- )
+include(cmake/utils.cmake)
- set(libevent_FOUND TRUE)
- set(libevent_INCLUDE_DIRS ${libevent_INSTALL}/include)
- set(libevent_LIBRARIES ${libevent_INSTALL}/lib/libevent.a ${libevent_INSTALL}/lib/libevent_pthreads.a)
-endif()
+FetchContent_MakeAvailableWithArgs(libevent
+ EVENT__DISABLE_TESTS=ON
+ EVENT__DISABLE_REGRESS=ON
+ EVENT__DISABLE_SAMPLES=ON
+ EVENT__DISABLE_OPENSSL=ON
+ EVENT__LIBRARY_TYPE=STATIC
+ EVENT__DISABLE_BENCHMARK=ON
+)
+
+add_library(event_with_headers INTERFACE)
+target_include_directories(event_with_headers INTERFACE ${libevent_SOURCE_DIR}/include ${libevent_BINARY_DIR}/include)
+target_link_libraries(event_with_headers INTERFACE event event_pthreads)
diff --git a/cmake/lua.cmake b/cmake/lua.cmake
index 0069440..3f58041 100644
--- a/cmake/lua.cmake
+++ b/cmake/lua.cmake
@@ -15,33 +15,30 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __LUA_INCLUDED) # guard against multiple includes
- set(__LUA_INCLUDED TRUE)
+include_guard()
- # build directory
- set(lua_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/lua-prefix)
- # install directory
- set(lua_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/lua-install)
- set(LUA_SOURCE_DIR "${PROJECT_SOURCE_DIR}/external/lua/src")
+include(FetchContent)
- set(CFLAGS "${CMAKE_C_FLAGS} -DLUA_ANSI -DENABLE_CJSON_GLOBAL -DREDIS_STATIC='' -DLUA_USE_MKSTEMP")
+FetchContent_Declare(lua
+ GIT_REPOSITORY https://github.com/KvrocksLabs/lua
+ GIT_TAG 6f73d72d45c2e3915ee961e41705f35526608735
+)
- ExternalProject_Add(lua
- SOURCE_DIR ${LUA_SOURCE_DIR}
- PREFIX ${lua_PREFIX}
- INSTALL_DIR ${lua_INSTALL}
- CONFIGURE_COMMAND ""
- BUILD_COMMAND make CFLAGS+=${CFLAGS} liblua.a
+FetchContent_GetProperties(lua)
+if(NOT lua_POPULATED)
+ FetchContent_Populate(lua)
- BUILD_ALWAYS true
- BUILD_IN_SOURCE true
- INSTALL_COMMAND COMMAND cp liblua.a ${lua_INSTALL}
- )
- file(GLOB LUA_PUBLIC_HEADERS
- "${LUA_SOURCE_DIR}/*.h"
- )
- file(COPY ${LUA_PUBLIC_HEADERS} DESTINATION ${lua_INSTALL}/include)
- set(lua_FOUND TRUE)
- set(lua_INCLUDE_DIRS ${lua_INSTALL}/include)
- set(lua_LIBRARIES ${lua_INSTALL}/liblua.a)
-endif()
\ No newline at end of file
+ set(LUA_CFLAGS "${CMAKE_C_FLAGS} -DLUA_ANSI -DENABLE_CJSON_GLOBAL -DREDIS_STATIC= -DLUA_USE_MKSTEMP")
+
+ add_custom_target(make_lua COMMAND make "CFLAGS=${LUA_CFLAGS}" liblua.a
+ WORKING_DIRECTORY ${lua_SOURCE_DIR}/src
+ )
+
+ file(GLOB LUA_PUBLIC_HEADERS "${lua_SOURCE_DIR}/src/*.h")
+ file(COPY ${LUA_PUBLIC_HEADERS} DESTINATION ${lua_BINARY_DIR}/include)
+endif()
+
+add_library(lua INTERFACE)
+target_include_directories(lua INTERFACE ${lua_BINARY_DIR}/include)
+target_link_libraries(lua INTERFACE ${lua_SOURCE_DIR}/src/liblua.a)
+add_dependencies(lua make_lua)
diff --git a/cmake/modules/FindJeMalloc.cmake b/cmake/modules/FindJeMalloc.cmake
new file mode 100644
index 0000000..23aa812
--- /dev/null
+++ b/cmake/modules/FindJeMalloc.cmake
@@ -0,0 +1,25 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements. See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership. The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied. See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+# used for `find_package(JeMalloc)` mechanism in rocksdb
+
+if(jemalloc_SOURCE_DIR)
+ message(STATUS "Found JeMalloc in ${jemalloc_SOURCE_DIR}")
+
+ add_library(JeMalloc::JeMalloc ALIAS jemalloc) # rocksdb use it
+ install(TARGETS jemalloc EXPORT RocksDBTargets) # export for install(...)
+endif()
diff --git a/cmake/modules/SnappyConfig.cmake b/cmake/modules/SnappyConfig.cmake
new file mode 100644
index 0000000..f1875ea
--- /dev/null
+++ b/cmake/modules/SnappyConfig.cmake
@@ -0,0 +1,24 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements. See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership. The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied. See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+# used for `find_package(Snappy CONFIG)` mechanism in rocksdb
+
+if(snappy_SOURCE_DIR)
+ message(STATUS "Found Snappy in ${snappy_SOURCE_DIR}")
+
+ add_library(Snappy::snappy ALIAS snappy) # rocksdb use it
+endif()
diff --git a/cmake/rocksdb.cmake b/cmake/rocksdb.cmake
index 49a473a..5817724 100644
--- a/cmake/rocksdb.cmake
+++ b/cmake/rocksdb.cmake
@@ -15,67 +15,40 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __ROCKSDB_INCLUDED)
- set(__ROCKSDB_INCLUDED TRUE)
+include_guard()
- find_package(Threads)
- set(CMAKE_INSTALL_LIBDIR lib)
- # build directory
- set(rocksdb_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/rocksdb-prefix)
- # install directory
- set(rocksdb_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/rocksdb-install)
- set(COMPILE_WITH_JEMALLOC ON)
+set(COMPILE_WITH_JEMALLOC ON)
- if (UNIX)
- set(ROCKSDB_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
+if (DISABLE_JEMALLOC)
+ set(COMPILE_WITH_JEMALLOC OFF)
+endif()
- set(ROCKSDB_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${ROCKSDB_EXTRA_COMPILER_FLAGS}")
- set(ROCKSDB_C_FLAGS "${CMAKE_C_FLAGS} ${ROCKSDB_EXTRA_COMPILER_FLAGS}")
- if (NOT DISABLE_JEMALLOC)
- list(APPEND rocksdb_DEPENDS jemalloc)
- list(APPEND rocksdb_DEPENDS snappy)
- set(JEMALLOC_ROOT_DIR ${jemalloc_INSTALL})
- else()
- set(rocksdb_DEPENDS "snappy")
- set(COMPILE_WITH_JEMALLOC OFF)
- endif()
- ExternalProject_Add(rocksdb
- DEPENDS ${rocksdb_DEPENDS}
- PREFIX ${rocksdb_PREFIX}
- #GIT_REPOSITORY "https://github.com/facebook/rocksdb"
- #GIT_TAG "v5.15.10"
- SOURCE_DIR ${PROJECT_SOURCE_DIR}/external/rocksdb
- INSTALL_DIR ${rocksdb_INSTALL}
- CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
- -DCMAKE_INSTALL_LIBDIR=${CMAKE_INSTALL_LIBDIR}
- -DCMAKE_INSTALL_PREFIX=${rocksdb_INSTALL}
- -DBUILD_SHARED_LIBS=OFF
- -DBUILD_STATIC_LIBS=ON
- -DBUILD_PACKAGING=OFF
- -DBUILD_TESTING=OFF
- -DBUILD_NC_TESTS=OFF
- -DBUILD_CONFIG_TESTS=OFF
- -DINSTALL_HEADERS=ON
- -DCMAKE_C_FLAGS=${ROCKSDB_C_FLAGS}
- -DCMAKE_CXX_FLAGS=${ROCKSDB_CXX_FLAGS}
- -DCMAKE_PREFIX_PATH=${snappy_INSTALL}
- -DJEMALLOC_ROOT_DIR=${JEMALLOC_ROOT_DIR}
- -DFAIL_ON_WARNINGS=OFF
- -DWITH_TESTS=OFF
- -DWITH_SNAPPY=ON
- -DWITH_TOOLS=OFF
- -DWITH_GFLAGS=OFF
- -DUSE_RTTI=ON
- -DWITH_JEMALLOC=${COMPILE_WITH_JEMALLOC}
- LOG_DOWNLOAD 1
- LOG_CONFIGURE 1
- LOG_INSTALL 1
- )
+include(FetchContent)
- include(GNUInstallDirs)
- set(rocksdb_FOUND TRUE)
- set(rocksdb_INCLUDE_DIRS ${rocksdb_INSTALL}/include)
- set(rocksdb_LIBRARIES ${rocksdb_INSTALL}/${CMAKE_INSTALL_LIBDIR}/librocksdb.a)
-endif()
+FetchContent_Declare(rocksdb
+ GIT_REPOSITORY https://github.com/facebook/rocksdb
+ GIT_TAG v6.29.5
+)
+
+include(cmake/utils.cmake)
+
+FetchContent_GetProperties(jemalloc)
+FetchContent_GetProperties(snappy)
+
+FetchContent_MakeAvailableWithArgs(rocksdb
+ CMAKE_MODULE_PATH=${PROJECT_SOURCE_DIR}/cmake/modules # to locate FindJeMalloc.cmake
+ Snappy_DIR=${PROJECT_SOURCE_DIR}/cmake/modules # to locate SnappyConfig.cmake
+ FAIL_ON_WARNINGS=OFF
+ WITH_TESTS=OFF
+ WITH_BENCHMARK_TOOLS=OFF
+ WITH_SNAPPY=ON
+ WITH_TOOLS=OFF
+ WITH_GFLAGS=OFF
+ USE_RTTI=ON
+ ROCKSDB_BUILD_SHARED=OFF
+ WITH_JEMALLOC=${COMPILE_WITH_JEMALLOC}
+)
+add_library(rocksdb_with_headers INTERFACE)
+target_include_directories(rocksdb_with_headers INTERFACE ${rocksdb_SOURCE_DIR}/include)
+target_link_libraries(rocksdb_with_headers INTERFACE rocksdb)
diff --git a/cmake/snappy.cmake b/cmake/snappy.cmake
index 8dcf2d5..1bc5438 100644
--- a/cmake/snappy.cmake
+++ b/cmake/snappy.cmake
@@ -15,48 +15,18 @@
# specific language governing permissions and limitations
# under the License.
-if (NOT __SNAPPY_INCLUDED)
- set(__SNAPPY_INCLUDED TRUE)
- # build directory
- set(snappy_PREFIX ${CMAKE_BUILD_DIRECTORY}/external/snappy-prefix)
- # install directory
- set(snappy_INSTALL ${CMAKE_BUILD_DIRECTORY}/external/snappy-install)
- set(CMAKE_INSTALL_LIBDIR lib)
+include_guard()
- if (UNIX)
- set(SNAPPY_EXTRA_COMPILER_FLAGS "-fPIC")
- endif()
+include(FetchContent)
- set(SNAPPY_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${SNAPPY_EXTRA_COMPILER_FLAGS}")
- set(SNAPPY_C_FLAGS "${CMAKE_C_FLAGS} ${SNAPPY_EXTRA_COMPILER_FLAGS}")
+FetchContent_Declare(snappy
+ GIT_REPOSITORY https://github.com/google/snappy
+ GIT_TAG 1.1.9
+)
- ExternalProject_Add(snappy
- PREFIX ${snappy_PREFIX}
- #GIT_REPOSITORY "https://github.com/google/snappy"
- #GIT_TAG "1.1.7"
- SOURCE_DIR ${PROJECT_SOURCE_DIR}/external/snappy
- INSTALL_DIR ${snappy_INSTALL}
- CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
- -DCMAKE_INSTALL_PREFIX=${snappy_INSTALL}
- -DCMAKE_INSTALL_LIBDIR=${CMAKE_INSTALL_LIBDIR}
- -DBUILD_SHARED_LIBS=OFF
- -DBUILD_STATIC_LIBS=ON
- -DBUILD_PACKAGING=OFF
- -DBUILD_TESTING=OFF
- -DBUILD_NC_TESTS=OFF
- -DBUILD_CONFIG_TESTS=OFF
- -DINSTALL_HEADERS=ON
- -DCMAKE_C_FLAGS=${SNAPPY_C_FLAGS}
- -DCMAKE_CXX_FLAGS=${SNAPPY_CXX_FLAGS}
- -DSNAPPY_BUILD_TESTS=OFF
- LOG_DOWNLOAD 1
- LOG_CONFIGURE 1
- LOG_INSTALL 1
- )
-
- include(GNUInstallDirs)
- set(snappy_FOUND TRUE)
- set(snappy_INCLUDE_DIRS ${snappy_INSTALL}/include)
- set(snappy_LIBRARIES ${snappy_INSTALL}/${CMAKE_INSTALL_LIBDIR}/libsnappy.a)
-endif()
+include(cmake/utils.cmake)
+FetchContent_MakeAvailableWithArgs(snappy
+ SNAPPY_BUILD_TESTS=OFF
+ SNAPPY_BUILD_BENCHMARKS=OFF
+)
diff --git a/cmake/utils.cmake b/cmake/utils.cmake
new file mode 100644
index 0000000..e8ecdd3
--- /dev/null
+++ b/cmake/utils.cmake
@@ -0,0 +1,43 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements. See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership. The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License. You may obtain a copy of the License at
+#
+# http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied. See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+include_guard()
+
+macro(parse_var arg key value)
+ string(REGEX REPLACE "^(.+)=(.+)$" "\\1;\\2" REGEX_RESULT ${arg})
+ list(GET REGEX_RESULT 0 ${key})
+ list(GET REGEX_RESULT 1 ${value})
+endmacro()
+
+function(FetchContent_MakeAvailableWithArgs dep)
+ if(NOT ${dep}_POPULATED)
+ FetchContent_Populate(${dep})
+
+ foreach(arg IN LISTS ARGN)
+ parse_var(${arg} key value)
+ set(${key}_OLD ${${key}})
+ set(${key} ${value} CACHE INTERNAL "")
+ endforeach()
+
+ add_subdirectory(${${dep}_SOURCE_DIR} ${${dep}_BINARY_DIR} EXCLUDE_FROM_ALL)
+
+ foreach(arg IN LISTS ARGN)
+ parse_var(${arg} key value)
+ set(${key} ${${key}_OLD} CACHE INTERNAL "")
+ endforeach()
+ endif()
+endfunction()