You are viewing a plain text version of this content. The canonical link for it is here.
Posted to commits@xerces.apache.org by ga...@apache.org on 2005/06/23 17:08:35 UTC
svn commit: r193156 [2/2] - in /xerces/docs/trunk/website/content: ./ style/
style/dtd/ style/graphics/ style/resources/ style/stylesheets/
Added: xerces/docs/trunk/website/content/style/stylesheets/changes2document.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/changes2document.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/changes2document.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/changes2document.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,43 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="changes">
+ <s1 title="{@title}">
+ <xsl:apply-templates/>
+ </s1>
+ </xsl:template>
+
+ <xsl:template match="release">
+ <s2 title="Release {@version} {@date}">
+ <br/><xsl:apply-templates/>
+ </s2>
+ </xsl:template>
+
+ <xsl:template match="features">
+ <s3 title="Features">
+ <ul><xsl:apply-templates/></ul>
+ </s3>
+ </xsl:template>
+
+ <xsl:template match="fixes">
+ <s3 title="Bugs fixed">
+ <ul><xsl:apply-templates/></ul>
+ </s3>
+ </xsl:template>
+
+ <xsl:template match="feat|fix">
+ <li><xsl:apply-templates/></li>
+ </xsl:template>
+
+ <xsl:template match="@*|node()">
+ <xsl:copy>
+ <xsl:apply-templates select="@*|node()"/>
+ </xsl:copy>
+ </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/style/stylesheets/context2footer.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/context2footer.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/context2footer.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/context2footer.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,29 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="context">
+ <image source="sbk:/style/graphics/footer.gif">
+ <xsl:apply-templates/>
+ </image>
+ </xsl:template>
+
+ <xsl:template match="parameter">
+ <xsl:if test="@name='copyright'">
+ <text font="Arial Bold" size="11" x="124" y="6" style="plain"
+ halign="left" valign="top" color="666699"
+ text="Copyright © {@value}. All Rights Reserved."/>
+ <text font="Arial Bold" size="11" x="123" y="5" style="plain"
+ halign="left" valign="top" color="333366"
+ text="Copyright © {@value}. All Rights Reserved."/>
+ <text font="Arial Bold" size="11" x="122" y="4" style="plain"
+ halign="left" valign="top" color="ffffff"
+ text="Copyright © {@value}. All Rights Reserved."/>
+ </xsl:if>
+ </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/style/stylesheets/context2label.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/context2label.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/context2label.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/context2label.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,25 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:param name="image"/>
+ <xsl:param name="color"/>
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="context">
+ <image source="{$image}">
+ <xsl:apply-templates/>
+ </image>
+ </xsl:template>
+
+ <xsl:template match="parameter">
+ <xsl:if test="@name='label'">
+ <text font="Arial" size="12" x="14" y="1" halign="left"
+ valign="top" color="{$color}" style="italic" text="{@value}"/>
+ </xsl:if>
+ </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/style/stylesheets/directory2project.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/directory2project.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/directory2project.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/directory2project.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,34 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:param name="base"/>
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="directory">
+ <project>
+ <xsl:apply-templates/>
+ </project>
+ </xsl:template>
+
+ <xsl:template match="entry">
+
+ <!--xsl:if test="@directory!='true'"-->
+ <resource source="{@href}" target="{$base}{@href}"/>
+ <!--/xsl:if-->
+<!-- don't copy subdir to avoid copying proprietary CVS files
+ <xsl:if test="@directory='true'">
+ <process source="{@href}" producer="directory">
+ <processor name="xslt">
+ <parameter name="stylesheet" value="sbk:/style/stylesheets/directory2project.xsl"/>
+ <parameter name="base" value="{$base}{@href}"/>
+ </processor>
+ </process>
+ </xsl:if>
+-->
+ </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/style/stylesheets/document2html.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/document2html.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/document2html.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/document2html.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,445 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:param name="stylebook.project"/>
+ <xsl:param name="copyright"/>
+ <xsl:param name="id"/>
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="s1">
+ <html>
+ <head>
+ <meta http-equiv="Content-Type" content="text/html; charset=utf8"/>
+ <script language="JavaScript" type="text/javascript" src="resources/script.js"/>
+ <title><xsl:value-of select="@title"/></title>
+ </head>
+ <body text="#000000" link="#0000ff" vlink="#0000aa" alink="#ff0000"
+ topmargin="4" leftmargin="4" marginwidth="4" marginheight="4"
+ bgcolor="#ffffff">
+ <!-- THE TOP BAR (HEADER) -->
+ <table width="620" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td width="135" height="60" rowspan="3" valign="top" align="left">
+ <img width="135" height="60" src="resources/logo.gif" hspace="0" vspace="0" border="0"/></td>
+ <td width="456" height="5" valign="top" align="left" colspan="4">
+ <img width="456" height="5" src="resources/line.gif" hspace="0" vspace="0" border="0"/></td>
+ <td width="29" height="60" rowspan="3" valign="top" align="left">
+ <img width="29" height="60" src="resources/right.gif" hspace="0" vspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td width="456" height="35" valign="top" align="left" colspan="4" bgcolor="#0086b2">
+ <img src="graphics/{$id}-header.jpg" width="456" height="35" hspace="0" vspace="0" border="0" alt="{s1/@title}"/></td>
+ </tr>
+ <tr>
+ <td width="168" height="20" valign="top" align="left">
+ <img width="168" height="20" src="resources/bottom.gif" hspace="0" vspace="0" border="0"/></td>
+ <td width="96" height="20" valign="top" align="left">
+ <a href="http://xml.apache.org/" onMouseOver="rolloverOn('xml');" onMouseOut="rolloverOff('xml');" target="new">
+ <img alt="http://xml.apache.org/" width="96" height="20" src="resources/button-xml-lo.gif"
+ name="xml" hspace="0" vspace="0" border="0"
+ onLoad="rolloverLoad('xml','resources/button-xml-hi.gif','resources/button-xml-lo.gif');"/>
+ </a>
+ </td>
+ <td width="96" height="20" valign="top" align="left">
+ <a href="http://www.apache.org/" onMouseOver="rolloverOn('asf');" onMouseOut="rolloverOff('asf');" target="new">
+ <img alt="http://www.apache.org/" width="96" height="20" src="resources/button-asf-lo.gif"
+ name="asf" hspace="0" vspace="0" border="0"
+ onLoad="rolloverLoad('asf','resources/button-asf-hi.gif','resources/button-asf-lo.gif');"/>
+ </a>
+ </td>
+ <td width="96" height="20" valign="top" align="left">
+ <a href="http://www.w3.org/" onMouseOver="rolloverOn('w3c');" onMouseOut="rolloverOff('w3c');" target="new">
+ <img alt="http://www.w3.org/" width="96" height="20" src="resources/button-w3c-lo.gif"
+ name="w3c" hspace="0" vspace="0" border="0"
+ onLoad="rolloverLoad('w3c','resources/button-w3c-hi.gif','resources/button-w3c-lo.gif');"/>
+ </a>
+ </td>
+ </tr>
+ </table>
+ <!-- THE MAIN PANEL (SIDEBAR AND CONTENT) -->
+ <table width="620" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <!-- THE SIDE BAR -->
+ <td width="120" valign="top" align="left">
+ <img width="120" height="14" src="resources/join.gif" hspace="0" vspace="0" border="0"/><br/>
+ <xsl:apply-templates select="document($stylebook.project)"/>
+ <img width="120" height="14" src="resources/close.gif" hspace="0" vspace="0" border="0"/><br/>
+ </td>
+ <!-- THE CONTENT PANEL -->
+ <td width="500" valign="top" align="left">
+ <table border="0" cellspacing="0" cellpadding="3">
+ <tr><td><xsl:apply-templates/></td></tr>
+ </table>
+ </td>
+ </tr>
+ </table><br/>
+ <table width="620" border="0" cellspacing="0" cellpadding="0">
+ <tr><td bgcolor="#0086b2"><img src="images/dot.gif" width="1" height="1"/></td></tr>
+ <tr>
+ <td align="center"><font size="-1" color="#0086b2"><i>
+ Copyright © <xsl:value-of select="$copyright"/>.
+ All Rights Reserved.
+ </i></font></td>
+ </tr>
+ </table>
+ </body>
+ </html>
+ </xsl:template>
+
+<!-- ###################################################################### -->
+<!-- book -->
+
+ <xsl:template match="book">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="document|faqs|changes|group|container">
+ <xsl:if test="@id=$id">
+ <img src="graphics/{@id}-label-1.jpg" width="120" height="12" hspace="0" vspace="0" border="0" alt="{@label}"/>
+ </xsl:if>
+ <xsl:if test="@id!=$id">
+ <a href="{@id}.html" onMouseOver="rolloverOn('side-{@id}');" onMouseOut="rolloverOff('side-{@id}');">
+ <img onLoad="rolloverLoad('side-{@id}','graphics/{@id}-label-2.jpg','graphics/{@id}-label-3.jpg');"
+ name="side-{@id}" src="graphics/{@id}-label-3.jpg" width="120" height="12" hspace="0" vspace="0" border="0" alt="{@label}"/>
+ </a>
+ </xsl:if>
+ <br/>
+ </xsl:template>
+
+ <xsl:template match="external">
+ <xsl:variable name="extid" select="concat('ext-',position())"/>
+ <a href="{@href}" onMouseOver="rolloverOn('side-{$extid}');" onMouseOut="rolloverOff('side-{$extid}');">
+ <img onLoad="rolloverLoad('side-{$extid}','graphics/{$extid}-label-2.jpg','graphics/{$extid}-label-3.jpg');"
+ name="side-{$extid}" src="graphics/{$extid}-label-3.jpg" width="120" height="12" hspace="0" vspace="0" border="0" alt="{@label}"/>
+ </a>
+ <br/>
+ </xsl:template>
+
+ <xsl:template match="separator">
+ <img src="resources/separator.gif" width="120" height="6" hspace="0" vspace="0" border="0"/><br/>
+ </xsl:template>
+
+
+<!-- ###################################################################### -->
+<!-- document -->
+
+ <xsl:template match="s2">
+ <table width="494" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="ffffff" colspan="2" width="494">
+ <table width="494" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="#039acc" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#039acc" width="492" height="1"><img src="resources/void.gif" width="492" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#039acc" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="492">
+ <font size="+1" face="arial,helvetica,sanserif" color="#ffffff">
+ <img src="resources/void.gif" width="2" height="2" vspace="0" hspace="0" border="0"/>
+ <b><xsl:value-of select="@title"/></b>
+ </font>
+ </td>
+ <td bgcolor="#017299" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#017299" width="492" height="1"><img src="resources/void.gif" width="492" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#017299" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ </table>
+ </td>
+ </tr>
+ <tr>
+ <td width="10"> </td>
+ <td width="484">
+ <font face="arial,helvetica,sanserif" color="#000000">
+ <xsl:apply-templates/>
+ </font>
+ </td>
+ </tr>
+ </table>
+ <br/>
+ </xsl:template>
+
+ <xsl:template match="s3">
+ <table width="484" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="ffffff" colspan="2" width="484">
+ <table width="484" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="#039acc" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#039acc" width="482" height="1"><img src="resources/void.gif" width="482" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#039acc" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="482">
+ <font face="arial,helvetica,sanserif" color="#ffffff">
+ <img src="resources/void.gif" width="2" height="2" vspace="0" hspace="0" border="0"/>
+ <b><xsl:value-of select="@title"/></b>
+ </font>
+ </td>
+ <td bgcolor="#017299" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#017299" width="482" height="1"><img src="resources/void.gif" width="482" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#017299" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ </table>
+ </td>
+ </tr>
+ <tr>
+ <td width="10"> </td>
+ <td width="474">
+ <font size="-1" face="arial,helvetica,sanserif" color="#000000">
+ <xsl:apply-templates/>
+ </font>
+ </td>
+ </tr>
+ </table>
+ <br/>
+ </xsl:template>
+
+ <xsl:template match="s4">
+ <table width="474" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="ffffff" colspan="2" width="484">
+ <table width="474" cellspacing="0" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="#039acc" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#039acc" width="472" height="1"><img src="resources/void.gif" width="472" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#039acc" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="472">
+ <font size="-1" face="arial,helvetica,sanserif" color="#ffffff">
+ <img src="resources/void.gif" width="2" height="2" vspace="0" hspace="0" border="0"/>
+ <b><xsl:value-of select="@title"/></b>
+ </font>
+ </td>
+ <td bgcolor="#017299" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#017299" width="472" height="1"><img src="resources/void.gif" width="472" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#017299" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ </table>
+ </td>
+ </tr>
+ <tr>
+ <td width="10"> </td>
+ <td width="464">
+ <font size="-1" face="arial,helvetica,sanserif" color="#000000">
+ <xsl:apply-templates/>
+ </font>
+ </td>
+ </tr>
+ </table>
+ <br/>
+ </xsl:template>
+
+<!-- ###################################################################### -->
+<!-- blocks -->
+
+ <xsl:template match="p">
+ <p><xsl:apply-templates/></p>
+ </xsl:template>
+
+ <xsl:template match="note">
+ <table width="100%" cellspacing="3" cellpadding="0" border="0">
+ <tr>
+ <td width="20" valign="top">
+ <img src="resources/note.gif" width="20" height="24" vspace="0" hspace="0" border="0" alt="Note"/>
+ </td>
+ <td valign="top">
+ <font size="-1" face="arial,helvetica,sanserif" color="#000000">
+ <i>
+ <xsl:apply-templates/>
+ </i>
+ </font>
+ </td>
+ </tr>
+ </table>
+ </xsl:template>
+
+ <xsl:template match="ul">
+ <ul><xsl:apply-templates/></ul>
+ </xsl:template>
+
+ <xsl:template match="ol">
+ <ol><xsl:apply-templates/></ol>
+ </xsl:template>
+
+ <xsl:template match="li">
+ <li><xsl:apply-templates/></li>
+ </xsl:template>
+
+ <!--Definition lists: gloss, term, label, item -->
+ <xsl:template match="gloss">
+ <dl><xsl:apply-templates/></dl>
+ </xsl:template>
+ <!-- <term> contains a single-word, multi-word or symbolic
+ designation which is regarded as a technical term. -->
+ <xsl:template match="term">
+ <dfn><xsl:apply-templates/></dfn>
+ </xsl:template>
+ <xsl:template match="label" priority="1">
+ <dt><xsl:apply-templates/></dt>
+ </xsl:template>
+ <xsl:template match="item" priority="2">
+ <dd>
+ <xsl:apply-templates/>
+ </dd>
+ </xsl:template>
+
+ <xsl:template match="source">
+ <div align="left">
+ <table width="464" cellspacing="4" cellpadding="0" border="0">
+ <tr>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="462" height="1"><img src="resources/void.gif" width="462" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#0086b2" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#ffffff" width="462">
+ <font size="-1"><pre><xsl:apply-templates/></pre></font>
+ </td>
+ <td bgcolor="#0086b2" width="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ <tr>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="462" height="1"><img src="resources/void.gif" width="462" height="1" vspace="0" hspace="0" border="0"/></td>
+ <td bgcolor="#0086b2" width="1" height="1"><img src="resources/void.gif" width="1" height="1" vspace="0" hspace="0" border="0"/></td>
+ </tr>
+ </table>
+ </div>
+ </xsl:template>
+
+ <xsl:template match="table">
+ <table width="100%" border="0" cellspacing="2" cellpadding="2">
+ <xsl:apply-templates/>
+ </table>
+ </xsl:template>
+
+ <xsl:template match="tr">
+ <tr><xsl:apply-templates/></tr>
+ </xsl:template>
+
+ <xsl:template match="th">
+ <td bgcolor="#039acc" colspan="{@colspan}" rowspan="{@rowspan}" valign="center" align="center">
+ <font color="#ffffff" size="-1" face="arial,helvetica,sanserif">
+ <b><xsl:apply-templates/></b> 
+ </font>
+ </td>
+ </xsl:template>
+
+ <xsl:template match="td">
+ <td bgcolor="#a0ddf0" colspan="{@colspan}" rowspan="{@rowspan}" valign="top" align="{@align}">
+ <font color="#000000" size="-1" face="arial,helvetica,sanserif">
+ <xsl:apply-templates/> 
+ </font>
+ </td>
+ </xsl:template>
+
+ <xsl:template match="tn">
+ <td bgcolor="#ffffff" colspan="{@colspan}" rowspan="{@rowspan}">
+  
+ </td>
+ </xsl:template>
+
+<!-- ###################################################################### -->
+<!-- markup -->
+
+ <xsl:template match="em">
+ <b><xsl:apply-templates/></b>
+ </xsl:template>
+
+ <xsl:template match="ref">
+ <i><xsl:apply-templates/></i>
+ </xsl:template>
+
+ <xsl:template match="code">
+ <code><font face="courier, monospaced"><xsl:apply-templates/></font></code>
+ </xsl:template>
+
+ <xsl:template match="br">
+ <br/>
+ </xsl:template>
+
+<!-- ###################################################################### -->
+<!-- links -->
+
+ <xsl:template match="link">
+ <xsl:if test="string-length(@anchor)=0">
+ <xsl:if test="string-length(@idref)=0">
+ <xsl:apply-templates/>
+ </xsl:if>
+ <xsl:if test="string-length(@idref)>0">
+ <a href="{@idref}.html"><xsl:apply-templates/></a>
+ </xsl:if>
+ </xsl:if>
+
+ <xsl:if test="string-length(@anchor)>0">
+ <xsl:if test="string-length(@idref)=0">
+ <a href="#{@anchor}"><xsl:apply-templates/></a>
+ </xsl:if>
+ <xsl:if test="string-length(@idref)>0">
+ <a href="{@idref}.html#{@anchor}"><xsl:apply-templates/></a>
+ </xsl:if>
+ </xsl:if>
+ </xsl:template>
+
+ <xsl:template match="anchor">
+ <a name="{@name}"><xsl:comment>anchor</xsl:comment></a>
+ </xsl:template>
+
+ <xsl:template match="jump">
+ <a href="{@href}"><xsl:apply-templates/></a>
+ </xsl:template>
+
+ <xsl:template match="img">
+ <img src="images/{@src}" border="0" vspace="4" hspace="4" align="right"/>
+ </xsl:template>
+
+ <xsl:template match="resource-ref">
+ <xsl:variable name="resourceFile"
+ select="document($stylebook.project)/book/resources/@source"/>
+ <xsl:variable name="xref" select="@idref"/>
+ <xsl:variable name="href"
+ select="document($resourceFile)/resources/resource[@id=$xref]/@location"/>
+ <xsl:variable name="label"
+ select="document($resourceFile)/resources/resource[@id=$xref]/@title"/>
+ <A href="{$href}" target="_top"><xsl:value-of select="$label"/></A>
+ </xsl:template>
+
+ <xsl:template match="human-resource-ref">
+ <xsl:variable name="resourceFile"
+ select="document($stylebook.project)/book/resources/@source"/>
+ <xsl:variable name="ref" select="@idref"/>
+ <xsl:variable name="mailto"
+ select="document($resourceFile)/resources/human-resource[@id=$ref]/@mailto"/>
+ <xsl:variable name="name"
+ select="document($resourceFile)/resources/human-resource[@id=$ref]/@name"/>
+ <A href="mailto:{$mailto}"><xsl:value-of select="$name"/></A>
+ </xsl:template>
+
+<!-- ###################################################################### -->
+<!-- copy
+
+ <xsl:template match="@*|node()">
+ <xsl:copy>
+ <xsl:apply-templates select="@*|node()"/>
+ </xsl:copy>
+ </xsl:template>
+-->
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/style/stylesheets/faqs2document.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/faqs2document.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/faqs2document.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/faqs2document.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,51 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="faqs">
+ <s1 title="{@title}">
+ <s2 title="Questions">
+ <ul>
+ <xsl:apply-templates select="faq" mode="index"/>
+ </ul>
+ </s2>
+ <br/>
+ <xsl:apply-templates select="faq"/>
+ </s1>
+ </xsl:template>
+
+ <xsl:template match="faq" mode="index">
+ <li>
+ <link anchor="faq-{position()}">
+ <xsl:if test="string-length(@title)=0">
+ <xsl:value-of select="q"/>
+ </xsl:if>
+ <xsl:if test="string-length(@title)>0">
+ <xsl:value-of select="@title"/>
+ </xsl:if>
+ </link>
+ </li>
+ </xsl:template>
+
+ <xsl:template match="faq">
+ <anchor name="faq-{position()}"/>
+ <s2 title="{q}">
+ <xsl:apply-templates select="a"/>
+ </s2>
+ </xsl:template>
+
+ <xsl:template match="a">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="@*|node()">
+ <xsl:copy>
+ <xsl:apply-templates select="@*|node()"/>
+ </xsl:copy>
+ </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/style/stylesheets/group2document.xsl
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/style/stylesheets/group2document.xsl?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/style/stylesheets/group2document.xsl (added)
+++ xerces/docs/trunk/website/content/style/stylesheets/group2document.xsl Thu Jun 23 08:08:32 2005
@@ -0,0 +1,31 @@
+<?xml version="1.0"?>
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+
+ <xsl:template match="/">
+ <xsl:apply-templates/>
+ </xsl:template>
+
+ <xsl:template match="group">
+ <s1 title="{@title}">
+ <xsl:apply-templates/>
+ </s1>
+ </xsl:template>
+
+ <xsl:template match="entry">
+ <s2 title="{@title}">
+ <p>
+ Read the <link idref="{@id}"><xsl:value-of select="@title"/></link>
+ document or jump directly to:
+ </p>
+ <ul>
+ <xsl:apply-templates/>
+ </ul>
+ </s2>
+ </xsl:template>
+
+ <xsl:template match="voice">
+ <li><link idref="{ancestor::*/@id}" anchor="faq-{position()}"><xsl:apply-templates/></link></li>
+ </xsl:template>
+
+</xsl:stylesheet>
\ No newline at end of file
Added: xerces/docs/trunk/website/content/xerces_book.xml
URL: http://svn.apache.org/viewcvs/xerces/docs/trunk/website/content/xerces_book.xml?rev=193156&view=auto
==============================================================================
--- xerces/docs/trunk/website/content/xerces_book.xml (added)
+++ xerces/docs/trunk/website/content/xerces_book.xml Thu Jun 23 08:08:32 2005
@@ -0,0 +1,44 @@
+<?xml version="1.0"?>
+<!--
+ * Copyright 1999-2005 The Apache Software Foundation.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ * http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+-->
+
+<!DOCTYPE book SYSTEM "sbk:/style/dtd/book.dtd">
+
+<book title="Xerces Website" copyright="1999-2005 The Apache Software Foundation">
+
+ <separator/>
+
+ <document id="index" label="Home" source="readme.xml"/>
+ <document id="charter" label="Charter" source="charter.xml"/>
+
+ <separator/>
+
+ <external href="http://xml.apache.org/xerces-c" label="Xerces C"/>
+ <external href="http://xml.apache.org/xerces-j" label="Xerces J 1"/>
+ <external href="http://xml.apache.org/xerces2-j" label="Xerces J 2"/>
+ <external href="http://xml.apache.org/xerces-p" label="Xerces P"/>
+
+ <separator/>
+ <external href="http://marc.theaimsgroup.com/?l=xerces-c-users" label="C Users Archive"/>
+ <external href="http://marc.theaimsgroup.com/?l=xerces-c-dev" label="C Devel Archive"/>
+ <external href="http://marc.theaimsgroup.com/?l=xerces-j-users" label="J Users Archive"/>
+ <external href="http://marc.theaimsgroup.com/?l=xerces-j-dev" label="J Devel Archive"/>
+ <external href="http://marc.theaimsgroup.com/?l=xerces-p-dev" label="P Devel Archive"/>
+
+
+ <separator/>
+
+</book>
---------------------------------------------------------------------
To unsubscribe, e-mail: commits-unsubscribe@xerces.apache.org
For additional commands, e-mail: commits-help@xerces.apache.org