You are viewing a plain text version of this content. The canonical link for it is here.
Posted to cvs@httpd.apache.org by do...@apache.org on 2001/01/02 06:02:33 UTC
cvs commit: httpd-2.0 .gdbinit
dougm 01/01/01 21:02:33
Modified: . .gdbinit
Log:
add dump_{bucket,brigade} macros
Revision Changes Path
1.4 +36 -0 httpd-2.0/.gdbinit
Index: .gdbinit
===================================================================
RCS file: /home/cvs/httpd-2.0/.gdbinit,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- .gdbinit 2000/12/20 05:38:34 1.3
+++ .gdbinit 2001/01/02 05:02:33 1.4
@@ -31,3 +31,39 @@
document dump_string_array
Print all of the elements in an array of strings.
end
+
+define dump_bucket
+ set $bucket = $arg0
+ printf "bucket=%s(0x%lx), length=%ld, data=0x%lx\n", \
+ $bucket->type->name, \
+ (unsigned long)$bucket, (long)$bucket->length, \
+ (unsigned long)$bucket->data
+end
+document dump_bucket
+ Print bucket info
+end
+
+define dump_brigade
+ set $bb = $arg0
+ set $bucket = ((&((ap_bucket_brigade *)$bb)->list))->next
+ set $sentinel = ((char *)((&(((ap_bucket_brigade *)$bb)->list)) \
+ - ((size_t) &((struct ap_bucket *)0)->link)))
+ set $i = 0
+
+ printf "dump of brigade 0x%lx\n", (unsigned long)$bb
+ if $bucket == $sentinel
+ printf "brigade is empty\n"
+ end
+
+ while $bucket != $sentinel
+ printf " %d: bucket=%s(0x%lx), length=%ld, data=0x%lx\n", \
+ $i, $bucket->type->name, \
+ (unsigned long)$bucket, (long)$bucket->length, \
+ (unsigned long)$bucket->data
+ set $i = $i + 1
+ set $bucket = $bucket->link.next
+ end
+end
+document dump_brigade
+ Print bucket brigade info
+end
\ No newline at end of file