You are viewing a plain text version of this content. The canonical link for it is here.
Posted to dev@subversion.apache.org by Garrett Rooney <ro...@electricjellyfish.net> on 2002/09/07 20:07:02 UTC
[PATCH] --disable-swig argument for configure
In the FreeBSD port of subversion, we have to control the building of
the SWIG bindings, because depending on the existence of the correct
version of SWIG on the system, we could have some extra libraries
installed, which the package management tools have to deal with...
Currently, I work around the issue by hacking the makefile at build
time to avoid installing the libraries we build when SWIG is found, but
I'd rather be able to pass a --disable-swig argument to configure (and
also have this be conditional on some option in the port's Makefile, so
we can optionally install the SWIG libraries once there are tools which
use them).
Here's a patch that implements this option. It seems to work, and I'd
commit it now, but I'd like someone with a bit more autoconf knowledge
to look over it first and make sure I didn't make any stupid mistakes.
Thanks,
-garrett
Index: configure.in
===================================================================
--- configure.in
+++ configure.in Sat Sep 7 15:45:28 2002
@@ -308,34 +308,50 @@
${PYTHON} ${abs_srcdir}/build/pycheck.py
fi
+dnl let people turn off the swig bindings here, even if swig exists on
+dnl their system
+LOOK_FOR_SWIG="true"
+AC_ARG_ENABLE(swig,
+[ --disable-swig Do not try to build the SWIG bindings],
+[
+ if test "$enableval" = "yes" ; then
+ AC_MSG_NOTICE([Enabling search for SWIG])
+ else
+ LOOK_FOR_SWIG="false"
+ AC_MSG_NOTICE([Disabling search for SWIG])
+ fi
+])
+
dnl try to find "swig" to build the SWIG bindings
-AC_PATH_PROG(SWIG, swig, none)
-if test "$SWIG" != "none"; then
- AC_MSG_CHECKING([swig version])
- SWIG_VERSION="`$SWIG -version 2>&1 | sed -ne 's/^.*Version
\(.*\)$/\1/p'`"
- AC_MSG_RESULT([$SWIG_VERSION])
- case $SWIG_VERSION in
- [1.3.1[23]*])
- SWIG_SUITABLE=yes
- ;;
- *)
- SWIG_SUITABLE=no
- AC_MSG_WARN([swig bindings require 1.3.12.])
- ;;
- esac
- if test "$PYTHON" != "none" -a "$SWIG_SUITABLE" = "yes"; then
- SWIG_BUILD_RULES="$SWIG_BUILD_RULES swig-py-lib"
- SWIG_INSTALL_RULES="$SWIG_INSTALL_RULES install-swig-py-lib"
+if test "$LOOK_FOR_SWIG" = "true"; then
+ AC_PATH_PROG(SWIG, swig, none)
+ if test "$SWIG" != "none"; then
+ AC_MSG_CHECKING([swig version])
+ SWIG_VERSION="`$SWIG -version 2>&1 | sed -ne 's/^.*Version
\(.*\)$/\1/p'`"
+ AC_MSG_RESULT([$SWIG_VERSION])
+ case $SWIG_VERSION in
+ [1.3.1[23]*])
+ SWIG_SUITABLE=yes
+ ;;
+ *)
+ SWIG_SUITABLE=no
+ AC_MSG_WARN([swig bindings require 1.3.12.])
+ ;;
+ esac
+ if test "$PYTHON" != "none" -a "$SWIG_SUITABLE" = "yes"; then
+ SWIG_BUILD_RULES="$SWIG_BUILD_RULES swig-py-lib"
+ SWIG_INSTALL_RULES="$SWIG_INSTALL_RULES install-swig-py-lib"
- AC_CACHE_CHECK([for Python includes], [ac_cv_python_includes],[
- ac_cv_python_includes="`$PYTHON
${abs_srcdir}/ac-helpers/get-py-info.py --includes`"
- ])
- SWIG_PY_INCLUDES="-I$ac_cv_python_includes"
+ AC_CACHE_CHECK([for Python includes], [ac_cv_python_includes],[
+ ac_cv_python_includes="`$PYTHON
${abs_srcdir}/ac-helpers/get-py-info.py --includes`"
+ ])
+ SWIG_PY_INCLUDES="-I$ac_cv_python_includes"
+ fi
fi
+ AC_SUBST(SWIG_BUILD_RULES)
+ AC_SUBST(SWIG_INSTALL_RULES)
+ AC_SUBST(SWIG_PY_INCLUDES)
fi
-AC_SUBST(SWIG_BUILD_RULES)
-AC_SUBST(SWIG_INSTALL_RULES)
-AC_SUBST(SWIG_PY_INCLUDES)
dnl try to find the "makeinfo" program
AC_PATH_PROG(MAKEINFO, makeinfo, [echo cannot run makeinfo])
--
garrett rooney Remember, any design flaw you're
rooneg@electricjellyfish.net sufficiently snide about becomes
http://electricjellyfish.net/ a feature. -- Dan Sugalski
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Branko Čibej <br...@xbc.nu>.
Justin Erenkrantz wrote:
>On Sat, Sep 07, 2002 at 04:07:02PM -0400, Garrett Rooney wrote:
>
>
>>Here's a patch that implements this option. It seems to work, and I'd
>>commit it now, but I'd like someone with a bit more autoconf knowledge
>>to look over it first and make sure I didn't make any stupid mistakes.
>>
>>
>
>+1. Looks fine.
>
>Only question I have is whether the option should be "--with-swig"
>rather than "--enable-swig" - I've never fully groked the rules on
>this, but my hunch is that it should be AC_ARG_WITH not AC_ARG_ENABLE.
>But, I don't care much either way. -- justin
>
>
It's --with-PACKAGE[=DIR] and --enable-FEATURE. SWIG is a package, not a
feature. And I *do* care, because lots of people will be confused if we
use the wrong switch. So, please make that --with-swig[=DIR] and
--without-swig.
(Note that --with-swig=no is the same as --without-swig, and that plain
--with-swig is the same as --with-swig=yes. No, you don't have to do
anything to make that work, autoconf will do it for you.)
--
Brane Čibej <br...@xbc.nu> http://www.xbc.nu/brane/
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Garrett Rooney <ro...@electricjellyfish.net>.
On Sunday, September 8, 2002, at 09:20 AM, Garrett Rooney wrote:
> On Sunday, September 8, 2002, at 05:56 AM, Peter Davis wrote:
>
>> On Saturday 07 September 2002 18:08, Greg Stein wrote:
>>> $ ./configure --with-swig=/home/gstein/src/SWIG
>>
>> If Garrett can get this working, then I'll... be really happy.
>> Relying on the
>> system swig was one of my major showstoppers, because I run Gentoo
>> Linux for
>> which all of the swig packages are older "stable" versions. So I
>> installed
>> my own swig aside the Gentoo packages, but I had to hack the build to
>> use it.
>>
>> So, thanks! I'll love you for it!
>
> Well, if you've got a free second, try this patch and let me know if
> it works for you. I think it should, but the system I'm testing it on
> doesn't actually have SWIG installed, and I won't be able to test on
> one that does until later today.
i just committed somethign pretty close to this in revision 3145. the
only difference is that i moved the AC_ARG_WITH stuff inside
SVN_CHECK_SWIG, which necesitated moving the stuff that used to be in
SVN_CHECK_SWIG into a helper function (SVN_FIND_SWIG). i believe this
is what Branko was asking for in one of his reviews of these patches.
-garrett
--
garrett rooney Remember, any design flaw you're
rooneg@electricjellyfish.net sufficiently snide about becomes
http://electricjellyfish.net/ a feature. -- Dan Sugalski
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Garrett Rooney <ro...@electricjellyfish.net>.
On Sunday, September 8, 2002, at 05:56 AM, Peter Davis wrote:
> On Saturday 07 September 2002 18:08, Greg Stein wrote:
>> $ ./configure --with-swig=/home/gstein/src/SWIG
>
> If Garrett can get this working, then I'll... be really happy.
> Relying on the
> system swig was one of my major showstoppers, because I run Gentoo
> Linux for
> which all of the swig packages are older "stable" versions. So I
> installed
> my own swig aside the Gentoo packages, but I had to hack the build to
> use it.
>
> So, thanks! I'll love you for it!
Well, if you've got a free second, try this patch and let me know if it
works for you. I think it should, but the system I'm testing it on
doesn't actually have SWIG installed, and I won't be able to test on
one that does until later today.
(attaching the patch so it won't get mangled like the last one did)
-garrett
Re: [PATCH] --disable-swig argument for configure
Posted by Peter Davis <pe...@pdavis.cx>.
On Saturday 07 September 2002 18:08, Greg Stein wrote:
> $ ./configure --with-swig=/home/gstein/src/SWIG
If Garrett can get this working, then I'll... be really happy. Relying on the
system swig was one of my major showstoppers, because I run Gentoo Linux for
which all of the swig packages are older "stable" versions. So I installed
my own swig aside the Gentoo packages, but I had to hack the build to use it.
So, thanks! I'll love you for it!
--
Peter Davis
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Greg Stein <gs...@lyra.org>.
On Sat, Sep 07, 2002 at 06:43:31PM -0400, Garrett Rooney wrote:
> On Saturday, September 7, 2002, at 05:59 PM, Justin Erenkrantz wrote:
>...
> > Only question I have is whether the option should be "--with-swig"
> > rather than "--enable-swig" - I've never fully groked the rules on
> > this, but my hunch is that it should be AC_ARG_WITH not AC_ARG_ENABLE.
> > But, I don't care much either way. -- justin
>
> as much as i hate to admit it (because admitting it means i get to
> write more m4, and i hate writing m4), you have a point, AC_ARG_WITH
> does sound more appropriate. i'll see what i can do about making it
> use that instead.
AC_ARG_WITH is used to specify a package, while AC_ARG_ENABLE is to turn
on/off features. In this case, the "proper" thing to do is use ARG_WITH and
enable path processing. That would allow a person to do:
$ ./configure --with-swig=/home/gstein/src/SWIG
So that I can use a private copy of SWIG (which has the Right Version),
instead of the system copy.
Cheers,
-g
--
Greg Stein, http://www.lyra.org/
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Garrett Rooney <ro...@electricjellyfish.net>.
On Saturday, September 7, 2002, at 09:18 PM, Greg Stein wrote:
> On Sat, Sep 07, 2002 at 07:53:00PM -0400, Garrett Rooney wrote:
>> ...
>> +AC_ARG_WITH(swig,
>> + [AC_HELP_STRING([--with-swig],
>> + [Try to find a suitable SWIG and build
>> the
>> SWIG
>
> Yup. Your mailer killed the patch. Nice wrap there :-)
>
> (while you'll be able to commit directly, it does make it hard for
> "us" to
> try out the patch... no matter; I'll just review/comment...)
sorry about that, thanks for the review...
>> + bindings with it.])],
>> +[
>> + if test "$withval" = "no" ; then
>> + SWIG_SUITABLE=no
>> + else
>> + AC_PATH_PROG(SWIG, swig, none)
>> + SVN_CHECK_SWIG
>> fi
>> -fi
>> -AC_SUBST(SWIG_BUILD_RULES)
>> -AC_SUBST(SWIG_INSTALL_RULES)
>> -AC_SUBST(SWIG_PY_INCLUDES)
>> +],
>> +[
>> + AC_PATH_PROG(SWIG, swig, none)
>> + SVN_CHECK_SWIG
>> +])
>
> It seems that SVN_CHECK_SWIG should take an optional directory. The
> AC_PATH_PROG would move inside SVN_CHECK_SWIG (note that the two are
> always
> paired in your code above).
>
> $withval will be "no" if somebody says --with-swig=no or
> --without-swig.
> $withval will be "yes" if they say --with-swig. $withval will contain
> VALUE
> if they say --with-swig=VALUE.
>
> The test conditions should consider the "yes" vs VALUE cases.
yeah, this occured to me when i was writing it, and wouldn't be too
hard to add. i should be able to add support for that sometime
tomorrow.
>> +++ ac-helpers/swig.m4 Sat Sep 7 19:30:16 2002
>> @@ -0,0 +1,36 @@
>> +dnl check to see if SWIG is current enough.
>> +dnl
>> +dnl if it is, then check to see if we have the correct version of
>> pyton.
>
> s/pyton/python/
oops.
>> ...
>
>
> In general, the patch is fine, but (if checked in now) could use a
> couple
> small iterations.
i'll make the changes people have requested and commit the patch either
later tonight or sometime tomorrow.
thanks for the extra sets of eyes everyone...
-garrett
--
garrett rooney Remember, any design flaw you're
rooneg@electricjellyfish.net sufficiently snide about becomes
http://electricjellyfish.net/ a feature. -- Dan Sugalski
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Greg Stein <gs...@lyra.org>.
On Sat, Sep 07, 2002 at 07:53:00PM -0400, Garrett Rooney wrote:
>...
> +AC_ARG_WITH(swig,
> + [AC_HELP_STRING([--with-swig],
> + [Try to find a suitable SWIG and build the
> SWIG
Yup. Your mailer killed the patch. Nice wrap there :-)
(while you'll be able to commit directly, it does make it hard for "us" to
try out the patch... no matter; I'll just review/comment...)
> + bindings with it.])],
> +[
> + if test "$withval" = "no" ; then
> + SWIG_SUITABLE=no
> + else
> + AC_PATH_PROG(SWIG, swig, none)
> + SVN_CHECK_SWIG
> fi
> -fi
> -AC_SUBST(SWIG_BUILD_RULES)
> -AC_SUBST(SWIG_INSTALL_RULES)
> -AC_SUBST(SWIG_PY_INCLUDES)
> +],
> +[
> + AC_PATH_PROG(SWIG, swig, none)
> + SVN_CHECK_SWIG
> +])
It seems that SVN_CHECK_SWIG should take an optional directory. The
AC_PATH_PROG would move inside SVN_CHECK_SWIG (note that the two are always
paired in your code above).
$withval will be "no" if somebody says --with-swig=no or --without-swig.
$withval will be "yes" if they say --with-swig. $withval will contain VALUE
if they say --with-swig=VALUE.
The test conditions should consider the "yes" vs VALUE cases.
> +++ ac-helpers/swig.m4 Sat Sep 7 19:30:16 2002
> @@ -0,0 +1,36 @@
> +dnl check to see if SWIG is current enough.
> +dnl
> +dnl if it is, then check to see if we have the correct version of
> pyton.
s/pyton/python/
>...
In general, the patch is fine, but (if checked in now) could use a couple
small iterations.
Cheers,
-g
--
Greg Stein, http://www.lyra.org/
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Branko Čibej <br...@xbc.nu>.
Garrett Rooney wrote:
> On Saturday, September 7, 2002, at 06:43 PM, Garrett Rooney wrote:
>
>> as much as i hate to admit it (because admitting it means i get to
>> write more m4, and i hate writing m4), you have a point, AC_ARG_WITH
>> does sound more appropriate. i'll see what i can do about making it
>> use that instead.
>
>
> Ok, here's a patch that uses AC_ARG_WITH.
>
> It also moves the code to check the SWIG version into
> ac-helpers/swig.m4, since it was going to have to be used in more than
> one place and it seems like our stuff seems to do that as soon as you
> need to AC_DEFUN something.
Most of this looks fine, but it ignores any explicit path supplied to
--with-swig. Could you add that? Look at how we find Berkeley DB, or
APR, or APR-util ... in fact, factoring out the $withval handling would
be nice, too.
--
Brane Čibej <br...@xbc.nu> http://www.xbc.nu/brane/
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Garrett Rooney <ro...@electricjellyfish.net>.
On Saturday, September 7, 2002, at 06:43 PM, Garrett Rooney wrote:
> as much as i hate to admit it (because admitting it means i get to
> write more m4, and i hate writing m4), you have a point, AC_ARG_WITH
> does sound more appropriate. i'll see what i can do about making it
> use that instead.
Ok, here's a patch that uses AC_ARG_WITH.
It also moves the code to check the SWIG version into
ac-helpers/swig.m4, since it was going to have to be used in more than
one place and it seems like our stuff seems to do that as soon as you
need to AC_DEFUN something.
-garrett
Index: configure.in
===================================================================
--- configure.in
+++ configure.in Sat Sep 7 19:44:49 2002
@@ -34,6 +34,7 @@
sinclude(ac-helpers/apr.m4)
sinclude(ac-helpers/find_apu.m4)
sinclude(ac-helpers/aprutil.m4)
+sinclude(ac-helpers/swig.m4)
dnl Grab the libtool macros
sinclude(ac-helpers/libtool.m4)
@@ -308,34 +309,22 @@
${PYTHON} ${abs_srcdir}/build/pycheck.py
fi
-dnl try to find "swig" to build the SWIG bindings
-AC_PATH_PROG(SWIG, swig, none)
-if test "$SWIG" != "none"; then
- AC_MSG_CHECKING([swig version])
- SWIG_VERSION="`$SWIG -version 2>&1 | sed -ne 's/^.*Version
\(.*\)$/\1/p'`"
- AC_MSG_RESULT([$SWIG_VERSION])
- case $SWIG_VERSION in
- [1.3.1[23]*])
- SWIG_SUITABLE=yes
- ;;
- *)
- SWIG_SUITABLE=no
- AC_MSG_WARN([swig bindings require 1.3.12.])
- ;;
- esac
- if test "$PYTHON" != "none" -a "$SWIG_SUITABLE" = "yes"; then
- SWIG_BUILD_RULES="$SWIG_BUILD_RULES swig-py-lib"
- SWIG_INSTALL_RULES="$SWIG_INSTALL_RULES install-swig-py-lib"
-
- AC_CACHE_CHECK([for Python includes], [ac_cv_python_includes],[
- ac_cv_python_includes="`$PYTHON
${abs_srcdir}/ac-helpers/get-py-info.py --includes`"
- ])
- SWIG_PY_INCLUDES="-I$ac_cv_python_includes"
+AC_ARG_WITH(swig,
+ [AC_HELP_STRING([--with-swig],
+ [Try to find a suitable SWIG and build the
SWIG
+ bindings with it.])],
+[
+ if test "$withval" = "no" ; then
+ SWIG_SUITABLE=no
+ else
+ AC_PATH_PROG(SWIG, swig, none)
+ SVN_CHECK_SWIG
fi
-fi
-AC_SUBST(SWIG_BUILD_RULES)
-AC_SUBST(SWIG_INSTALL_RULES)
-AC_SUBST(SWIG_PY_INCLUDES)
+],
+[
+ AC_PATH_PROG(SWIG, swig, none)
+ SVN_CHECK_SWIG
+])
dnl try to find the "makeinfo" program
AC_PATH_PROG(MAKEINFO, makeinfo, [echo cannot run makeinfo])
Index: ac-helpers/swig.m4
===================================================================
--- ac-helpers/swig.m4
+++ ac-helpers/swig.m4 Sat Sep 7 19:30:16 2002
@@ -0,0 +1,36 @@
+dnl check to see if SWIG is current enough.
+dnl
+dnl if it is, then check to see if we have the correct version of
pyton.
+dnl
+dnl if we do, then set up the appropriate SWIG_ variables to build the
+dnl python bindings.
+
+AC_DEFUN(SVN_CHECK_SWIG,
+[
+ if test "$SWIG" != "none"; then
+ AC_MSG_CHECKING([swig version])
+ SWIG_VERSION="`$SWIG -version 2>&1 | sed -ne 's/^.*Version
\(.*\)$/\1/p'`"
+ AC_MSG_RESULT([$SWIG_VERSION])
+ case $SWIG_VERSION in
+ [1.3.1[23]*])
+ SWIG_SUITABLE=yes
+ ;;
+ *)
+ SWIG_SUITABLE=no
+ AC_MSG_WARN([swig bindings require 1.3.12.])
+ ;;
+ esac
+ if test "$PYTHON" != "none" -a "$SWIG_SUITABLE" = "yes"; then
+ SWIG_BUILD_RULES="$SWIG_BUILD_RULES swig-py-lib"
+ SWIG_INSTALL_RULES="$SWIG_INSTALL_RULES install-swig-py-lib"
+
+ AC_CACHE_CHECK([for Python includes], [ac_cv_python_includes],[
+ ac_cv_python_includes="`$PYTHON
${abs_srcdir}/ac-helpers/get-py-info.py --includes`"
+ ])
+ SWIG_PY_INCLUDES="-I$ac_cv_python_includes"
+ fi
+ fi
+ AC_SUBST(SWIG_BUILD_RULES)
+ AC_SUBST(SWIG_INSTALL_RULES)
+ AC_SUBST(SWIG_PY_INCLUDES)
+])
--
garrett rooney Remember, any design flaw you're
rooneg@electricjellyfish.net sufficiently snide about becomes
http://electricjellyfish.net/ a feature. -- Dan Sugalski
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Garrett Rooney <ro...@electricjellyfish.net>.
On Saturday, September 7, 2002, at 05:59 PM, Justin Erenkrantz wrote:
> On Sat, Sep 07, 2002 at 04:07:02PM -0400, Garrett Rooney wrote:
>> Here's a patch that implements this option. It seems to work, and I'd
>> commit it now, but I'd like someone with a bit more autoconf knowledge
>> to look over it first and make sure I didn't make any stupid mistakes.
>
> +1. Looks fine.
>
> Only question I have is whether the option should be "--with-swig"
> rather than "--enable-swig" - I've never fully groked the rules on
> this, but my hunch is that it should be AC_ARG_WITH not AC_ARG_ENABLE.
> But, I don't care much either way. -- justin
as much as i hate to admit it (because admitting it means i get to
write more m4, and i hate writing m4), you have a point, AC_ARG_WITH
does sound more appropriate. i'll see what i can do about making it
use that instead.
-garrett
--
garrett rooney Remember, any design flaw you're
rooneg@electricjellyfish.net sufficiently snide about becomes
http://electricjellyfish.net/ a feature. -- Dan Sugalski
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org
Re: [PATCH] --disable-swig argument for configure
Posted by Justin Erenkrantz <je...@apache.org>.
On Sat, Sep 07, 2002 at 04:07:02PM -0400, Garrett Rooney wrote:
> Here's a patch that implements this option. It seems to work, and I'd
> commit it now, but I'd like someone with a bit more autoconf knowledge
> to look over it first and make sure I didn't make any stupid mistakes.
+1. Looks fine.
Only question I have is whether the option should be "--with-swig"
rather than "--enable-swig" - I've never fully groked the rules on
this, but my hunch is that it should be AC_ARG_WITH not AC_ARG_ENABLE.
But, I don't care much either way. -- justin
---------------------------------------------------------------------
To unsubscribe, e-mail: dev-unsubscribe@subversion.tigris.org
For additional commands, e-mail: dev-help@subversion.tigris.org