You are viewing a plain text version of this content. The canonical link for it is here.
Posted to commits@santuario.apache.org by sc...@apache.org on 2018/06/15 15:56:20 UTC
svn commit: r1833604 - in /santuario/xml-security-cpp/trunk: Makefile.am
configure.ac m4/ax_pkg_check_modules.m4 xml-security-c.pc.in
xml-security-c.spec xsec/Makefile.am xsec/samples/IOStreamOutputter.cpp
Author: scantor
Date: Fri Jun 15 15:56:20 2018
New Revision: 1833604
URL: http://svn.apache.org/viewvc?rev=1833604&view=rev
Log:
General build and pkg-config changes from Ferenc.
Added:
santuario/xml-security-cpp/trunk/m4/ax_pkg_check_modules.m4
Modified:
santuario/xml-security-cpp/trunk/Makefile.am
santuario/xml-security-cpp/trunk/configure.ac
santuario/xml-security-cpp/trunk/xml-security-c.pc.in
santuario/xml-security-cpp/trunk/xml-security-c.spec
santuario/xml-security-cpp/trunk/xsec/Makefile.am
santuario/xml-security-cpp/trunk/xsec/samples/IOStreamOutputter.cpp
Modified: santuario/xml-security-cpp/trunk/Makefile.am
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/Makefile.am?rev=1833604&r1=1833603&r2=1833604&view=diff
==============================================================================
--- santuario/xml-security-cpp/trunk/Makefile.am (original)
+++ santuario/xml-security-cpp/trunk/Makefile.am Fri Jun 15 15:56:20 2018
@@ -14,7 +14,6 @@
# limitations under the License.
#
-AUTOMAKE_OPTIONS = foreign dist-bzip2 dist-zip
ACLOCAL_AMFLAGS = -I m4
SUBDIRS = xsec
@@ -25,7 +24,9 @@ EXTRA_DIST = \
LICENSE.txt \
NOTICE.txt \
Projects \
+ doc/doxy.conf \
xml-security-c.spec \
+ xsec/basicTests.pl \
xsec/framework/resource.h \
xsec/framework/version.rc \
xsec/tools/threadTest/threadtest.cpp
Modified: santuario/xml-security-cpp/trunk/configure.ac
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/configure.ac?rev=1833604&r1=1833603&r2=1833604&view=diff
==============================================================================
--- santuario/xml-security-cpp/trunk/configure.ac (original)
+++ santuario/xml-security-cpp/trunk/configure.ac Fri Jun 15 15:56:20 2018
@@ -21,7 +21,7 @@ AC_INIT([[XML-Security-C]],[2.0.0],[dev@
AC_CONFIG_SRCDIR(xsec)
AC_CONFIG_AUX_DIR(build-aux)
AC_CONFIG_MACRO_DIR(m4)
-AM_INIT_AUTOMAKE([subdir-objects])
+AM_INIT_AUTOMAKE([foreign dist-bzip2 dist-zip subdir-objects nostdinc])
AC_PROG_LIBTOOL
PKG_INSTALLDIR
@@ -85,29 +85,7 @@ return (cwd != NULL) ? EXIT_SUCCESS : EX
AC_LANG(C++)
-# Xerces is required
-
-AC_ARG_WITH(xerces,AS_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
- [if test x_$with_xerces != x_/usr; then
- LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
- CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
- fi])
-LIBS="-lxerces-c $LIBS"
-
-AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
-AC_MSG_CHECKING([Xerces version])
-AC_PREPROC_IFELSE(
- [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
-[#if _XERCES_VERSION >= 30200
-int i = 0;
-#else
-#error cannot use version 1.x or 2.x
-#endif])],
- [AC_MSG_RESULT(OK)],
- [AC_MSG_FAILURE([Xerces-C 3.2+ is required])])
-
-AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]], [[xercesc::XMLPlatformUtils::Initialize()]])],
- [],[AC_MSG_ERROR([unable to link with Xerces])])
+AX_PKG_CHECK_MODULES([xerces],,[xerces-c >= 3.2])
# Get user options
@@ -185,49 +163,15 @@ fi
# Crypto provider options (OpenSSL / NSS)
-AC_ARG_WITH(openssl,
- AS_HELP_STRING([--with-openssl],[Use Openssl. Values = 'yes' or installation directory (Default = yes)]),
- use_openssl=$withval, use_openssl=yes)
-
-if test x"$use_openssl" != "xno" ; then
-
- # Check for explicit location or try pkg-config
- if test x"$use_openssl" = "xyes" ; then
- AC_PATH_PROG(PKG_CONFIG, pkg-config,)
- if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
- if pkg-config openssl ; then
- SSLLIBS="`$PKG_CONFIG --libs openssl`"
- SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
- else
- AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl=PATH instead])
- fi
- else
- SSLLIBS="-lcrypto -lssl"
- fi
- else
- if test x_$use_openssl != x_/usr; then
- SSLFLAGS="-I${use_openssl}/include"
- SSLLIBS="-L${use_openssl}/lib -lcrypto -lssl"
- else
- SSLLIBS="-lcrypto -lssl"
- fi
- fi
-
- AC_MSG_CHECKING(for OpenSSL cflags)
- AC_MSG_RESULT($SSLFLAGS)
- CPPFLAGS="$CPPFLAGS $SSLFLAGS"
-
- AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <openssl/opensslv.h>]])],
- [AC_DEFINE([XSEC_HAVE_OPENSSL],[1],[Define if OpenSSL is in use.])],
- [AC_MSG_ERROR([Unable to find OpenSSL headers])]);
-
- AC_MSG_CHECKING(for OpenSSL libraries)
- AC_MSG_RESULT($SSLLIBS)
- LIBS="$LIBS $SSLLIBS"
-
- AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/evp.h>]], [[EVP_EncryptInit(NULL, NULL, NULL, NULL) ; return 0; ]])],,
- [AC_MSG_ERROR(["Unable to find libcrypto"])])
-
+AC_ARG_WITH([openssl],
+ [AS_HELP_STRING([--with-openssl],[use the OpenSSL crypto provider @<:@default=check@:>@])],,
+ [with_openssl=check])
+
+AS_IF([test x"$with_openssl" != xno],
+ [AX_PKG_CHECK_MODULES([openssl],,[libcrypto],
+ [with_openssl=found
+ AC_DEFINE([XSEC_HAVE_OPENSSL],[1],[Define if OpenSSL is in use])
+
# Now try to find out some things about this version of OpenSSL
AC_MSG_CHECKING([for const input buffers in OpenSSL])
@@ -280,59 +224,21 @@ if test x"$use_openssl" != "xno" ; then
[AC_MSG_RESULT([yes])
AC_DEFINE([XSEC_OPENSSL_D2IX509_CONST_BUFFER],[1],[Define to 1 if OpenSSL X509 API has const input buffer.])],
[AC_MSG_RESULT([no])])
-fi
-AC_ARG_WITH(nss,
- AS_HELP_STRING([--with-nss],[Use NSS (no longer officially supported). Values = 'yes' or installation directory (Default = no)]),
- use_nss=$withval, use_nss=no)
-
-if test x"$use_nss" != "xno" ; then
-
- # Check for explicit location or try pkg-config
- if test x"$use_nss" = "xyes" ; then
- AC_PATH_PROG(PKG_CONFIG, pkg-config,)
- if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
- if pkg-config nss && pkg-config nspr; then
- NSSLIBS="`$PKG_CONFIG --libs nss` `$PKG_CONFIG --libs nspr`"
- NSSFLAGS="`$PKG_CONFIG --cflags nss` `$PKG_CONFIG --cflags nspr`"
- else
- AC_MSG_WARN([NSS not supported by pkg-config, try --with-nss=PATH instead])
- fi
- else
- check=`nss-config --version 2>/dev/null`
- if test -n "$check"; then
- NSSLIBS="`nss-config --libs` `nspr-config --libs`"
- NSSFLAGS="`nss-config --cflags` `nspr-config --cflags`"
- else
- AC_MSG_ERROR([Unable to use pkg-config or find nss-config/nspr-config, try --with-nss=PATH])
- fi
- fi
- else
- if test x_$use_nss != x_/usr; then
- NSSLIBS="-L${use_nss}/lib"
- fi
- # NSS is broken and doesn't use a standard include path.
- NSSFLAGS="-I${use_nss}/include/nss3 -I${use_nss}/include/nss -I${use_nss}/include/nspr"
- NSSLIBS="$NSSLIBS -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4"
- fi
-
- AC_MSG_CHECKING(for NSS cflags)
- AC_MSG_RESULT($NSSFLAGS)
- CPPFLAGS="$CPPFLAGS $NSSFLAGS"
-
- AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <nss.h>]])],
- [AC_DEFINE([XSEC_HAVE_NSS],[1],[Define if NSS is in use.])],
- [AC_MSG_ERROR([Unable to find NSS headers])])
-
- AC_MSG_CHECKING(for NSS libraries)
- AC_MSG_RESULT($NSSLIBS)
- LIBS="$LIBS $NSSLIBS"
-
- AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <nss.h>]], [[NSS_NoDB_Init(NULL);]])],,
- [AC_MSG_ERROR([Unable to link with NSS])])
-
- AC_MSG_WARN([NSS is no longer officially supported])
-fi
+ ],[AS_IF([test "x$with_openssl" != xcheck],[AC_MSG_ERROR([Unable to find OpenSSL])])])
+ ])
+
+AC_ARG_WITH([nss],
+ [AS_HELP_STRING([--with-nss],[use the NSS crypto provider @<:@default=check@:>@])],,
+ [with_nss=check])
+
+AS_IF([test x"$with_nss" != xno],
+ [AX_PKG_CHECK_MODULES([nss],,[nss],
+ [with_nss=found
+ AC_DEFINE([XSEC_HAVE_NSS],[1],[Define if NSS is in use])
+ AC_MSG_WARN([NSS is no longer officially supported])
+ ],[AS_IF([test "x$with_nss" != "xcheck"],[AC_MSG_ERROR([Unable to find NSS])])])
+ ])
AC_ARG_ENABLE(xkms,
AS_HELP_STRING([--disable-xkms],[disable XKMS support]),
@@ -343,8 +249,8 @@ if test x"$have_xkms" = "xyes" ; then
fi
# Populate the Makefile conditionals
-AM_CONDITIONAL(XSEC_AM_HAVE_OPENSSL, test x"$use_openssl" != "xno")
-AM_CONDITIONAL(XSEC_AM_HAVE_NSS, test x"$use_nss" != "xno")
+AM_CONDITIONAL([XSEC_AM_HAVE_OPENSSL],[test "x$with_openssl" = xfound])
+AM_CONDITIONAL([XSEC_AM_HAVE_NSS],[test "x$with_nss" = xfound])
AM_CONDITIONAL(XSEC_AM_HAVE_XKMS, test x"$have_xkms" = "xyes")
# output the Makefiles
Added: santuario/xml-security-cpp/trunk/m4/ax_pkg_check_modules.m4
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/m4/ax_pkg_check_modules.m4?rev=1833604&view=auto
==============================================================================
--- santuario/xml-security-cpp/trunk/m4/ax_pkg_check_modules.m4 (added)
+++ santuario/xml-security-cpp/trunk/m4/ax_pkg_check_modules.m4 Fri Jun 15 15:56:20 2018
@@ -0,0 +1,69 @@
+# ===========================================================================
+# https://www.gnu.org/software/autoconf-archive/ax_pkg_check_modules.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# AX_PKG_CHECK_MODULES(PREFIX, PUBLIC-MODULES, PRIVATE-MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND], [PUBLIC-VARIABLE], [PRIVATE-VARIABLE])
+#
+# DESCRIPTION
+#
+# A wrapper around PKG_CHECK_MODULES which splits the list of modules into
+# public and private dependencies, and produces two variables listing the
+# dependencies across all invocations of AX_PKG_CHECK_MODULES. These two
+# variables are exposed via AC_SUBST, and should be used in a pkg-config
+# file as the substituted values for Requires and Requires.private.
+#
+# The PREFIX, PUBLIC-MODULES and PRIVATE-MODULES arguments should be
+# specified as for PKG_CHECK_MODULES, with the concatenation of
+# PUBLIC-MODULES and PRIVATE-MODULES equaling the LIST-OF-MODULES from
+# PKG_CHECK_MODULES. The ACTION-IF-FOUND and ACTION-IF-NOT-FOUND
+# arguments are optional, and should also be specified as for
+# PKG_CHECK_MODULES. ACTION-IF-FOUND is evaluated if the full
+# LIST-OF-MODULES is found; ACTION-IF-NOT-FOUND similarly.
+#
+# PUBLIC-VARIABLE defaults to AX_PACKAGE_REQUIRES, and PRIVATE-VARIABLE
+# defaults to AX_PACKAGE_REQUIRES_PRIVATE. Both variables are AC_SUBST-ed
+# by this macro.
+#
+# For example:
+#
+# AX_PKG_CHECK_MODULES([GLIB],[glib-2.0 gio-2.0],[gthread-2.0])
+# AX_PKG_CHECK_MODULES([DBUS],[],[dbus-glib-1 >= 0.98 dbus-1])
+#
+# results in the substitutions:
+#
+# AX_PACKAGE_REQUIRES="glib-2.0 gio-2.0"
+# AX_PACKAGE_REQUIRES_PRIVATE="gthread-2.0 dbus-glib-1 >= 0.98 dbus-1"
+#
+# and can be used with a template pkg-config file (.pc.in) using:
+#
+# Requires: @AX_PACKAGE_REQUIRES@
+# Requires.private: @AX_PACKAGE_REQUIRES_PRIVATE@
+#
+# LICENSE
+#
+# Copyright (c) 2014 Philip Withnall <ph...@tecnocode.co.uk>
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved. This file is offered as-is, without any
+# warranty.
+
+#serial 4 (changed as https://bugs.freedesktop.org/show_bug.cgi?id=87154)
+
+AC_DEFUN([AX_PKG_CHECK_MODULES],[
+ m4_define([ax_package_requires],
+ [m4_default_quoted([$6],[AX_PACKAGE_REQUIRES])])
+ m4_define([ax_package_requires_private],
+ [m4_default_quoted([$7],[AX_PACKAGE_REQUIRES_PRIVATE])])
+
+ PKG_CHECK_MODULES([$1],[$2 $3],[
+ ax_package_requires="$[]ax_package_requires m4_normalize($2)"
+ ax_package_requires_private="$[]ax_package_requires_private m4_normalize($3)"
+ $4],[$5])
+
+ # Substitute output.
+ AC_SUBST(ax_package_requires)
+ AC_SUBST(ax_package_requires_private)
+])dnl AX_PKG_CHECK_MODULES
Modified: santuario/xml-security-cpp/trunk/xml-security-c.pc.in
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/xml-security-c.pc.in?rev=1833604&r1=1833603&r2=1833604&view=diff
==============================================================================
--- santuario/xml-security-cpp/trunk/xml-security-c.pc.in (original)
+++ santuario/xml-security-cpp/trunk/xml-security-c.pc.in Fri Jun 15 15:56:20 2018
@@ -3,9 +3,10 @@ exec_prefix=@exec_prefix@
libdir=@libdir@
includedir=@includedir@
-Name: XML-Security-C++
+Name: @PACKAGE_NAME@
Description: Apache XML security C++ library
Version: @VERSION@
-Libs: -L${libdir} -lxerces-c
-Libs.private: @SSLLIBS@ @NSSLIBS@
+Libs: -L${libdir} -lxml-security-c
Cflags: -I${includedir}
+Requires: @AX_PACKAGE_REQUIRES@
+Requires.private: @AX_PACKAGE_REQUIRES_PRIVATE@
Modified: santuario/xml-security-cpp/trunk/xml-security-c.spec
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/xml-security-c.spec?rev=1833604&r1=1833603&r2=1833604&view=diff
==============================================================================
--- santuario/xml-security-cpp/trunk/xml-security-c.spec (original)
+++ santuario/xml-security-cpp/trunk/xml-security-c.spec Fri Jun 15 15:56:20 2018
@@ -99,10 +99,12 @@ This package includes files needed for d
%{_libdir}/*.so
%{_libdir}/*.a
%{_libdir}/pkgconfig/xml-security-c.pc
+%exclude %{_libdir}/*.la
%changelog
* Mon Nov 13 2017 Scott Cantor <ca...@osu.edu> 2.0.0-1
- update to 2.0.0
+- exclude libtool archive
* Wed Jan 28 2015 Scott Cantor <ca...@osu.edu> 1.7.3-1
- update to 1.7.3
Modified: santuario/xml-security-cpp/trunk/xsec/Makefile.am
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/xsec/Makefile.am?rev=1833604&r1=1833603&r2=1833604&view=diff
==============================================================================
--- santuario/xml-security-cpp/trunk/xsec/Makefile.am (original)
+++ santuario/xml-security-cpp/trunk/xsec/Makefile.am Fri Jun 15 15:56:20 2018
@@ -14,13 +14,15 @@
# limitations under the License.
#
-AUTOMAKE_OPTIONS = foreign subdir-objects
-
-AM_CPPFLAGS = -I..
+# Find generated headers in the build directory;
+# find everything else in the source directory (always with full path)
+AM_CPPFLAGS = -I$(top_builddir) -I$(top_srcdir)
noinst_PROGRAMS = ${samples}
bin_PROGRAMS = ${tools}
-LDADD = libxml-security-c.la
+
+AM_CXXFLAGS = $(xerces_CFLAGS)
+LDADD = libxml-security-c.la $(xerces_LIBS)
#
# The following are sample programs. They are NOT installed
@@ -51,6 +53,10 @@ xsec_simpleEncrypt_SOURCES = \
samples/simpleEncrypt.cpp \
samples/IOStreamOutputter.cpp \
samples/IOStreamOutputter.hpp
+xsec_simpleEncrypt_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(openssl_CFLAGS)
+xsec_simpleEncrypt_LDADD = $(LDADD) \
+ $(openssl_LIBS)
# Decrypt
@@ -59,6 +65,10 @@ xsec_simpleDecrypt_SOURCES = \
samples/simpleDecrypt.cpp \
samples/IOStreamOutputter.cpp \
samples/IOStreamOutputter.hpp
+xsec_simpleDecrypt_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(openssl_CFLAGS)
+xsec_simpleDecrypt_LDADD = $(LDADD) \
+ $(openssl_LIBS)
#
# Finally we compile the tools that can be used to manipulate
@@ -72,12 +82,18 @@ tools =
tools += xsec-xtest
xsec_xtest_SOURCES = \
tools/xtest/xtest.cpp
-xsec_xtest_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_xtest_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
+xsec_xtest_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(nss_CFLAGS) \
+ $(openssl_CFLAGS)
+xsec_xtest_LDADD = $(LDADD) \
+ $(nss_LIBS) \
+ $(openssl_LIBS)
tools += xsec-c14n
xsec_c14n_SOURCES = \
tools/c14n/c14n.cpp
-xsec_c14n_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_c14n_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
tools += xsec-checksig
xsec_checksig_SOURCES = \
@@ -86,39 +102,69 @@ xsec_checksig_SOURCES = \
tools/checksig/AnonymousResolver.cpp \
tools/checksig/InteropResolver.hpp \
tools/checksig/InteropResolver.cpp
-xsec_checksig_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_checksig_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
+xsec_checksig_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(nss_CFLAGS) \
+ $(openssl_CFLAGS)
+xsec_checksig_LDADD = $(LDADD) \
+ $(nss_LIBS) \
+ $(openssl_LIBS)
tools += xsec-templatesign
xsec_templatesign_SOURCES = \
tools/templatesign/templatesign.cpp
-xsec_templatesign_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_templatesign_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
+xsec_templatesign_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(openssl_CFLAGS)
+xsec_templatesign_LDADD = $(LDADD) \
+ $(openssl_LIBS)
tools += xsec-txfmout
xsec_txfmout_SOURCES = \
tools/txfmout/txfmout.cpp
-xsec_txfmout_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_txfmout_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
tools += xsec-siginf
xsec_siginf_SOURCES = \
tools/siginf/siginf.cpp
-xsec_siginf_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_siginf_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
tools += xsec-cipher
xsec_cipher_SOURCES = \
tools/cipher/cipher.cpp \
tools/cipher/XencInteropResolver.hpp \
tools/cipher/XencInteropResolver.cpp
-xsec_cipher_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_cipher_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
+xsec_cipher_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(nss_CFLAGS) \
+ $(openssl_CFLAGS)
+xsec_cipher_LDADD = $(LDADD) \
+ $(nss_LIBS) \
+ $(openssl_LIBS)
if XSEC_AM_HAVE_XKMS
tools += xsec-xklient
xsec_xklient_SOURCES = \
tools/xklient/xklient.cpp \
enc/OpenSSL/OpenSSLSupport.hpp
-xsec_xklient_CPPFLAGS = -DXSEC_BUILDING_TOOLS
+xsec_xklient_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_TOOLS
+xsec_xklient_CXXFLAGS = $(AM_CXXFLAGS) \
+ $(openssl_CFLAGS)
+xsec_xklient_LDADD = $(LDADD) \
+ $(openssl_LIBS)
endif
-libxml_security_c_la_CPPFLAGS = -DXSEC_BUILDING_LIBRARY
+libxml_security_c_la_CPPFLAGS = $(AM_CPPFLAGS) -DXSEC_BUILDING_LIBRARY
+
+libxml_security_c_la_CXXFLAGS = \
+ $(xerces_CFLAGS) \
+ $(openssl_CFLAGS) \
+ $(nss_CFLAGS)
+
+libxml_security_c_la_LIBADD = \
+ $(xerces_LIBS) \
+ $(openssl_LIBS) \
+ $(nss_LIBS)
lib_LTLIBRARIES = libxml-security-c.la
@@ -232,12 +278,14 @@ frameworkinclude_HEADERS = \
framework/XSECException.hpp \
framework/XSECError.hpp \
framework/XSECProvider.hpp \
- framework/XSECConfig.hpp \
framework/XSECURIResolverXerces.hpp \
framework/XSECAlgorithmMapper.hpp \
framework/XSECW32Config.hpp \
framework/XSECVersion.hpp
+nodist_frameworkinclude_HEADERS = \
+ framework/XSECConfig.hpp
+
transformersinclude_HEADERS = \
transformers/TXFMXPathFilter.hpp \
transformers/TXFMHash.hpp \
@@ -602,9 +650,6 @@ nss_sources = \
#
libxml_security_c_la_LDFLAGS = -version-info 20:0:0
-install-exec-hook:
- for la in $(lib_LTLIBRARIES) ; do rm -f $(DESTDIR)$(libdir)/$$la ; done
-
EXTRA_DIST = \
utils/winutils/XSECSOAPRequestorSimpleWin32.cpp \
enc/WinCAPI/WinCAPICryptoProvider.cpp \
Modified: santuario/xml-security-cpp/trunk/xsec/samples/IOStreamOutputter.cpp
URL: http://svn.apache.org/viewvc/santuario/xml-security-cpp/trunk/xsec/samples/IOStreamOutputter.cpp?rev=1833604&r1=1833603&r2=1833604&view=diff
==============================================================================
--- santuario/xml-security-cpp/trunk/xsec/samples/IOStreamOutputter.cpp (original)
+++ santuario/xml-security-cpp/trunk/xsec/samples/IOStreamOutputter.cpp Fri Jun 15 15:56:20 2018
@@ -36,7 +36,7 @@
*/
#include "IOStreamOutputter.hpp"
-#include "utils/XSECDOMUtils.hpp"
+#include "../utils/XSECDOMUtils.hpp"
#include <xercesc/parsers/XercesDOMParser.hpp>