You are viewing a plain text version of this content. The canonical link for it is here.
Posted to cvs@httpd.apache.org by so...@apache.org on 2006/01/02 21:10:57 UTC
svn commit: r365417 - in /httpd/mod_smtpd/trunk: ./ m4/ src/
Author: soc-rian
Date: Mon Jan 2 12:10:41 2006
New Revision: 365417
URL: http://svn.apache.org/viewcvs?rev=365417&view=rev
Log:
Greatly enhanced build system, model taken from mod_mbox.
Auto-building of modules directly disabled for the time-being.
Added:
httpd/mod_smtpd/trunk/Makefile.am
httpd/mod_smtpd/trunk/m4/
httpd/mod_smtpd/trunk/m4/Makefile.am
httpd/mod_smtpd/trunk/m4/apache.m4
httpd/mod_smtpd/trunk/m4/apache_test.m4
httpd/mod_smtpd/trunk/m4/apreq2.m4
httpd/mod_smtpd/trunk/src/
httpd/mod_smtpd/trunk/src/Makefile.am
httpd/mod_smtpd/trunk/src/mod_smtpd.h
- copied unchanged from r365412, httpd/mod_smtpd/trunk/mod_smtpd.h
httpd/mod_smtpd/trunk/src/smtp.h
- copied unchanged from r365412, httpd/mod_smtpd/trunk/smtp.h
httpd/mod_smtpd/trunk/src/smtp_core.c
- copied unchanged from r365412, httpd/mod_smtpd/trunk/smtp_core.c
httpd/mod_smtpd/trunk/src/smtp_filters.c
- copied unchanged from r365412, httpd/mod_smtpd/trunk/smtp_filters.c
httpd/mod_smtpd/trunk/src/smtp_filters.h
- copied unchanged from r365412, httpd/mod_smtpd/trunk/smtp_filters.h
httpd/mod_smtpd/trunk/src/smtp_protocol.c
- copied unchanged from r365412, httpd/mod_smtpd/trunk/smtp_protocol.c
httpd/mod_smtpd/trunk/src/smtp_util.c
- copied unchanged from r365412, httpd/mod_smtpd/trunk/smtp_util.c
Removed:
httpd/mod_smtpd/trunk/Makefile.in
httpd/mod_smtpd/trunk/mod_smtpd.h
httpd/mod_smtpd/trunk/smtp.h
httpd/mod_smtpd/trunk/smtp_core.c
httpd/mod_smtpd/trunk/smtp_filters.c
httpd/mod_smtpd/trunk/smtp_filters.h
httpd/mod_smtpd/trunk/smtp_protocol.c
httpd/mod_smtpd/trunk/smtp_util.c
Modified:
httpd/mod_smtpd/trunk/autogen.sh
httpd/mod_smtpd/trunk/configure.ac
Added: httpd/mod_smtpd/trunk/Makefile.am
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/Makefile.am?rev=365417&view=auto
==============================================================================
--- httpd/mod_smtpd/trunk/Makefile.am (added)
+++ httpd/mod_smtpd/trunk/Makefile.am Mon Jan 2 12:10:41 2006
@@ -0,0 +1,3 @@
+EXTRA_DIST = AUTHORS ChangeLog NEWS README
+
+SUBDIRS = src m4
Modified: httpd/mod_smtpd/trunk/autogen.sh
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/autogen.sh?rev=365417&r1=365416&r2=365417&view=diff
==============================================================================
--- httpd/mod_smtpd/trunk/autogen.sh (original)
+++ httpd/mod_smtpd/trunk/autogen.sh Mon Jan 2 12:10:41 2006
@@ -1,4 +1,8 @@
#!/bin/sh
+aclocal -I m4
+libtoolize --force --copy --automake
+automake --add-missing --copy --foreign
autoconf
+
rm -rf autom4te.cache
Modified: httpd/mod_smtpd/trunk/configure.ac
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/configure.ac?rev=365417&r1=365416&r2=365417&view=diff
==============================================================================
--- httpd/mod_smtpd/trunk/configure.ac (original)
+++ httpd/mod_smtpd/trunk/configure.ac Mon Jan 2 12:10:41 2006
@@ -1,91 +1,25 @@
# Required initializer
-AC_INIT(mod_smtpd, 0.9)
+AC_INIT
-AC_DEFUN([CHECK_VERSION],[dnl
- min_apache_version=ifelse([$1], ,no,$1)
- AP_BIN=`$APXS_BIN -q BINDIR`
- AP_SBIN=`$APXS_BIN -q SBINDIR`
- AP_PROG=`$APXS_BIN -q PROGNAME`
- if test -e "$AP_BIN/$AP_PROG"; then
- AP_PATH="$AP_BIN/$AP_PROG"
- else
- AP_PATH="$AP_SBIN/$AP_PROG"
- fi
- our_apache_version=`$AP_PATH -v | grep -i Apache |
- sed -e 's/.*Apache\///' | tr -dc [^0-9.]`
-
- AC_MSG_CHECKING(for Apache version >= $min_apache_version)
-
- if test "$our_apache_version" \> "$min_apache_version" ||
- test "$our_apache_version" = "$min_apache_version"; then
- AC_MSG_RESULT(yes)
- else
- AC_MSG_RESULT(no)
- AC_MSG_ERROR([*** Apache version $min_apache_version not found!])
- fi
-])
-
-AC_DEFUN([CHECK_APREQ2],[dnl
- AC_ARG_WITH(
- libapreq2,
- [ --with-libapreq2[=PATH_TO_LIBAPREQ2] APREQ2 LIB LOCATION],
- APREQ2_LOC="$withval"
- )
-
- AC_MSG_CHECKING(for libapreq2)
-
- test ! -d "$APREQ2_LOC" && APREQ2_LOC=`$APXS_BIN -q LIBDIR`
-
- if ld -L${APREQ2_LOC} -lapreq2 &&
- test -d "${APREQ2_LOC}/../include/apreq2"; then
- APREQ2_LIBDIR="-L'${APREQ2_LOC}'"
- APREQ2_INCLUDEDIR="-I'${APREQ2_LOC}/../include'"
- AC_MSG_RESULT(yes)
- else
- AC_MSG_RESULT(no)
- AC_MSG_ERROR([*** libapreq2 not found! ${APREQ2_LOC}/../include])
- fi
- AC_SUBST(APREQ2_LIBDIR)
- AC_SUBST(APREQ2_INCLUDEDIR)
-])
-
-# Define a macro that is used to parse a --with-apxs parameter
-# The macro is named "APACHE_DIR"
-AC_DEFUN([APACHE_DIR],[dnl
- AC_ARG_WITH(
- apxs,
- [ --with-apxs[=PATH_TO_APXS] APXS Location],
- apxs_prefix="$withval",
- )
-
- # if with-apxs is a directory or its empty
- # search for it
- if test -d $apxs_prefix || test ! $apxs_prefix; then
- if test $apxs_prefix; then
- apxs_prefix=`dirname $apxs_prefix`
- test_paths="$apxs_prefix:$apxs_prefix/bin"
- test_paths="${test_paths}:$apxs_prefix/sbin"
- fi
- test_paths="${test_paths}:${PATH}:/usr/bin:/usr/sbin"
- test_paths="${test_paths}:/usr/local/bin:/usr/local/sbin:/usr/local/apache2/bin"
- AC_PATH_PROG(APXS_BIN, apxs, no, [$test_paths])
- else
- APXS_BIN="$withval"
- fi
-
- if test "$APXS_BIN" = "no"; then
- AC_MSG_ERROR([*** The apxs binary installed by apache could not be found!])
- AC_MSG_ERROR([*** Use the --with-apxs option with the full path to apxs])
- fi
-])
-
-# Now call the APACHE_DIR macro that was just specified
-APACHE_DIR
-
-CHECK_VERSION(2.0)
-
-CHECK_APREQ2
-
-# Write the Makefile
-AC_OUTPUT(include.mk)
-AC_OUTPUT(Makefile)
+AC_CANONICAL_TARGET
+
+# Automake initialization
+AM_INIT_AUTOMAKE(mod_smtpd, 1.0)
+
+# Add a test for a compiler.
+AC_PROG_CC
+AM_PROG_LIBTOOL
+AC_PROG_INSTALL
+
+AP_VERSION=2.0.40
+CHECK_APACHE(,$AP_VERSION,
+ :,:,
+ AC_MSG_ERROR([*** Apache version $AP_VERSION not found!])
+)
+prefix=${AP_PREFIX}
+
+CHECK_APREQ2()
+
+AC_CONFIG_FILES([Makefile src/Makefile m4/Makefile])
+# Write config.status and the Makefile
+AC_OUTPUT
Added: httpd/mod_smtpd/trunk/m4/Makefile.am
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/m4/Makefile.am?rev=365417&view=auto
==============================================================================
--- httpd/mod_smtpd/trunk/m4/Makefile.am (added)
+++ httpd/mod_smtpd/trunk/m4/Makefile.am Mon Jan 2 12:10:41 2006
@@ -0,0 +1 @@
+EXTRA_DIST = apache.m4 apache_test.m4
Added: httpd/mod_smtpd/trunk/m4/apache.m4
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/m4/apache.m4?rev=365417&view=auto
==============================================================================
--- httpd/mod_smtpd/trunk/m4/apache.m4 (added)
+++ httpd/mod_smtpd/trunk/m4/apache.m4 Mon Jan 2 12:10:41 2006
@@ -0,0 +1,137 @@
+dnl -------------------------------------------------------- -*- autoconf -*-
+dnl Copyright 2005 The Apache Software Foundation
+dnl
+dnl Licensed under the Apache License, Version 2.0 (the "License");
+dnl you may not use this file except in compliance with the License.
+dnl You may obtain a copy of the License at
+dnl
+dnl http://www.apache.org/licenses/LICENSE-2.0
+dnl
+dnl Unless required by applicable law or agreed to in writing, software
+dnl distributed under the License is distributed on an "AS IS" BASIS,
+dnl WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+dnl See the License for the specific language governing permissions and
+dnl limitations under the License.
+
+dnl CHECK_APACHE([MINIMUM13-VERSION [, MINIMUM20-VERSION [,
+dnl ACTION-IF-FOUND13 [, ACTION-IF-FOUND20 [, ACTION-IF-NOT-FOUND]]])
+dnl Test for Apache apxs, APR, and APU
+
+AC_DEFUN([CHECK_APACHE],
+[dnl
+AC_ARG_WITH(
+ apxs,
+ [AC_HELP_STRING([--with-apxs=PATH],[Path to apxs])],
+ apxs_prefix="$withval",
+ apxs_prefix="/usr"
+ )
+
+AC_ARG_ENABLE(
+ apachetest,
+ [AC_HELP_STRING([--disable-apxstest],[Do not try to compile and run apache version test program])],
+ ,
+ enable_apachetest=yes
+ )
+
+ if test -x $apxs_prefix -a ! -d $apxs_prefix; then
+ APXS_BIN=$apxs_prefix
+ else
+ test_paths="$apxs_prefix:$apxs_prefix/bin:$apxs_prefix/sbin"
+ test_paths="${test_paths}:/usr/bin:/usr/sbin"
+ test_paths="${test_paths}:/usr/local/bin:/usr/local/sbin:/usr/local/apache2/bin"
+ AC_PATH_PROG(APXS_BIN, apxs, no, [$test_paths])
+ fi
+ min_apache13_version=ifelse([$1], ,no,$1)
+ min_apache20_version=ifelse([$2], ,no,$2)
+ no_apxs=""
+ if test "$APXS_BIN" = "no"; then
+ AC_MSG_ERROR([*** The apxs binary installed by apache could not be found!])
+ AC_MSG_ERROR([*** Use the --with-apxs option with the full path to apxs])
+ else
+ AP_INCLUDES="-I`$APXS_BIN -q INCLUDEDIR 2>/dev/null`"
+ AP_INCLUDEDIR="`$APXS_BIN -q INCLUDEDIR 2>/dev/null`"
+
+ AP_PREFIX="`$APXS_BIN -q prefix 2>/dev/null`"
+
+ AP_BINDIR="`$APXS_BIN -q bindir 2>/dev/null`"
+ AP_SBINDIR="`$APXS_BIN -q sbindir 2>/dev/null`"
+
+ APXS_CFLAGS=""
+ for flag in CFLAGS EXTRA_CFLAGS EXTRA_CPPFLAGS NOTEST_CFLAGS; do
+ APXS_CFLAGS="$APXS_CFLAGS `$APXS_BIN -q $flag 2>/dev/null`"
+ done
+
+ AP_CPPFLAGS="$APXS_CPPFLAGS $AP_INCLUDES"
+ AP_CFLAGS="$APXS_CFLAGS $AP_INCLUDES"
+
+ AP_LIBEXECDIR=`$APXS_BIN -q LIBEXECDIR 2>/dev/null`
+
+ if test "x$enable_apachetest" = "xyes" ; then
+ if test "$min_apache20_version" != "no"; then
+ APR_CONFIG="`$APXS_BIN -q APR_BINDIR 2>/dev/null`/apr-1-config"
+ if test ! -x $APR_CONFIG; then
+ APR_CONFIG="`$APXS_BIN -q APR_BINDIR 2>/dev/null`/apr-config"
+ fi
+ APR_INCLUDES=`$APR_CONFIG --includes 2>/dev/null`
+ APR_VERSION=`$APR_CONFIG --version 2>/dev/null`
+ APU_CONFIG="`$APXS_BIN -q APU_BINDIR 2>/dev/null`/apu-1-config"
+ if test ! -x $APU_CONFIG; then
+ APU_CONFIG="`$APXS_BIN -q APU_BINDIR 2>/dev/null`/apu-config"
+ fi
+ APU_INCLUDES=`$APU_CONFIG --includes 2>/dev/null`
+ APU_VERSION=`$APU_CONFIG --version 2>/dev/null`
+
+ AC_MSG_CHECKING(for Apache 2.0 version >= $min_apache20_version)
+ TEST_APACHE_VERSION(20,$min_apache20_version,
+ AC_MSG_RESULT(yes)
+ AC_DEFINE(WITH_APACHE20,1,[Define to 1 if we are compiling with Apache 2.0.x])
+ AP_VERSION="2.0"
+ APXS_EXTENSION=.la
+ AP_CFLAGS="$AP_CFLAGS $APU_INCLUDES $APR_INCLUDES"
+ AP_CPPFLAGS="$AP_CPPFLAGS $APU_INCLUDES $APR_INCLUDES"
+ AP_DEFS="-DWITH_APACHE20"
+ ifelse([$4], , , $4),
+ AC_MSG_RESULT(no)
+ if test "x$min_apache13_version" = "xno"; then
+ ifelse([$5], , , $5)
+ fi
+ )
+ fi
+ if test "$min_apache13_version" != "no" -a "x$AP_VERSION" = "x"; then
+ APR_INCLUDES=""
+ APR_VERSION=""
+ APU_INCLUDES=""
+ APU_VERSION=""
+ AC_MSG_CHECKING(for Apache 1.3 version >= $min_apache13_version)
+ TEST_APACHE_VERSION(13,$min_apache13_version,
+ AC_MSG_RESULT(yes)
+ AC_DEFINE(WITH_APACHE13,1,[Define to 1 if we are compiling with Apache 1.3.x])
+ AP_VERSION="1.3"
+ APXS_EXTENSION=.so
+ AP_CFLAGS="-g $AP_CFLAGS"
+ AP_DEFS="-DWITH_APACHE13"
+ ifelse([$3], , , $3),
+ AC_MSG_RESULT(no)
+ ifelse([$5], , , $5)
+ )
+ fi
+ fi
+ AC_SUBST(AP_DEFS)
+ AC_SUBST(AP_PREFIX)
+ AC_SUBST(AP_CFLAGS)
+ AC_SUBST(AP_CPPFLAGS)
+ AC_SUBST(AP_INCLUDES)
+ AC_SUBST(AP_INCLUDEDIR)
+ AC_SUBST(AP_LIBEXECDIR)
+ AC_SUBST(AP_VERSION)
+ AC_SUBST(AP_BINDIR)
+ AC_SUBST(AP_SBINDIR)
+ AC_SUBST(APR_CONFIG)
+ AC_SUBST(APU_CONFIG)
+ AC_SUBST(APR_INCLUDES)
+ AC_SUBST(APU_INCLUDES)
+ AC_SUBST(APXS_EXTENSION)
+ AC_SUBST(APXS_BIN)
+ AC_SUBST(APXS_CFLAGS)
+ fi
+])
Added: httpd/mod_smtpd/trunk/m4/apache_test.m4
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/m4/apache_test.m4?rev=365417&view=auto
==============================================================================
--- httpd/mod_smtpd/trunk/m4/apache_test.m4 (added)
+++ httpd/mod_smtpd/trunk/m4/apache_test.m4 Mon Jan 2 12:10:41 2006
@@ -0,0 +1,112 @@
+dnl -------------------------------------------------------- -*- autoconf -*-
+dnl Copyright 2005 The Apache Software Foundation
+dnl
+dnl Licensed under the Apache License, Version 2.0 (the "License");
+dnl you may not use this file except in compliance with the License.
+dnl You may obtain a copy of the License at
+dnl
+dnl http://www.apache.org/licenses/LICENSE-2.0
+dnl
+dnl Unless required by applicable law or agreed to in writing, software
+dnl distributed under the License is distributed on an "AS IS" BASIS,
+dnl WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+dnl See the License for the specific language governing permissions and
+dnl limitations under the License.
+
+
+dnl TEST_APACHE_VERSION(RELEASE, [MINIMUM-VERSION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
+dnl Test for Apache
+dnl
+AC_DEFUN([TEST_APACHE_VERSION],
+[dnl
+ AC_REQUIRE([AC_CANONICAL_TARGET])
+ releasetest=$1
+ min_apache_version="$2"
+ no_apache=""
+ ac_save_CFLAGS="$CFLAGS"
+ CFLAGS="$CFLAGS $AP_CFLAGS"
+ if test $releasetest -eq 20; then
+ CFLAGS="$CFLAGS $APU_INCLUDES $APR_INCLUDES"
+ fi
+ AC_TRY_RUN([
+#include <stdio.h>
+#include <stdlib.h>
+#include <string.h>
+#include "httpd.h"
+
+#ifndef AP_SERVER_BASEREVISION
+ #define AP_SERVER_BASEREVISION SERVER_BASEREVISION
+#endif
+
+char* my_strdup (char *str)
+{
+ char *new_str;
+
+ if (str) {
+ new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
+ strcpy (new_str, str);
+ } else
+ new_str = NULL;
+
+ return new_str;
+}
+
+int main (int argc, char *argv[])
+{
+ int major1, minor1, micro1;
+ int major2, minor2, micro2;
+ char *tmp_version;
+
+ { FILE *fp = fopen("conf.apachetest", "a"); if ( fp ) fclose(fp); }
+
+ tmp_version = my_strdup("$min_apache_version");
+ if (sscanf(tmp_version, "%d.%d.%d", &major1, &minor1, µ1) != 3) {
+ printf("%s, bad version string\n", "$min_apache_version");
+ exit(1);
+ }
+ tmp_version = my_strdup(AP_SERVER_BASEREVISION);
+ if (sscanf(tmp_version, "%d.%d.%d", &major2, &minor2, µ2) != 3) {
+ printf("%s, bad version string\n", AP_SERVER_BASEREVISION);
+ exit(1);
+ }
+
+ if ( (major2 == major1) &&
+ ( (minor2 > minor1) ||
+ ((minor2 == minor1) && (micro2 >= micro1)) ) ) {
+ exit(0);
+ } else {
+ exit(1);
+ }
+}
+
+],, no_apache=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
+ CFLAGS="$ac_save_CFLAGS"
+
+ if test "x$no_apache" = x ; then
+ ifelse([$3], , :, [$3])
+ else
+ if test -f conf.apachetest ; then
+ :
+ else
+ echo "*** Could not run Apache test program, checking why..."
+ CFLAGS="$CFLAGS $AP_CFLAGS"
+ if test $releasetest -eq 20; then
+ CFLAGS="$CFLAGS $APU_INCLUDES $APR_INCLUDES"
+ fi
+ AC_TRY_LINK([
+#include <stdio.h>
+#include "httpd.h"
+
+int main(int argc, char *argv[])
+{ return 0; }
+#undef main
+#define main K_and_R_C_main
+], [ return 0; ],
+ [ echo "*** The test program compiled, but failed to run. Check config.log" ],
+ [ echo "*** The test program failed to compile or link. Check config.log" ])
+ CFLAGS="$ac_save_CFLAGS"
+ fi
+ ifelse([$4], , :, [$4])
+ fi
+ rm -f conf.apachetest
+])
Added: httpd/mod_smtpd/trunk/m4/apreq2.m4
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/m4/apreq2.m4?rev=365417&view=auto
==============================================================================
--- httpd/mod_smtpd/trunk/m4/apreq2.m4 (added)
+++ httpd/mod_smtpd/trunk/m4/apreq2.m4 Mon Jan 2 12:10:41 2006
@@ -0,0 +1,57 @@
+dnl -------------------------------------------------------- -*- autoconf -*-
+dnl Copyright 2005 The Apache Software Foundation
+dnl
+dnl Licensed under the Apache License, Version 2.0 (the "License");
+dnl you may not use this file except in compliance with the License.
+dnl You may obtain a copy of the License at
+dnl
+dnl http://www.apache.org/licenses/LICENSE-2.0
+dnl
+dnl Unless required by applicable law or agreed to in writing, software
+dnl distributed under the License is distributed on an "AS IS" BASIS,
+dnl WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+dnl See the License for the specific language governing permissions and
+dnl limitations under the License.
+
+dnl Check for libapreq2
+dnl CHECK_APREQ2(ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND])
+AC_DEFUN([CHECK_APREQ2],
+[dnl
+
+AC_ARG_WITH(
+ libapreq2,
+ [AC_HELP_STRING([--with-libapreq2=PATH],
+ [Path to Top Level libapreq2 Install Directory])],
+ mc_path="$withval",
+ :)
+
+if test -z $mc_path; then
+ test_paths="${prefix} /usr/local /usr"
+else
+ test_paths="${mc_path}"
+fi
+
+for x in $test_paths ; do
+ AC_MSG_CHECKING([for libapreq2 in ${x}])
+ if test -f ${x}/include/apreq2/apreq_parser.h; then
+ AC_MSG_RESULT([yes])
+ APREQ2_LIBS="-L${x}/lib -lapreq2"
+ APREQ2_INCLUDES="-I${x}/include"
+ break
+ else
+ AC_MSG_RESULT([no])
+ fi
+done
+
+AC_SUBST(APREQ2_LIBS)
+AC_SUBST(APREQ2_INCLUDES)
+
+if test -z "${APREQ2_LIBS}"; then
+ AC_MSG_NOTICE([*** libapreq2 not found.])
+ ifelse([$2], , AC_MSG_ERROR([libapreq2 is required]), [$2])
+else
+ AC_MSG_NOTICE([libapreq2 has been found.])
+ ifelse([$1], , , [$1])
+fi
+])
+
Added: httpd/mod_smtpd/trunk/src/Makefile.am
URL: http://svn.apache.org/viewcvs/httpd/mod_smtpd/trunk/src/Makefile.am?rev=365417&view=auto
==============================================================================
--- httpd/mod_smtpd/trunk/src/Makefile.am (added)
+++ httpd/mod_smtpd/trunk/src/Makefile.am Mon Jan 2 12:10:41 2006
@@ -0,0 +1,14 @@
+mod_smtpd_la_SOURCES = smtp_core.c smtp_filters.c smtp_protocol.c smtp_util.c \
+smtp.h smtp_filters.h
+mod_smtpd_la_LDFLAGS = @APREQ2_LIBS@ -rpath ${AP_LIBEXECDIR} \
+-module -avoid-version ${MODULE_LDFLAGS}
+
+include_HEADERS = mod_smtpd.h
+mod_LTLIBRARIES = mod_smtpd.la
+moddir=${AP_LIBEXECDIR}
+
+INCLUDES=@AP_INCLUDES@ @APR_INCLUDES@ @APU_INCLUDES@ @APREQ2_INCLUDES@
+
+install: install-am
+ rm -f $(DESTDIR)${AP_LIBEXECDIR}/mod_smtpd.a
+ rm -f $(DESTDIR)${AP_LIBEXECDIR}/mod_smtpd.la