You are viewing a plain text version of this content. The canonical link for it is here.
Posted to commits@cayenne.apache.org by aa...@apache.org on 2006/05/21 22:35:00 UTC
svn commit: r408485 - in
/incubator/cayenne/main/trunk/cayenne-regression-profiler: build-jmeter.xml
src/main/jmeter/jmeter-results-report.xsl
Author: aadamchik
Date: Sun May 21 13:35:00 2006
New Revision: 408485
URL: http://svn.apache.org/viewvc?rev=408485&view=rev
Log:
added JMeter client Ant task
Added:
incubator/cayenne/main/trunk/cayenne-regression-profiler/build-jmeter.xml
incubator/cayenne/main/trunk/cayenne-regression-profiler/src/main/jmeter/jmeter-results-report.xsl
Added: incubator/cayenne/main/trunk/cayenne-regression-profiler/build-jmeter.xml
URL: http://svn.apache.org/viewvc/incubator/cayenne/main/trunk/cayenne-regression-profiler/build-jmeter.xml?rev=408485&view=auto
==============================================================================
--- incubator/cayenne/main/trunk/cayenne-regression-profiler/build-jmeter.xml (added)
+++ incubator/cayenne/main/trunk/cayenne-regression-profiler/build-jmeter.xml Sun May 21 13:35:00 2006
@@ -0,0 +1,31 @@
+<!--
+ An ant file to run JMeter client.
+-->
+<project default="jmeter">
+
+ <path id="jmeter.classpath">
+ <fileset dir="${jmeter.home}/" includes="**/*.jar"/>
+ </path>
+
+ <target name="jmeter">
+ <taskdef
+ name="jmeter"
+ classname="org.programmerplanet.ant.taskdefs.jmeter.JMeterTask"
+ classpathref="jmeter.classpath"/>
+
+ <delete>
+ <fileset dir="target/jmeter"/>
+ </delete>
+
+ <jmeter
+ jmeterhome="${jmeter.home}"
+ testplan="src/main/jmeter/cayenne-profile.jmx"
+ resultlog="target/jmeter/cayenne-profile.jtl"/>
+
+ <xslt
+ in="target/jmeter/cayenne-profile.jtl"
+ out="target/jmeter/cayenne-profile.html"
+ style="src/main/jmeter/jmeter-results-report.xsl"/>
+ </target>
+
+</project>
\ No newline at end of file
Added: incubator/cayenne/main/trunk/cayenne-regression-profiler/src/main/jmeter/jmeter-results-report.xsl
URL: http://svn.apache.org/viewvc/incubator/cayenne/main/trunk/cayenne-regression-profiler/src/main/jmeter/jmeter-results-report.xsl?rev=408485&view=auto
==============================================================================
--- incubator/cayenne/main/trunk/cayenne-regression-profiler/src/main/jmeter/jmeter-results-report.xsl (added)
+++ incubator/cayenne/main/trunk/cayenne-regression-profiler/src/main/jmeter/jmeter-results-report.xsl Sun May 21 13:35:00 2006
@@ -0,0 +1,273 @@
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+<xsl:output method="html" indent="yes" encoding="US-ASCII" doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN" />
+
+<xsl:template match="testResults">
+ <html>
+ <head>
+ <title>Load Test Results</title>
+ <style type="text/css">
+ body {
+ font:normal 68% verdana,arial,helvetica;
+ color:#000000;
+ }
+ table tr td, table tr th {
+ font-size: 68%;
+ }
+ table.details tr th{
+ font-weight: bold;
+ text-align:left;
+ background:#a6caf0;
+ white-space: nowrap;
+ }
+ table.details tr td{
+ background:#eeeee0;
+ white-space: nowrap;
+ }
+ h1 {
+ margin: 0px 0px 5px; font: 165% verdana,arial,helvetica
+ }
+ h2 {
+ margin-top: 1em; margin-bottom: 0.5em; font: bold 125% verdana,arial,helvetica
+ }
+ h3 {
+ margin-bottom: 0.5em; font: bold 115% verdana,arial,helvetica
+ }
+ .Failure {
+ font-weight:bold; color:red;
+ }
+ </style>
+ </head>
+ <body>
+
+ <xsl:call-template name="pageHeader" />
+
+ <xsl:call-template name="summary" />
+ <hr size="1" width="95%" align="left" />
+
+ <xsl:call-template name="pagelist" />
+ <hr size="1" width="95%" align="left" />
+
+ <xsl:call-template name="detail" />
+
+ </body>
+ </html>
+</xsl:template>
+
+<xsl:template name="pageHeader">
+ <h1>Load Test Results</h1>
+ <table width="100%">
+ <tr>
+ <td align="left"></td>
+ <td align="right">Designed for use with <a href="http://jakarta.apache.org/jmeter">JMeter</a> and <a href="http://ant.apache.org">Ant</a>.</td>
+ </tr>
+ </table>
+ <hr size="1" />
+</xsl:template>
+
+<xsl:template name="summary">
+ <h2>Summary</h2>
+ <table class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
+ <tr valign="top">
+ <th>Tests</th>
+ <th>Failures</th>
+ <th>Success Rate</th>
+ <th>Average Time</th>
+ <th>Min Time</th>
+ <th>Max Time</th>
+ </tr>
+ <tr valign="top">
+ <xsl:variable name="allCount" select="count(/testResults/sampleResult)" />
+ <xsl:variable name="allFailureCount" select="count(/testResults/sampleResult[attribute::success='false'])" />
+ <xsl:variable name="allSuccessCount" select="count(/testResults/sampleResult[attribute::success='true'])" />
+ <xsl:variable name="allSuccessPercent" select="$allSuccessCount div $allCount" />
+ <xsl:variable name="allTotalTime" select="sum(/testResults/sampleResult/@time)" />
+ <xsl:variable name="allAverageTime" select="$allTotalTime div $allCount" />
+ <xsl:variable name="allMinTime">
+ <xsl:call-template name="min">
+ <xsl:with-param name="nodes" select="/testResults/sampleResult/@time" />
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:variable name="allMaxTime">
+ <xsl:call-template name="max">
+ <xsl:with-param name="nodes" select="/testResults/sampleResult/@time" />
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:attribute name="class">
+ <xsl:choose>
+ <xsl:when test="$allFailureCount > 0">Failure</xsl:when>
+ </xsl:choose>
+ </xsl:attribute>
+ <td>
+ <xsl:value-of select="$allCount" />
+ </td>
+ <td>
+ <xsl:value-of select="$allFailureCount" />
+ </td>
+ <td>
+ <xsl:call-template name="display-percent">
+ <xsl:with-param name="value" select="$allSuccessPercent" />
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$allAverageTime" />
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$allMinTime" />
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$allMaxTime" />
+ </xsl:call-template>
+ </td>
+ </tr>
+ </table>
+</xsl:template>
+
+<xsl:template name="pagelist">
+ <h2>Pages</h2>
+ <table class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
+ <tr valign="top">
+ <th>URL</th>
+ <th>Tests</th>
+ <th>Failures</th>
+ <th>Success Rate</th>
+ <th>Average Time</th>
+ <th>Min Time</th>
+ <th>Max Time</th>
+ </tr>
+ <xsl:for-each select="/testResults/sampleResult[not(@label = preceding::*/@label)]">
+ <xsl:variable name="label" select="@label" />
+ <xsl:variable name="count" select="count(../sampleResult[@label = current()/@label])" />
+ <xsl:variable name="failureCount" select="count(../sampleResult[@label = current()/@label][attribute::success='false'])" />
+ <xsl:variable name="successCount" select="count(../sampleResult[@label = current()/@label][attribute::success='true'])" />
+ <xsl:variable name="successPercent" select="$successCount div $count" />
+ <xsl:variable name="totalTime" select="sum(../sampleResult[@label = current()/@label]/@time)" />
+ <xsl:variable name="averageTime" select="$totalTime div $count" />
+ <xsl:variable name="minTime">
+ <xsl:call-template name="min">
+ <xsl:with-param name="nodes" select="../sampleResult[@label = current()/@label]/@time" />
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:variable name="maxTime">
+ <xsl:call-template name="max">
+ <xsl:with-param name="nodes" select="../sampleResult[@label = current()/@label]/@time" />
+ </xsl:call-template>
+ </xsl:variable>
+ <tr valign="top">
+ <xsl:attribute name="class">
+ <xsl:choose>
+ <xsl:when test="$failureCount > 0">Failure</xsl:when>
+ </xsl:choose>
+ </xsl:attribute>
+ <td>
+ <xsl:value-of select="$label" />
+ </td>
+ <td>
+ <xsl:value-of select="$count" />
+ </td>
+ <td>
+ <xsl:value-of select="$failureCount" />
+ </td>
+ <td>
+ <xsl:call-template name="display-percent">
+ <xsl:with-param name="value" select="$successPercent" />
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$averageTime" />
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$minTime" />
+ </xsl:call-template>
+ </td>
+ <td>
+ <xsl:call-template name="display-time">
+ <xsl:with-param name="value" select="$maxTime" />
+ </xsl:call-template>
+ </td>
+ </tr>
+ </xsl:for-each>
+ </table>
+</xsl:template>
+
+<xsl:template name="detail">
+ <xsl:variable name="allFailureCount" select="count(/testResults/sampleResult[attribute::success='false'])" />
+
+ <xsl:if test="$allFailureCount > 0">
+ <h2>Failure Detail</h2>
+
+ <xsl:for-each select="/testResults/sampleResult[not(@label = preceding::*/@label)]">
+
+ <xsl:variable name="failureCount" select="count(../sampleResult[@label = current()/@label][attribute::success='false'])" />
+
+ <xsl:if test="$failureCount > 0">
+ <h3><xsl:value-of select="@label" /></h3>
+
+ <table class="details" border="0" cellpadding="5" cellspacing="2" width="95%">
+ <tr valign="top">
+ <th>Response</th>
+ <th>Failure Message</th>
+ </tr>
+
+ <xsl:for-each select="/testResults/sampleResult[@label = current()/@label][attribute::success='false']">
+ <tr>
+ <td><xsl:value-of select="@responseCode" /> - <xsl:value-of select="@responseMessage" /></td>
+ <td><xsl:value-of select="assertionResult/@failureMessage" /></td>
+ </tr>
+ </xsl:for-each>
+
+ </table>
+ </xsl:if>
+
+ </xsl:for-each>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template name="min">
+ <xsl:param name="nodes" select="/.." />
+ <xsl:choose>
+ <xsl:when test="not($nodes)">NaN</xsl:when>
+ <xsl:otherwise>
+ <xsl:for-each select="$nodes">
+ <xsl:sort data-type="number" />
+ <xsl:if test="position() = 1">
+ <xsl:value-of select="number(.)" />
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="max">
+ <xsl:param name="nodes" select="/.." />
+ <xsl:choose>
+ <xsl:when test="not($nodes)">NaN</xsl:when>
+ <xsl:otherwise>
+ <xsl:for-each select="$nodes">
+ <xsl:sort data-type="number" order="descending" />
+ <xsl:if test="position() = 1">
+ <xsl:value-of select="number(.)" />
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="display-percent">
+ <xsl:param name="value" />
+ <xsl:value-of select="format-number($value,'0.00%')" />
+</xsl:template>
+
+<xsl:template name="display-time">
+ <xsl:param name="value" />
+ <xsl:value-of select="format-number($value,'0 ms')" />
+</xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file