You are viewing a plain text version of this content. The canonical link for it is here.
Posted to dev@tomcat.apache.org by cr...@apache.org on 2001/05/19 03:14:33 UTC
cvs commit: jakarta-tomcat-4.0/catalina/docs/dev/xdocs/stylesheets tempoarary.xsl
craigmcc 01/05/18 18:14:33
Added: catalina/docs/dev/xdocs/stylesheets tempoarary.xsl
Log:
Add a temporary XSLT stylesheet (cribbed from the one in Struts) that can
be used until the overall documentation for Tomcat is Anakia-ized (or
whatever final choice we make).
Revision Changes Path
1.1 jakarta-tomcat-4.0/catalina/docs/dev/xdocs/stylesheets/tempoarary.xsl
Index: tempoarary.xsl
===================================================================
<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Temporary Stylesheet for Catalina Developer Documentation -->
<!-- $Id: tempoarary.xsl,v 1.1 2001/05/19 01:14:33 craigmcc Exp $ -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<!-- Output method -->
<xsl:output method="html" indent="yes"/>
<!-- Defined variables -->
<xsl:variable name="body-bg" select="'#ffffff'"/>
<xsl:variable name="body-fg" select="'#000000'"/>
<xsl:variable name="body-link" select="'#023264'"/>
<xsl:variable name="banner-bg" select="'#023264'"/>
<xsl:variable name="banner-fg" select="'#ffffff'"/>
<!-- Process an entire document into an HTML page -->
<xsl:template match="document">
<xsl:variable name="project"
select="document('project.xml')/project"/>
<html>
<head>
<meta name="author" content="{properties/author/.}"/>
<!-- <link rel="stylesheet" type="text/css" href="default.css"/> -->
<xsl:choose>
<xsl:when test="properties/title">
<title><xsl:value-of select="properties/title"/></title>
</xsl:when>
<xsl:when test="body/title">
<title><xsl:value-of select="body/title"/></title>
</xsl:when>
<xsl:otherwise>
<title><xsl:value-of select="$project/title"/></title>
</xsl:otherwise>
</xsl:choose>
</head>
<body bgcolor="{$body-bg}" text="{$body-fg}" link="{$body-link}"
alink="{$body-link}" vlink="{$body-link}">
<table border="0" width="100%" cellspacing="5">
<tr><td colspan="2">
<a href="http://jakarta.apache.org">
<img src="images/jakarta-logo.gif" align="left" border="0"/>
</a>
<img src="images/tomcat.gif" align="right" border="0"/>
</td></tr>
<tr><td colspan="2">
<hr/>
</td></tr>
<tr>
<td width="120" valign="top">
<xsl:apply-templates select="$project"/>
</td>
<td valign="top">
<xsl:apply-templates select="body"/>
</td>
</tr>
<tr><td colspan="2">
<hr/>
</td></tr>
<tr><td colspan="2">
<div align="center"><font color="{$body-link}" size="-1"><em>
Copyright (c) 2000-2001, Apache Software Foundation
</em></font></div>
<img src="images/tomcat-power.gif" align="right" border="0"/>
</td></tr>
</table>
</body>
</html>
</xsl:template>
<!-- Process a menu for the navigation bar -->
<xsl:template match="menu">
<table border="0" cellspacing="5">
<tr>
<th colspan="2" align="left">
<font color="{body-link}"><strong>
<xsl:value-of select="@name"/>
</strong></font>
</th>
</tr>
<xsl:apply-templates/>
</table>
</xsl:template>
<!-- Process a menu item for the navigation bar -->
<xsl:template match="item">
<tr>
<td align="center" width="15"></td>
<td>
<font size="-1">
<xsl:variable name="href">
<xsl:value-of select="@href"/>
</xsl:variable>
<a href="{$href}"><xsl:value-of select="@name"/></a>
</font>
</td>
</tr>
</xsl:template>
<!-- Process a documentation section -->
<xsl:template match="section">
<xsl:choose>
<xsl:when test="@href">
<xsl:variable name="href">
<xsl:value-of select="@href"/>
</xsl:variable>
<a name="{$href}"></a>
</xsl:when>
</xsl:choose>
<table border="0" cellspacing="5" cellpadding="5" width="100%">
<tr><td bgcolor="{$banner-bg}">
<font color="{$banner-fg}" face="arial,helvetica,sanserif" size="+1">
<strong><xsl:value-of select="@name"/></strong>
</font>
</td></tr>
<tr><td>
<blockquote>
<xsl:apply-templates/>
</blockquote>
</td></tr>
</table>
</xsl:template>
<!-- Process a documentation subsection -->
<xsl:template match="subsection">
<xsl:choose>
<xsl:when test="@href">
<xsl:variable name="href">
<xsl:value-of select="@href"/>
</xsl:variable>
<a name="{$href}"></a>
</xsl:when>
</xsl:choose>
<table border="0" cellspacing="5" cellpadding="5" width="100%">
<tr><td bgcolor="{$banner-bg}">
<font color="{$banner-fg}" face="arial,helvetica,sanserif" size="+1">
<xsl:value-of select="@name"/>
</font>
</td></tr>
<tr><td>
<blockquote>
<xsl:apply-templates/>
</blockquote>
</td></tr>
</table>
</xsl:template>
<!-- Process a source code example -->
<xsl:template match="source">
<table border="1" cellpadding="5">
<tr><td><pre>
<xsl:apply-templates/>
</pre></td></tr>
</table>
</xsl:template>
<!-- Process an individual paragraph -->
<xsl:template match="p">
<p><xsl:apply-templates/><br/></p>
</xsl:template>
<!-- Process everything else by just passing it through -->
<xsl:template match="*|@*">
<xsl:copy>
<xsl:apply-templates select="@*|*|text()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>